// TDC fix
@DefineProject
	@Name = "Zoop"
	@Version = "1.0"
	@OutDrive = C
	@SubDir = "\\ZOOP\\"
	@immediate = 1
	@Requires @Harddisk
@EndProject

@DefineVars
	@Integer @ErrorCode = 0
@EndVars

START:

@GetOutDrive

//	@Suppress A
//	@Suppress B
	@Suppress Z
	@LocalWindow(6,38)
	@Cls
	Please choose the drive on which to install ZOOP (tm)

@EndOutDrive

@If (@Removable)
	@Display
	You can't install @Name onto a floppy drive!

	@Pause
	@Goto START
	@EndDisplay
@EndIf

@GetSubDir
    Which directory should ZOOP (tm) be installed in?
    @Prompt = "Please Enter The Subdirectory Name:"
@EndSubDir

@If (@Exists "@OutDrive:\\@SubDir")
	@GetGroups
	@LocalWindow(5,38)
	@SET Y = "Yes"
	@SET N = "No"
	@Cls
	That directory exists, still want to use it?

	@EndGroups

	@If ('N' [= @Group)
	 @Goto START
	@EndIf
@Endif

@if (@DiskFree @OutDrive < 5000000)
	@Display
	@Cls

	The drive space on @OutDrive: doesn't have enough room.
	You'll need to have at least 5,000,000 bytes free.
	Your disk only has @DiskFree bytes free.

	@EndDisplay
	@Pause
	@Exit
@endif

	@MkDir("@OutDrive:\\@SubDir")

@Display

Installing ZOOP (tm) - Please Wait . . .

	Copying Disk contents ...
	@Copy(".\\README.TXT", "@OutDrive:\\@SubDir\\README.TXT")
	@Copy(".\\ZOOP1.EXE", "@OutDrive:\\@SubDir\\ZOOP1.EXE")
	@If(@Exists ".\\DISK2\\ZOOP2.EXE")
		@Copy(".\\DISK2\\ZOOP2.EXE", "@OutDrive:\\@SubDir\\ZOOP2.EXE")
	@Else
		@Copy(".\\ZOOP2.EXE", "@OutDrive:\\@SubDir\\ZOOP2.EXE")
	@EndIf
	@ChDrive @OutDrive
	@ChDir "@SubDir"
	Ready to extract Disk content, this may take a few moments ...
	
	@Pause
@EndDisplay

@ErrorCode = @Spawn("ZOOP1.EXE -x -i -y -g3121x >NUL")
  @If ( @ErrorCode == 0 )
  	@Display
  	Completed extracting DISK 1
  	@Pause
  	@EndDisplay
  @Else
	@GetOption
	There was an error extracting content for DISK 1. Continue?
	@Option 1 = "Yes"
	@Option 2 = "No"
	@EndOption
    @If ( 2 [= @Option ) 
	@ClearOption( 2 )
	@Abort
    @Endif
  @Endif

@ErrorCode = @Spawn("ZOOP2.EXE -x -i -y -g3121x >NUL")
  @If ( @ErrorCode == 0 )
  	@Display
  	Completed extracting DISK 2
  	@Pause
  	@EndDisplay
  @Else
	@GetOption
	There was an error extracting content for DISK 2. Continue?
	@Option 1 = "Yes"
	@Option 2 = "No"
	@EndOption
    @If ( 2 [= @Option ) 
	@ClearOption( 2 )
	@Abort
    @Endif
  @Endif

        @If(@Exists "@OutDrive:\\@SubDir\\ZOOP1.EXE")
            @Delete  ("@OutDrive:\\@SubDir\\ZOOP1.EXE")
        @EndIf
        @If(@Exists "@OutDrive:\\@SubDir\\ZOOP2.EXE")
            @Delete  ("@OutDrive:\\@SubDir\\ZOOP2.EXE")
        @EndIf	

@Display


    Note about Setsound:
    	Setsound is a utility to assist in setting up sound for Zoop (tm).
    	It does not incorporate a full auto-detect feature. You must know
    	the type of sound card that you use and choose it during the
    	running of Setsound. If you do not know what type of Sound card
    	you have, check the documentation that was supplied with your
    	computer, or contact your retailer or computer manufacturer.

    WARNING: You must setup both Midi and Digital for any sound
             to work properly.

    If you have a Compaq computer:
	Some Compaq computers are sold with sound cards from ESS
	Technologies. If you have this combination, you must choose
	Sound Blaster Pro as both your Digital and Midi devices while
	in Setsound.

	@Pause

@EndDisplay

	@ErrorCode = @Spawn("SETSOUND.EXE")

@Display

	@Cls

    Note:
	If you have one of the following Graphic Adapters, or ZOOP (tm)
	is not displaying properly, be sure to follow the instructions
	in README.TXT to configure properly.
	
	Matrox MGA Ultima
	Hercules Graphite
	Diamond Viper
	Orchid Fahrenheit
	Orchid Celsius
	
	@Pause

@EndDisplay

@Finish


@EndFinish

 
