@ECHO OFF
REM *****MICROPROSE INSTALLER, MULTI-DISK (ZIP) VERSION, V1*****

:TITLE
CLS
IF NOT EXIST CHOOSE.COM GOTO ERROR     
ECHO                          MEGATRAVELLER 2
ECHO                      HARD DRIVE INSTALLATION
ECHO.
ECHO.
ECHO NOTE - YOU MUST HAVE AT LEAST 3 MB FREE ON YOUR HARD DRIVE IN ORDER 
ECHO        TO INSTALL THE GAME! (PRESS ESC TO EXIT INSTALLATION, OR ANY
ECHO        OTHER KEY TO CONTINUE.)
CHOOSE.COM
IF ERRORLEVEL 01 IF NOT ERRORLEVEL 02 GOTO END

:FLOPPIES
CLS
ECHO WHICH FLOPPY DRIVE ARE YOU INSTALLING FROM (A OR B)? (ESC TO EXIT)
:FIRSTCHOICE
CHOOSE.COM 
IF ERRORLEVEL 48 IF NOT ERRORLEVEL 49 GOTO CHOICEB
IF ERRORLEVEL 30 IF NOT ERRORLEVEL 31 GOTO CHOICEA
IF ERRORLEVEL 01 IF NOT ERRORLEVEL 02 GOTO END
GOTO FLOPPIES

:CHOICEA
SET FLOPPY=A:
GOTO HDCHOICE

:CHOICEB
SET FLOPPY=B:
GOTO HDCHOICE

:HDCHOICE
CLS
IF NOT EXIST %FLOPPY%\INSTALL.BAT GOTO NOFLOPPY
ECHO INSTALLING FROM DRIVE %FLOPPY%.
ECHO. 
ECHO WHICH HARD DRIVE OR PARTITION ARE YOU INSTALLING TO (C OR D)? (ESC TO EXIT)
CHOOSE.COM
IF ERRORLEVEL 46 IF NOT ERRORLEVEL 47 GOTO HARDC
IF ERRORLEVEL 32 IF NOT ERRORLEVEL 33 GOTO HARDD
IF ERRORLEVEL 01 IF NOT ERRORLEVEL 02 GOTO END
GOTO HDCHOICE

:HARDC
SET HARDDISK=C:
GOTO INSTALLER

:HARDD
SET HARDDISK=D:
GOTO INSTALLER

:INSTALLER
CLS
IF NOT EXIST %HARDDISK%\*.* GOTO NOTTHERE
ECHO INSTALLING GAME FILES FROM %FLOPPY% TO %HARDDISK%\MT2
ECHO.
ECHO IS THIS CORRECT? (Y/N)
CHOOSE.COM
IF ERRORLEVEL 49 IF NOT ERRORLEVEL 50 GOTO FLOPPIES
IF ERRORLEVEL 21 IF NOT ERRORLEVEL 22 GOTO PROCEED
GOTO INSTALLER

:PROCEED
MD %HARDDISK%\MT2
PKUNZIP %FLOPPY%\MT2.ZIP %HARDDISK%\MT2
CLS
%HARDDISK%
CD\MT2


:SUCCESS
ECHO.
ECHO GAME FILES SUCCESSFULLY INSTALLED. TO START THE GAME, TYPE MT2
ECHO AND HIT ENTER.
ECHO.
APPEND ;
GOTO END

:ERROR
CLS
ECHO YOU MUST BE AT THE PROMPT FOR YOUR INSTALLATION DRIVE (A: OR B:)
ECHO IN ORDER TO RUN INSTALL.  PLEASE SWITCH TO THE CORRECT PROMPT AND TYPE
ECHO INSTALL TO TRY AGAIN.
GOTO END

:NOTTHERE
CLS
ECHO THE DRIVE %HARDDISK% DOES NOT EXIST, OR IS NOT A VALID INSTALLATION DRIVE.
PAUSE
GOTO FLOPPIES

:NOFLOPPY
CLS
ECHO THERE IS A PROBLEM READING DRIVE %FLOPPY%.  
PAUSE
GOTO FLOPPIES


:END
ECHO.
ECHO.
ECHO.
