//****************************************************************************
//                   INTEL CORPORATION PROPRIETARY INFORMATION
//       This software is supplied under the terms of a license agreement or
//       nondisclosure agreement with Intel Corporation and may not be copied
//       or disclosed except in accordance with the terms of that agreement.
//         Copyright (c) 2016 Intel Corporation. All Rights Reserved.
//****************************************************************************
//
//NOTE: Please use only TAB stops for indentation when editing this file!
//

CONFIGURATION  "Revision S7200AP_124"
DISPLAY        "FRU & SDR Update Package for Intel(R) Server Board S7200AP (S7200AP_124)"
DISPLAY        "Copyright (c) 2016 Intel Corporation"
DISPLAY        " "


// Detect baseboard by looking at the BMC product ID
//
PROBE          "BASEBOARD_PRODID" "75"
FOUND          "S7200AP" "WRONG_PKG"

IFSET "WRONG_PKG"
	DISPLAY ""
	DISPLAY "This is the incorrect FRU/SDR package for this baseboard."
	DISPLAY ""
ENDIF


IFSET "S7200AP"
	// Uncomment to force manual Chassis selection
	//SET "CHASSIS_MENU"

	// Uncomment to allow setting Board Mfg FRU fields
	//SET "ALLOW_BRD_UPDATE"

	// Determine if this is a S7200AP board
	FRUNAME     "SYSTEM"
	FRUADDRESS  0
	FRUAREA "BOARD" VALIDATE "BB_FRU_IPMI"
	IFSET "BB_FRU_IPMI"
		PROBE FRUFIELD "PN" "S7200AP"
		FOUND "AP_FRU_PN" ""
		IFSET "AP_FRU_PN"
			SET "S7200APP"
		ELSE
			SET "NO_ADP_FRU"
		ENDIF
	ELSE
		DISPLAY "No Valid Baseboard FRU detected!"
		SET "NO_ADP_FRU"
	ENDIF

	DISPLAY		""
	IFSET "S7200APP"
		DISPLAY		"Intel(R) Server Board S7200AP detected"
	ELSE
		DISPLAY		"Intel(R) Server Board S7200AP detected"
	ENDIF

	DISPLAY        ""
	MENUTITLE      "Select the function you want to perform:"
	MENU           "SDR"       "Update only the SDR"
	MENU           "FRU"       "Update only the FRU"
	MENU           "BOTH"      "Update both the SDR and the FRU"
	MENU           "ASSET"     "Modify the Asset Tag Only"
	// MENU           "FCT"       "Functional Test"
	// MENU           "FOQM"      "Functional Outgoing Manufacturing Test"
	// MENU           "SHIPPING"  "Default shipping configuration"
	MENU           "EXIT1"     "Exit FRU/SDR update"
	MENUPROMPT
	DISPLAY        " "

	IFSET "BOTH"
		SET "SDR"
		SET "FRU"
	ENDIF

	// Skip HW probing if one of the manufacturing specific configurations is selected
	IFSET "FCT"
		SET "MFG_CONFIG"
		SET "SKIP_PROBE"
	ENDIF

	IFSET "FOQM"
		SET "MFG_CONFIG"
		SET "SKIP_PROBE"
	ENDIF

	IFSET "SHIPPING"
		SET "MFG_CONFIG"
		SET "SKIP_PROBE"
	ENDIF

	IFSET "EXIT1"
		DISPLAY "Exiting without performing any updates"
	ELSE
		// Skip all hardware probing and program the selected manufacturing configuration
		IFSET "MFG_CONFIG"
			SDRNAME   "S7200AP.sdr"        // Update SDR Repository
		ENDIF

		SET "CONTINUE"

		IFSET "SDR"
			IFSET "CHASSIS_MENU"
			ELSE
				DISPLAY "Auto-detecting chassis model and attached hardware."
				DISPLAY "This may take up to 1 minute to complete."

				// Is a HSBP FRU device present?
				PROBE "IMBDEVICE" "08"
				FOUND "HSBP_FRU" ""
			ENDIF

			IFSET "HSBP_FRU" "CONTINUE"
				//DISPLAY "HSBP FRU is detected"
				FRUNAME     "SYSTEM"
				FRUADDRESS  08
				FRUAREA     "BOARD" VALIDATE HSBP_FRU_IPMI
				IFSET "HSBP_FRU_IPMI"
					FRUAREA "BOARD"
					//PROBE FRUFIELD "MN" "Intel Corporation"
					PROBE FRUFIELD "PN" "FHW12X35HSBP12G"
					FOUND "2U4N_BP_X35" "CONTINUE_PROBE"

					IFSET "CONTINUE_PROBE"
						CLEAR "CONTINUE_PROBE"
						PROBE FRUFIELD "PN" "FHW16X25HSBP12G"
						FOUND "2U4N_BP_X25" "CONTINUE_PROBE"
					ENDIF

					IFSET "CONTINUE_PROBE"
						CLEAR "CONTINUE_PROBE"
					ELSE
						SET "INTEL_HSBP"
					ENDIF

					CLEAR "CONTINUE_PROBE"
				ENDIF  // HSBP_FRU_IPMI

				IFSET "INTEL_HSBP"
					// Is a Node Presence device present?
					PROBE "PING" "03" "30"
					FOUND "NODE"

					IFSET "NODE"
						DISPLAY "NODE Presence is present"
						SET "BCP_2U4N"
					ELSE
						DISPLAY "NODE ERROR!"
						SET "CHASSIS_MENU"
					ENDIF
				ELSE  // INTEL_HSBP
					DISPLAY ""
					DISPLAY "HSBP FRU device is detected but not INTEL HSBP."
					DISPLAY "Reverting to Manual Chassis Selection."
					//SET "OTHER"
					SET "CHASSIS_MENU"
				ENDIF  // INTEL_HSBP
			ELSE  // HSBP_FRU
				DISPLAY ""
				DISPLAY "HSBP FRU device is not detected."
				DISPLAY "Reverting to Manual Chassis Selection."
				//SET "OTHER"
				SET "CHASSIS_MENU"
			ENDIF  // HSBP_FRU

			IFSET "BCP_2U4N"
				SET "SYS_FAN_2U4N"
			ENDIF

			//****************************************************************************************************
			// Display chassis selection menu only if auto-detection fails
			//*****************************************************************************************************
			IFSET "CHASSIS_MENU"
				//************************************************************************
				// If we could not detect a chassis type, signal Auto Config by setting
				// the AUTO_CFG_ERR_CHASSIS_DETECT tag.
				//************************************************************************
				SET "AUTO_CFG_ERR_CHASSIS_DETECT"

				DISPLAY " "
				MENUTITLE   "Select the chassis:"
				MENU        "2U4N_BP_X35"  "H2312 chassis"
				MENU        "2U4N_BP_X25"  "H2216 chassis"
				MENU        "TEST_PLATE"   "Test Plate for NPI:PO Kit"
				MENU        "OTHER"        "Other Chassis"
				MENUPROMPT
				DISPLAY ""
			ENDIF

			IFSET "CHASSIS_MENU"
				DISPLAY " "
				DISPLAY "Continuing to probe chassis hardware."
			ENDIF

			// Is a power supply module installed at the PS1 slot?
			//PROBE "IMBDEVICE" "02"
			PROBE "PING" "0F" "A0"
			FOUND "PS1" "NO_PS1"

			// Is a power supply module installed at the PS2 slot?
			//PROBE "IMBDEVICE" "03"
			PROBE "PING" "0F" "A2"
			FOUND "PS2" "NO_PS2"

			IFSET "NO_PS1" "NO_PS2"
				DISPLAY ""
				DISPLAY "Unable to communicate with any power supply modules."
				DISPLAY ""
			ENDIF

			IFSET "PS1"
				FRUNAME "SYSTEM"
				FRUADDRESS 02
				FRUAREA "PRODUCT" VALIDATE PS1_FRU_IPMI

				IFSET "PS1_FRU_IPMI"
					SET "STICKY_VALID_PS1"
					SET "CONTINUE_PROBE"
					FRUAREA "PRODUCT"
					PROBE FRUFIELD "PN" "IS162F22"
					FOUND "PS1_1600W" ""
					IFSET "PS1_1600W"
						CLEAR "CONTINUE_PROBE"
						SET "STICKY_PS1_1600W"
					ENDIF

					IFSET "CONTINUE_PROBE"
						FRUAREA "PRODUCT"
						PROBE FRUFIELD "PN" "PSSF222201A"
						FOUND "PS1_2130W" ""
						IFSET "PS1_2130W"
							CLEAR "CONTINUE_PROBE"
							SET "STICKY_PS1_2130W"
						ENDIF
					ENDIF

					IFSET "CONTINUE_PROBE"
						DISPLAY ""
						DISPLAY "Power supply 1 detected but unable to identify model."
						DISPLAY "Sensors for power supply 1 will not be installed."
						CLEAR "STICKY_PS1_1600W"
						CLEAR "STICKY_PS1_2130W"
					ENDIF
				ELSE
					DISPLAY ""
					DISPLAY "Power supply 1 detected but its FRU data is invalid."
					DISPLAY "Sensors for power supply 1 will not be installed."
					CLEAR "STICKY_PS1_1600W"
					CLEAR "STICKY_PS1_2130W"
				ENDIF
			ENDIF  // PS1

			IFSET "PS2"
				FRUNAME "SYSTEM"
				FRUADDRESS 03
				FRUAREA "PRODUCT" VALIDATE PS2_FRU_IPMI

				IFSET "PS2_FRU_IPMI"
					SET "STICKY_VALID_PS2"
					SET "CONTINUE_PROBE"
					FRUAREA "PRODUCT"
					PROBE FRUFIELD "PN" "IS162F22"
					FOUND "PS2_1600W" ""
					IFSET "PS2_1600W"
						CLEAR "CONTINUE_PROBE"
						SET "STICKY_PS2_1600W"
					ENDIF

					IFSET "CONTINUE_PROBE"
						FRUAREA "PRODUCT"
						PROBE FRUFIELD "PN" "PSSF222201A"
						FOUND "PS2_2130W" ""
						IFSET "PS2_2130W"
							CLEAR "CONTINUE_PROBE"
							SET "STICKY_PS2_2130W"
						ENDIF
					ENDIF

					IFSET "CONTINUE_PROBE"
						DISPLAY ""
						DISPLAY "Power supply 2 detected but unable to identify model."
						DISPLAY "Sensors for power supply 2 will not be installed."
						CLEAR "STICKY_PS2_1600W"
						CLEAR "STICKY_PS2_2130W"
					ENDIF
				ELSE
					DISPLAY ""
					DISPLAY "Power supply 2 detected but its FRU data is invalid."
					DISPLAY "Sensors for power supply 2 will not be installed."
					CLEAR "STICKY_PS2_1600W"
					CLEAR "STICKY_PS2_2130W"
				ENDIF
			ENDIF  // PS2

			IFSET   "SKIP_PROBE" // {
				// Skip probing the hardware 
			ELSE 
				// PROBE PCI Riser 1
				PROBE "IMBDEVICE" "0B"
				FOUND "RISER_1_FRU" ""
				
		
				// PROBE PCI Riser 2
				PROBE "IMBDEVICE" "0C"
				FOUND "RISER_2_FRU" ""

								
				// Probe the hardware to discover installed devices
				PROBE    "PROCESSOR"    1
				FOUND    "PROCESSOR_1"    ""

				PROBE "PING" "03" "9A"
				FOUND "HSBP_TEMP" ""
			ENDIF

			IFSET "SKIP_UPDATE" // {
				// Do not print out a summary of detected hardware if skipping the update
			ELSE
				// Print out summary of detected hardware
				DISPLAY ""
				DISPLAY "                                Detected Hardware"
				DISPLAY "********************************************************************************"

				IFSET   "2U4N_BP_X35"
					DISPLAY "Intel(R) Server Chassis H2000G Product Family"
				ENDIF

				IFSET   "2U4N_BP_X25"
					DISPLAY "Intel(R) Server Chassis H2000G Product Family"
				ENDIF

				IFSET   "TEST_PLATE"
					DISPLAY "Open Test Plate Chassis"
				ENDIF

				IFSET "S7200APP"
					DISPLAY "Intel(R) Server Board S7200AP"
				ELSE
					DISPLAY "Intel(R) Server Board S7200APx"
				ENDIF

				IFSET    "PROCESSOR_1"
					DISPLAY "Intel(R) Xeon Phi(TM) processor 7200 Series"
				ENDIF

				DISPLAY "Baseboard FRU Device"

				IFSET "STICKY_PS1_1600W"
					DISPLAY "1600 Watt Power Supply Module 1"
					DISPLAY "Power Supply Module 1 FRU Device"
				ENDIF

				IFSET "STICKY_PS2_1600W"
					DISPLAY "1600 Watt Power Supply Module 2"
					DISPLAY "Power Supply Module 2 FRU Device"
				ENDIF

				IFSET "STICKY_PS1_2130W"
					DISPLAY "2130 Watt Power Supply Module 1"
					DISPLAY "Power Supply Module 1 FRU Device"
				ENDIF

				IFSET "STICKY_PS2_2130W"
					DISPLAY "2130 Watt Power Supply Module 2"
					DISPLAY "Power Supply Module 2 FRU Device"
				ENDIF

				IFSET "STICKY_VALID_PS1" "STICKY_VALID_PS2"
					DISPLAY "Redundant Power Supply Configuration"
					SET "STICKY_REDUND_PS"
				ENDIF

				IFSET "2U4N_BP_X35"
					DISPLAY "HSBP is a 2U 12 slot 3.5 inch HDD Backplane"
				ENDIF

				IFSET "2U4N_BP_X25"
					DISPLAY "HSBP is a 2U 16 slot 2.5 inch HDD Backplane"
				ENDIF

			
				IFSET "RISER_1_FRU"
					DISPLAY "PCI RISER 1"
				ENDIF
				IFSET "RISER_2_FRU"
					DISPLAY "PCI RISER 2"
				ENDIF
				IFSET "LAN_LEASH"
					DISPLAY "Springville Temperature is detected."
				ENDIF

				DISPLAY "********************************************************************************"
			ENDIF

			//*****************************************************************
			// Set additional SDR tags based on chassis detected
			//*****************************************************************
			IFSET "2U4N_BP_X35"
				// Set additional SDR tags for the H2300 chassis
			ENDIF

			IFSET "2U4N_BP_X25"
				// Set additional SDR tags for the H2200 chassis
			ENDIF

			IFSET "OTHER"
				//System Fans
				DISPLAY ""
				PROMPT  "Is System Fan 1A installed (Y/N)?"
				YES     "OTHER_FAN_1A"
				NO      ""

				DISPLAY " "
				PROMPT  "Is System Fan 1B installed (Y/N)?"
				YES     "OTHER_FAN_1B"
				NO      ""

				DISPLAY " "
				PROMPT  "Is System Fan 2A installed (Y/N)?"
				YES     "OTHER_FAN_2A"
				NO      ""

				DISPLAY " "
				PROMPT  "Is System Fan 2B installed (Y/N)?"
				YES     "OTHER_FAN_2B"
				NO      ""

				DISPLAY " "
				PROMPT  "Is System Fan 3A installed (Y/N)?"
				YES     "OTHER_FAN_3A"
				NO      ""

				DISPLAY " "
				PROMPT  "Is System Fan 3B installed (Y/N)?"
				YES     "OTHER_FAN_3B"
				NO      ""

				DISPLAY " "
				PROMPT  "Is System Fan 4A installed (Y/N)?"
				YES     "OTHER_FAN_4A"
				NO      ""

				DISPLAY " "
				PROMPT  "Is System Fan 4B installed (Y/N)?"
				YES     "OTHER_FAN_4B"
				NO      ""

				DISPLAY " "
				PROMPT  "Is System Fan 5A installed (Y/N)?"
				YES     "OTHER_FAN_5A"
				NO      ""

				DISPLAY " "
				PROMPT  "Is System Fan 5B installed (Y/N)?"
				YES     "OTHER_FAN_5B"
				NO      ""

				DISPLAY " "
				PROMPT  "Is System Fan 6A installed (Y/N)?"
				YES     "OTHER_FAN_6A"
				NO      ""

				DISPLAY " "
				PROMPT  "Is System Fan 6B installed (Y/N)?"
				YES     "OTHER_FAN_6B"
				NO      ""

				PROMPT "Is a CPU Fan installed?"
				YES "OTHER_CPU_FAN"
				NO ""

				CLEAR "BCP_2U4N"
				CLEAR "SYS_FAN_2U4N"
				CLEAR "2U4N_BP_X35"
				CLEAR "2U4N_BP_X25"
				CLEAR "TEST_PLATE"
				CLEAR "STICKY_PS1_1600W"
				CLEAR "STICKY_PS2_1600W"
				CLEAR "STICKY_PS1_2130W"
				CLEAR "STICKY_PS2_2130W"
				CLEAR "STICKY_REDUND_PS"
				CLEAR "HSBP_TEMP"
			ENDIF

			IFSET "SHIPPING"
				CLEAR "BCP_2U4N"
				CLEAR "SYS_FAN_2U4N"
				CLEAR "2U4N_BP_X35"
				CLEAR "2U4N_BP_X25"
				CLEAR "TEST_PLATE"
				CLEAR "STICKY_PS1_1600W"
				CLEAR "STICKY_PS2_1600W"
				CLEAR "STICKY_PS1_2130W"
				CLEAR "STICKY_PS2_2130W"
				CLEAR "STICKY_REDUND_PS"
				CLEAR "HSBP_TEMP"
				// Set additional SDR tags for the SHIPPING chassis
			ENDIF

			IFSET "TEST_PLATE"
				//System Fans
				DISPLAY " "
				PROMPT  "Is System Fan 1A installed (Y/N)?"
				YES     "SYSTEM_FAN_1A"
				NO      ""

				DISPLAY " "
				PROMPT  "Is System Fan 1B installed (Y/N)?"
				YES     "SYSTEM_FAN_1B"
				NO      ""

				DISPLAY " "
				PROMPT  "Is System Fan 2A installed (Y/N)?"
				YES     "SYSTEM_FAN_2A"
				NO      ""

				DISPLAY " "
				PROMPT  "Is System Fan 2B installed (Y/N)?"
				YES     "SYSTEM_FAN_2B"
				NO      ""

				DISPLAY " "
				PROMPT  "Is System Fan 3A installed (Y/N)?"
				YES     "SYSTEM_FAN_3A"
				NO      ""

				DISPLAY " "
				PROMPT  "Is System Fan 3B installed (Y/N)?"
				YES     "SYSTEM_FAN_3B"
				NO      ""

				DISPLAY " "
				PROMPT  "Is System Fan 4A installed (Y/N)?"
				YES     "SYSTEM_FAN_4A"
				NO      ""

				DISPLAY " "
				PROMPT  "Is System Fan 4B installed (Y/N)?"
				YES     "SYSTEM_FAN_4B"
				NO      ""

				DISPLAY " "
				PROMPT  "Is System Fan 5A installed (Y/N)?"
				YES     "SYSTEM_FAN_5A"
				NO      ""

				DISPLAY " "
				PROMPT  "Is System Fan 5B installed (Y/N)?"
				YES     "SYSTEM_FAN_5B"
				NO      ""

				DISPLAY " "
				PROMPT  "Is System Fan 6A installed (Y/N)?"
				YES     "SYSTEM_FAN_6A"
				NO      ""

				DISPLAY " "
				PROMPT  "Is System Fan 6B installed (Y/N)?"
				YES     "SYSTEM_FAN_6B"
				NO      ""

				PROMPT "Is a CPU Fan installed?"
				YES "SYSTEM_CPU_FAN"
				NO ""

				CLEAR "BCP_2U4N"
				CLEAR "SYS_FAN_2U4N"
				CLEAR "2U4N_BP_X35"
				CLEAR "2U4N_BP_X25"
			ENDIF

			// Clear temp tags used for setting STICKY tags (i.e. Power Supply tags).
			// This prevents Auto-Config from updating SDRs unnecessarily when a PS is removed.
			// NOTE: This feature only works on BMC FW 0.23 or later
			CLEAR "PS1"
			CLEAR "PS2"
			CLEAR "NO_PS1"
			CLEAR "NO_PS2"
			CLEAR "PS1_FRU_IPMI"
			CLEAR "PS2_FRU_IPMI"
			CLEAR "PS1_1600W"
			CLEAR "PS2_1600W"
			CLEAR "PS1_2130W"
			CLEAR "PS2_2130W"
			CLEAR "CONTINUE"

			// Update the SDR Repository with selected records
			IFSET "SKIP_UPDATE"
				// Do nothing
			ELSE
				// Update SDR Repository
				SDRNAME   "S7200AP.sdr"

				// Run the init agent so new SDR data is read and used
				RUN_INIT_AGENT
			ENDIF
		ENDIF // SDR

		//*****************************************************************************
		// FRU file or asset tag programming
		//*****************************************************************************
		// Process Asset tag if requested.
		IFSET "ASSET"
			FRUNAME     "SYSTEM"
			FRUADDRESS  "IMBDEVICE" FF 20
			FRUAREA     "PRODUCT"
			FRUFIELD    "AT" "@STDIN:ASCII"
		ELSE
			// Begin baseboard FRU update
			IFSET "FRU"
				IFSET "NO_ADP_FRU"
					DISPLAY " "
					DISPLAY "FRU Board P/N data is invalid."
					CLEAR "NO_ADP_FRU"
				ELSE
					DISPLAY     " "

					FRUNAME     "S7200AP.fru"
					FRUAREA     "HEADER"
					FRUAREA     "INTERNALUSE"
					FRUAREA     "CHASSIS"
					FRUFIELD    "CT"

					PROMPT      "Do you want to update the chassis info area of the FRU (Y/N)?"
					YES         "UPD_CHS"
					NO          ""

					IFSET "UPD_CHS"
						DISPLAY     " "

						PROMPT      "Do you want to enter the chassis serial number (Y/N)?"
						YES         "CHASS_SN"
						NO          ""

						IFSET       "CHASS_SN"
							FRUFIELD    "S#" "@STDIN:ASCII"
						ENDIF

						DISPLAY     " "

						PROMPT      "Do you want to enter the chassis part number (Y/N)?"
						YES         "CHASS_PN"
						NO          ""

						IFSET       "CHASS_PN"
							FRUFIELD    "P#" "@STDIN:ASCII"
						ENDIF

						DISPLAY     " "
						PROMPT    "Do you want to enter data into the additional chassis field 1 (Y/N)?"
						YES         "CHASS_INFO_1"
						NO          ""

						IFSET       "CHASS_INFO_1"
							FRUFIELD  "AM1" "@STDIN:ASCII"
						ENDIF

						DISPLAY    " "

						PROMPT    "Do you want to enter data into the additional chassis field 2 (Y/N)?"
						YES         "CHASS_INFO_2"
						NO          ""

						IFSET       "CHASS_INFO_2"
							FRUFIELD  "AM2" "@STDIN:ASCII"
						ENDIF
					ENDIF

					IFSET "ALLOW_BRD_UPDATE"
						CLEAR "ALLOW_BRD_UPDATE"
						PROMPT  "Do you want to update Board info area of the FRU (Y/N)?"
						YES     "UPD_BRD"
						NO      ""

						IFSET "UPD_BRD"
							// Update board area
							FRUAREA     "BOARD"
							FRUFIELD    "P#"
							FRUFIELD    "S#"

							DISPLAY      " "
							PROMPT      "Do you want to enter the Board part number (Y/N)?"
							YES         "BRD_PN"
							NO          ""

							IFSET "BRD_PN"
								FRUFIELD    "P#" "@STDIN:ASCII"
							ENDIF

							DISPLAY     " "

							PROMPT      "Do you want to enter the Board serial number (Y/N)?"
							YES         "BRD_SN"
							NO          ""

							IFSET "BRD_SN"
								FRUFIELD    "S#" "@STDIN:ASCII"
							ENDIF
						ENDIF
					ENDIF

					DISPLAY     " "

					FRUAREA     "PRODUCT"
					PROMPT      "Do you want to update the product info area of the FRU (Y/N)?"
					YES     "UPD_PRD"
					NO      ""

					IFSET "UPD_PRD"
						FRUFIELD    "MN"
						FRUFIELD    "PN"
						FRUFIELD    "PV"
						DISPLAY      " "
						PROMPT      "Do you want to enter the product Version (Y/N)?"
						YES         "PROD_PV"
						NO          ""

						IFSET "PROD_PV"
							FRUFIELD    "PV" "@STDIN:ASCII"
						ENDIF

						DISPLAY     " "

						PROMPT      "Do you want to enter the product part number (Y/N)?"
						YES         "PROD_PN"
						NO          ""

						IFSET "PROD_PN"
							FRUFIELD    "P#" "@STDIN:ASCII"
						ENDIF

						DISPLAY     " "

						PROMPT      "Do you want to enter the product serial number (Y/N)?"
						YES         "PROD_SN"
						NO          ""

						IFSET "PROD_SN"
							FRUFIELD    "S#" "@STDIN:ASCII"
						ENDIF

						DISPLAY     " "

						PROMPT      "Do you want to enter a product asset tag (Y/N)?"
						YES         "PROD_ASSET"
						NO          ""

						IFSET "PROD_ASSET"
							FRUFIELD    "AT" "@STDIN:ASCII"
						ENDIF
					ENDIF
				ENDIF	// FRU PN
			ENDIF	// FRU
		ENDIF	// Asset
	ENDIF	// Not EXIT1
ENDIF	// S7200AP

