Plot 0
	% This plot is meant to be a complete adventure, which
	% hopefully will take a certain amount of time to complete.
	% It may also make the PC a powerful enemy, in the form of
	% a villanous corporate executive.
	name <PLOT: Biotech Enemy>
	rumor <lately monsters have been appearing for no natural reason.>

	% V1 = Time Limit
	% V2 = Have been given mission by E2.
	% V3 = Combat Indicator

	% Lots of elements for this one.
	Element1 <Scene Town>
	Element2 <Character Leader !Far 1>
	Element3 <Character Shy !Near 2>
	Element4 <Character Guardian !Near 2>
	Element5 <Character Guardian !Far 2 !Far 1>
	Element6 <Character Corporate Villainous>
	Element7 <Prefab>
	% Element 8 = Difficulcy Rating


	% Time limit code.
	START <ifPersona E2 else GoDelete ifPersona E3 else GoDelete ifPersona E4 else GoDelete if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 50000>
	GotoCheckTime <ifG ComTime V1 if= V2 0 AdvancePlot 0  DeleteChar E7>
	GoDelete <AdvancePlot 0  DeleteChar E7>

	% If combat has been entered, V3 = 1. This is important to keep
	% the events below from activating in scenes other than the
	% plot's combat...
	NU1 <if= T1 0 if= V3 1 Reputation 6 -1          V= 3 0>
	NU2 <if= T2 0 if= V3 1 XPV 75 Reputation 1 1    V= 3 0 V= 2 2>


sub
	Persona 2
	rumor <monsters have been sighted near town! !2 is looking for someone to investigate.>
	greeting <NewChat if= P2 3 else GoWonBattle1 Say 24>
	GoWonBattle1 <if= P2 2 else GoOnTheCase CashPrize 5000 ifPersona E5 else GoStopHere Say 22 P= 2 3>
	GoStopHere <Say 23 Goto GoCleanUp>
	GoOnTheCase <if= P2 1 else GoFirstTime say 21>
	GoFirstTime <ifG React 70 else goHiReact Say 1 AddChat 1 AddChat 2>
	goHiReact <ifG React 51 else GoMedReact Say 2 AddChat 3 AddChat 4 AddChat 5>
	GoMedReact <ifG React 20 else GoLowReact Say 3 AddChat 6 AddChat 7 AddChat 8>
	GoLowReact <ifG React 0 else GoNoReact Say 4 AddChat 8 AddChat 9>
	GoNoReact <ifG PCRep 1 d100 else GoNoHero Say 5 AddChat 3 AddChat 5 AddChat 8>
	GoNoHero <ifG PCRep 6 48 else GoNoChance Say 6 AddChat 8 AddChat 9>
	GoNoChance <Say 7>

	GoCleanUp <AdvancePlot 0  DeleteChar E7>

	result1 <NewChat Say 8  AddChat 10 AddChat 11>
	result1 <NewChat Say 9  AddChat 10 AddChat 11>
	result3 <NewChat Say 10  AddChat 12 AddChat 13>
	result4 <NewChat Say 11  AddChat 12 AddChat 13>
	result5 <NewChat Say 12  Goto GoCleanUp>
	result6 <NewChat Say 13  P= 2 1>
	result7 <NewChat Say 14  Goto GoCleanUp>
	result8 <NewChat Say 15  AddChat 12 AddChat 13>
	result9 <NewChat Say 16  AddChat 8  Reputation 3 -1>
	result10 <NewChat Say 17  P= 2 1>
	result11 <NewChat Say 18  Goto GoCleanUp>
	result12 <NewChat Say 19  P= 2 1>
	result13 <NewChat Say 20  Goto GoCleanUp>

	Msg1 <It's good to see you again. How have your travels been going?>
	Msg2 <I'm glad to see you today. Our town has a situation now which I could use your help with, if you are free to help me...>
	Msg3 <Certain strange animals have been spotted near town. I need a skilled adventurer to investigate the situation. Would you be interested in this job?>
	Msg4 <Have you come because you've heard about our situation?>
	Msg5 <I don't particularly like you, but our town needs someone right now. I have a job you may be able to do. Will you help us?>
	Msg6 <Hmmm... What do you want here? If you came because you heard about our situation, I guess I'll have to fill you in on it... this is no time for me to get choosy.>
	Msg7 <There are a lot of things for me to take care of right now.>
	Msg8 <That's good to hear. I wish I could say the same... There have been problems in town. Strange creatures have been spotted on the outskirts; everyone is worried. I could really use your help to investigate this matter.>
	Msg9 <That's too bad, and I can't even offer you any good news myself. A strange creature has been spotted just outside of town. I could really use your help to investigate the matter, if you're avaliable.>
	Msg10 <This is the situation: A strange creature has been spotted outside of town, the citizens are nervous, and I need someone to investigate the matter. I'll pay $5000 for the job. Are you interested?>
	Msg11 <A strange creature has been spotted outside of town. As you may know, we've had problems with monsters of various sorts in the past... The citizens are duly worried, and I need someone to investigate. Pay is $5000 if you're interested.>
	Msg12 <Okay, I understand.>
	Msg13 <There's a reward of $5000 for either locating or slaying the creature. \PERSONA E3 was the last one to actually see it.>
	Msg14 <Then I guess I should get back to work. Good day.>
	Msg15 <A strange creature has been sighted just outside of town. There's a reward of $5000 for either locating or destroying it. Are you up for this job?>
	Msg16 <You haven't heard about it? It's all that everyone has been talking about lately... Are you some kind of recluse? Anyhow, it has to do with a monster...>
	Msg17 <Wonderful! \PERSONA E3 was the most recent person to see this thing. Maybe you can find out where it is? There will be a reward of $5000 for either capturing or eliminating the creature.>
	Msg18 <That is most regretable. I wish you the best of luck in your current endeavors.>
	Msg19 <\PERSONA E3 is the only person to have seen this creature and lived. Go find our where this encounter took place, and search the area.>
	Msg20 <I must find someone else, then.>
	Msg21 <Speak to \Persona E3 about the creature.>
	Msg22 <Very good work out there. Here's your reward... The next task will be finding out where these things came from. \PERSONA E4 has been trying to get a sample of their blood for the \SCENE EScene E5 forensics lab.>
	Msg23 <Everything should return to normal now that the monsters have been eliminated. Hopefully there aren't any more...>
	Msg24 <Have you spoken to \PERSONA E4 about the creature's blood sample yet?>

	Prompt1 <I've been doing well.>
	Prompt2 <Not so good, I'm afraid...>
	Prompt3 <Of course I'll help.>
	Prompt4 <What kind of situation?>
	Prompt5 <Actually I'm kind of busy.>
	Prompt6 <Definitely.>
	Prompt7 <No, I wouldn't.>
	Prompt8 <Tell me the details.>
	Prompt9 <Situation? What situation?>
	Prompt10 <I am avaliable.>
	Prompt11 <I have other problems now.>
	Prompt12 <I'll do it.>
	Prompt13 <No, not really.>


	Persona 3
	% V1 = Can ask about location now.
	rumor <!3 has been very nervous these days.>
	greeting <NewChat ifG P2 1 else GoOnTheCase Say 9>
	GoOnTheCase <if= P2 1 else GoNoCase if= V1 0 else GoSecondTime Say 2  AddChat 1 AddChat 2>
	GoNoCase <say 1>
	GoSecondTime <Say 8 AddChat 4 AddChat 5>

	result1 <NewChat  V= 1 1  Reputation 7 1  AddChat 3  ifG SkRoll 19 11 else GoR1NoCon  Say 3>
	GoR1NoCon <AddReact -5 AddReact d5 Say 4>
	result2 <NewChat  V= 1 1  Reputation 3 1  AddChat 3  ifG SkRoll 19 5 else GoR2NoCon AddReact d8 Say 6>
	GoR2NoCon <Say 5>
	result3 <NewChat  Say 7  AddChat 4 AddChat 5>
	Result4 <EndChat  Say 10  P= 3 1  SavePos  MDynamic 0 PCRep 6 .enemydata FrzNU1 FrzNU2>
	FrzNU1 <if= T1 0 Return>
	FrzNU2 <if= T2 0 Return>
	.enemydata <Mutant Synth>

	Msg1 <I can't feel safe here any more...>
	Msg2 <Not even our community is safe any more...>
	Msg3 <It was horrible. I never got a good look at it, but the smell... It was like formaldehyde, or some other kind of chemical.>
	Msg4 <I can't! I mean, I don't know! I never got a very good look at it. I don't want to talk...>
	Msg5 <No, not particularly okay... That thing I saw. They say it's killed other people. We don't even know what it was...>
	Msg6 <I'm far too shaken up... that thing out there could have killed me. They say it's what murdered those people last week...>
	Msg7 <I can show you... are you planning to go there? Be careful. If it's still in the area it might be very dangerous.>
	Msg8 <It's still out there, I know... are you planning to go back to the place?>
	Msg9 <The monsters are gone... finally I can sleep again.>
	Msg10 <Good luck.>

	Prompt1 <Tell me about the monster.>
	Prompt2 <Are you okay?>
	Prompt3 <Can you tell me where you saw it?>
	Prompt4 <I'm ready to go now.>
	Prompt5 <Maybe I'll go there later.>


	Persona 4
	rumor <there have been some disappearances which may be connected to that mysterious creature.>
	greeting <NewChat if= P2 3 else GoNotYet AdvancePlot 1  Say 1 AddChat 1 ifG SkRoll 29 8 AddChat 2>
	GoNotYet <SayAnything>

	result1 <NewChat  Reputation 1 1  Say 2>
	result2 <NewChat  Reputation 6 1 Reputation 7 1 Say 3>

	Msg1 <I obtained some tissue samples from the place where you fought those creatures. The guardian office in \SCENE ESCene 5 had a similar case just a few weeks ago.>
	Msg2 <That might be a good idea. Unless we can find out where these monsters are coming from, we'll probably never be rid of them.>
	Msg3 <I suspect you may be right. The lab should be able to tell us whether these are mutants, biostructs, or what else... If you want to continue working on this case, talk to \PERSONA E5 in \SCENE EScene 5 about it.>

	Prompt1 <Maybe I should go there...>
	Prompt2 <These aren't natural creatures.>


	PLOT 1
		% The first creatures have been destroyed. Now the PC
		% will travel to location 5.
		rumor <there have been far too many monsters appearing in the wilds. Something mysterious must be happening.>

		% V1 = Timer
		% V2 = Phase
		% V3 = Combat Indicator

		% Time limit code.
		START <ifPersona E5 else GoDelete if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 250000>
		GotoCheckTime <ifG ComTime V1 if= V2 0 AdvancePlot 0  DeleteChar E7>
		GoDelete <AdvancePlot 0  DeleteChar E7>

		% If combat has been entered, V3 = 1. This is important to keep
		% the events below from activating in scenes other than the
		% plot's combat...
		NU1 <if= T1 0 if= V3 1 Reputation 6 -1           V= 3 0>
		NU2 <if= T2 0 if= V3 1 XPV 100 Reputation 1 1    V= 3 0 V= 2 2>

	sub
		Persona 4
		rumor <!4 is still busy investigating those strange creatures.>
		greeting <NewChat Say 1 AddChat 1>
		result1 <NewChat Say 2>
		Msg1 <I'm still waiting to get the lab work back on those bio-samples.>
		Msg2 <Well, I told you that the guardians in \SCENE ESCene 5 have recently encountered similar monsters. You should probably go see if you can learn anything from them.>
		Prompt1 <Where did you tell me to go?>

		Persona 5
		% V1 = Can go to cave.
		rumor <!5 was badly injured while fighting a monster.>
		greeting <NewChat if= P2 2 else GoOnMission AddReact d6 CashPrize 7500 ifPersona E7 else GoNoContinue ifPersona E6 else GoNoContinue Say 11 AdvancePlot 2>
		GoNoContinue <Say 12 DeleteChar E7 AdvancePlot 0>
		GoOnMission <if= V1 1 else GoFirstTime Say 10 AddChat 3>
		GoFirstTime <P= 2 1 AddChat 1 ifG React 50 else GoMedReact ifG PCRep 6 25 else GoHRNoRep Say 1>
		GoHRNoRep <Say 2>
		GoMedReact <ifG React 25 else GoLowReact ifG PCRep 6 d30 else GoMRNoRep Say 3>
		GoMRNoRep <Say 4>
		GoLowReact <Say 5>

		Result1 <NewChat Say 6 AddChat 2>
		Result2 <NewChat Say 7 V= 1 1 AddChat 3 AddChat 4>
		Result3 <EndChat  Say 8  P= 3 1  SavePos  MDynamic 0 PCRep 6 .enemydata FrzNU1 FrzNU2>
		FrzNU1 <if= T1 0 Return>
		FrzNU2 <if= T2 0 Return>
		.enemydata <Mutant Synth>
		result4 <NewChat Say 9>

		Msg1 <You did a fine job of hunting down the \SCENE ESCENE 4 monsters, as usual. I had a bit more trouble with the ones we had over this way. Got myself a few new scars...>
		Msg2 <I'm glad to see you... I heard that you had fought some creatures in \SCENE ESCENE 4 a while back but nobody could say whether or not you survived.>
		Msg3 <I heard what happened in \SCENE ESCENE 4 a while ago. We've been seeing the same kind of monsters around here recently...>
		Msg4 <What were you thinking, going out after the monsters in \SCENE ESCENE 4 like that! You could've been killed! I got hurt myself going after them, and I've got a whole lot more experience in these matters than you do!>
		Msg5 <The wilds outside of town have been infested with monsters. Travellers are advised to be extremely cautious.>
		Msg6 <There's not a lot I can tell you. They seem to be originating from a cave just to the north of town. We've been trying to find out where they come from, but need a larger tissue sample than we currently have for analysis.>
		Msg7 <Okay, I'll show you the way. Are you certain that you want to go right now? Do you need to repair your equipment or anything first?>
		Msg8 <I'll take you near the cave... After that you'll have to proceed on your own, I'm afraid.>
		Msg9 <It's probably not a good idea to go there unless you're fully prepared.>
		Msg10 <There have been a few more sightings of the creatures. Are you ready to head out?>
		Msg11 <Thanks to you, we now have a few mostly complete carcasses to do testing on. Come back in a little while and I may have some interesting results. Oh, and here's a reward for helping to protect our city.>
		Msg12 <Well, we have the carcasses now, but I doubt we'll find anything useful... Thanks for your efforts, though. Here's a reward.>

		Prompt1 <Tell me about these monsters.>
		Prompt2 <Show me the cave; I'll get you a sample.>
		Prompt3 <I'll go now.>
		Prompt4 <Maybe I should rest up first.>



	PLOT 2
		% The player has defeated the monsters, and the
		% guardians will now trace their construction to
		% character E7.
		rumor <there have been far too many monsters appearing in the wilds. I wonder what could be the reason?>

		% V1 = Timer
		% V2 = Phase
		% V3 = Combat Indicator
		% V4 = Agreed to lie

		% Time limit code.
		START <ifPersona E5 else GoDelete ifPersona E6 else GoDelete ifPersona E7 else GoDelete if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 250000>
		GotoCheckTime <ifG ComTime V1 if= V2 0 AdvancePlot 0  DeleteChar E7>
		GoDelete <AdvancePlot 0  DeleteChar E7>
	SUB
		Persona 4
		rumor <!4 has discovered the source of all those monsters!>
		greeting <NewChat if= P2 2 else GoFirst Say 6 AddChat 4 if= P4 1 AddChat 5>
		GoFirst <if= P2 0 else GoAlreadyKnow Say 1 AddChat 1>
		GoAlreadyKnow <Say 4>

		result1 <NewChat P= 2 1 Say 2 AddChat 2>
		result2 <NewChat Say 3>
		result3 <NewChat Say 5>
		result4 <NewChat Say 7 XPV 200 Reputation 1 1 AdvancePlot 3>
		result5 <NewChat Say 8 Reputation 1 -2 Reputation 2 -3 AdvancePlot 4>

		Msg1 <The blood sample I took from the monsters you defeated has paid off! The lab report just got in, and it's got some good info.>
		Msg2 <These creatures are not natural, not even mutants... They're self-replicating biostructs. Someone must have built them and released them into the wild.>
		Msg3 <Not entirely, but an elemental analysis of the blood has connected it to a pharmeceuticals lab in the \SCENE ESCENE 7 area.>
		Msg4 <I'm still working on the biostruct case. Hopefully we can catch the perpetrator before any more of these horrors are released.>
		Msg5 <That the monsters were synthetic, and that they were probably built in \SCENE ESCENE 7 or someplace nearby.>
		Msg6 <Did your investigation in \SCENE EScene 7 turn up anything?>
		Msg7 <Good work... I'll get in touch with the \SCENE EScene 7 guardians and have him picked up for questioning right away.>
		Msg8 <That's very strange. Well, I guess we'll just have to hope that no more monsters ever show up...>

		Prompt1 <Well, what did it say?>
		Prompt2 <Any idea who?>
		Prompt3 <What did the report say again?>
		Prompt4 <\PERSONA E7 created the monsters.>
		Prompt5 <I didn't find out anything.>


		Persona 5
		greeting <NewChat if= P2 2 else GoFirst  Say 6 AddChat 4 if= P4 1 AddChat 5>
		GoFirst <if= P2 0 else GoAlreadyKnow if= V1 0 else GoCheckTime Say 1 V= 1 ComTime V+ 1 18000>
		GoCheckTime <ifG ComTime V1 else GoWait Say 3 P= 2 1>
		GoWait <Say 2>
		GoAlreadyKnow <Say 3>

		result4 <NewChat Say 7 XPV 200 Reputation 1 1 AdvancePlot 3>
		result5 <NewChat Say 8 Reputation 1 -2 Reputation 2 -3 AdvancePlot 4>

		Msg1 <It's going to be at least five hours before I know anything here. If you have any other leads on this case, you may want to check them up.>
		Msg2 <There's still no word back from the forensics lab.>
		Msg3 <The lab report finally arrived! The creatures have been linked to a \SCENE ESCENE 7 pharmeceutical company.>
		Msg6 <Did your investigation in \SCENE EScene 7 turn up anything?>
		Msg7 <Good work... I'll get in touch with the \SCENE EScene 7 guardians and have him picked up for questioning right away.>
		Msg8 <That's very strange. Well, I guess we'll just have to hope that no more monsters ever show up...>

		Prompt4 <\PERSONA E7 created the monsters.>
		Prompt5 <I didn't find out anything.>


		Persona 7
		rumor <!7 has been conducting strange experiments.>
		greeting <NewChat if= P2 2 else GoFirst Say 13 ifG 1 P4 RunAway E7>
		GoFirst <if= P2 0 else GoSuspect SayAnything>
		GoSuspect <ifG PCRep 6 75 else GoNoRep Say 1 AddChat 1 AddChat 2>
		GoNoRep <ifG 0 PCRep 2 else GoLawful Say 2 AddChat 1 AddChat 3 AddChat 4>
		GoLawful <Say 3 AddCHat 1 AddChat 4>

		result1 <NewChat P= 2 2  Say 4  AddReact -15  AddChat 5 AddChat 6>
		result2 <NewChat P= 2 2  Say 5  AddChat 7 AddChat 8 AddChat 9>
		result3 <NewChat P= 2 2  Say 6  AddChat 1 AddChat 4>
		result4 <NewChat P= 2 2  Say 7  AddChat 5 AddChat 6>
		result5 <NewChat P= 2 2  Say 8  AddChat 7 AddChat 8 AddChat 9>
		result6 <NewChat P= 2 2  Say 9  AddChat 7 AddChat 8 AddChat 9>
		result7 <EndChat Say 10  Reputation 2 1  AddReact -30  RunAway E7>
		result8 <EndChat Say 11>
		result9 <EndChat Say 12  Reputation 2 -1  P= 4 1>

		Msg1 <Huh? W-What do you want with me?>
		Msg2 <What do you want? Are you looking for something? I'm afraid I don't handle the sales end of things myself...>
		Msg3 <What do you want? You better have a good reason for wasting my time.>
		Msg4 <Monsters? What would you know! My beautiful creations are not monsters... they are the next stage in weapons technology!>
		Msg5 <You already know why I'm so nervous! You killed them all! My beautiful creations, you destroyed them! Look, maybe we can have some kind of agreement...>
		Msg6 <Like I said, I don't do sales myself. You'll have to go to \SCENE EScene 6 if you want to buy something.>
		Msg7 <I am busy creating the future of weapons technology!>
		Msg8 <You don't know what you're dealing with here. Powerful interests are backing my research... Interfere and you could be making some very powerful enemies. Surely we can make some agreement...>
		Msg9 <You're asking too many questions... I know why you're here. There are some very powerful people interested in my research, people you don't want to be enemies with. Surely we can make some kind of deal...>
		Msg10 <You'll have to catch me first.>
		Msg11 <You do that.>
		Msg12 <A smart decision. You come back here after you've spoken to the guardians and I'll see what I can do for you.>
		Msg13 <I'm too busy for you today.>

		Prompt1 <I'm investigating biotech monsters.>
		Prompt2 <Why are you so nervous?>
		Prompt3 <I'm looking for something illegal.>
		Prompt4 <What kind of work do you do?>
		Prompt5 <I'm going to put you away.>
		Prompt6 <Who's funding your work?>
		Prompt7 <No deal. You're going down.>
		Prompt8 <I'll think about it.>
		Prompt9 <Okay, I'll derail the investigation.>

	PLOT 3
		% The player has turned in E7. E6 will become the
		% player's enemy, and E7 will end up murdered.

		% Time limit code.
		START <if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 250000 DeleteChar E7  PCEnemy E6>
		GotoCheckTime <ifG ComTime V1 AdvancePlot 0>

	SUB
		Persona 4
		greeting <NewChat if= P1 0 else Go2 Say 1>
		Go2 <Say 2 AdvancePlot 0>
		Msg1 <Thanks for your help! Our men are now in the process of tracking down the scientist you found.>
		Msg2 <The scientist you spoke with... Before our men could arrest him, he was found murdered. There's something big going on and I don't like it one bit.>

		Persona 5
		greeting <NewChat if= P1 0 else Go2 Say 1>
		Go2 <Say 2 AdvancePlot 0>
		Msg1 <Thanks for your help! Our men are now in the process of tracking down the scientist you found.>
		Msg2 <The scientist you spoke with... Before our men could arrest him, he was found murdered. There's something big going on and I don't like it one bit.>


	% END PLOT 3 SUBCOMS
	END

	PLOT 4
		% The player has derailed the guardian investigation.
		% E7 will reward the player financially.

		% Time limit code.
		START <if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 250000>
		GotoCheckTime <ifG ComTime V1 if= V2 0 AdvancePlot 0>
	SUB
		Persona 7
		greeting <NewChat Say 1 CashPrize 10000 AdvancePlot 0>
		Msg1 <You covered me, here's some cash for your trouble.>

	% END PLOT 4 SUBCOMS
	END


	% END PLOT 2 SUBCOMS
	END

	% END PLOT 1 SUBCOMS
	end

% END PLOT 0 SUBCOMS
end
inv
	NPC Scientist
	% The mad scientist who created the monsters for E6.
	Chardesc Old Shy Wangtta Villainous Chaotic
	Place <1 PASS>
end
