Plot 0
	name <PLOT: CorpJob1>
	% VARIABLES USED
	% 1 -> Time Limit Timer
	% 2 -> Combat Indicator

	element1 <Character Corporate>

	rumor <!1 is planning to hire a mecha pilot.>

	% Time limit - this plot will fade after a short time.
	START <if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 120000>
	GotoCheckTime <ifG ComTime V1 if= V2 0 AdvancePlot 0>

	% If combat has been entered, V2 = 1. This is important to keep
	% the events below from activating in scenes other than the
	% plot's combat...
	NU1 <if= T1 0 if= V2 1 AdvancePlot 1 Reputation 6 -8          V= 2 2>
	NU2 <if= T2 0 if= V2 1 AdvancePlot 2 XPV 50 Reputation 6 1    V= 2 2>

sub
	Persona 1
	% The NPC who will offer the job.
	% PCs who don't have mecha will be sent elsewhere...
	% Only PCs with good reaction score will be offered a job.
	greeting <NewChat ifG PCMeks 0 else GoNoMeks ifG React 35 else GoMedReact Goto GoJobDesc>

	% PCs with a medium reaction score have a chance to get offered a job,
	% if they make a good impression on the NPC.
	GoMedReact <ifG React 0 else GoLowReact Say 3 AddChat 1 AddChat 2 AddChat 3>

	% PCs with a low reaction score will most likely be told to buzz off.
	GoLowReact <NewChat SayAnything>

	% With no meks, the PC won't get offered a job at all, but may be told
	% about it.
	GoNoMeks <ifG React 50 else GoNMMedReact Say 1>
	GoNMMedReact <SayAnything>

	% Result 1 -> The player will try to charm the NPC with RENOWN
	result1 <ifG PCRep 6 10 else GoNoRep NewChat Say 8 AddChat 4 AddChat 5>
	GoNoRep <NewChat Say 7>

	% Result 2 -> The player will try to impress the NPC with INTIMIDATION
	result2 <Reputation 2 -1 ifG SkRoll 28 5 else GoNoInt NewChat Say 9 AddChat 4 AddChat 5>
	GoNoInt <AdvancePlot 0 Say 6 EndChat>

	% Result 3 -> The player goes quietly away.
	result3 <NewChat Say 5>

	% Result 4 -> Go straight to the job description.
	result4 <Goto GoJobDesc>

	% Result 5 -> Go away.
	result5 <NewChat Say 10>

	% The NPC will describe the job being offered. This will depend upon the
	% PC's reputation.
	% V1 = Threat Value of Encounter
	GoJobDesc <ifG PCRep 6 90 Else GoLvl9 V= 1 12000000 E= 8 10 Say 11 goto GoChoose>
	GoLvl9 <ifG PCRep 6 80 Else GoLvl8 V= 1 6500000 E= 8 9 Say 12 goto GoChoose>
	GoLvl8 <ifG PCRep 6 70 Else GoLvl7 V= 1 3300000 E= 8 8 Say 13 goto GoChoose>
	GoLvl7 <ifG PCRep 6 60 Else GoLvl6 V= 1 1700000 E= 8 7 Say 14 goto GoChoose>
	GoLvl6 <ifG PCRep 6 50 Else GoLvl5 V= 1  900000 E= 8 6 Say 15 goto GoChoose>
	GoLvl5 <ifG PCRep 6 40 Else GoLvl4 V= 1  500000 E= 8 5 Say 16 goto GoChoose>
	GoLvl4 <ifG PCRep 6 30 Else GoLvl3 V= 1  300000 E= 8 4 Say 17 goto GoChoose>
	GoLvl3 <ifG PCRep 6 20 Else GoLvl2 V= 1  200000 E= 8 3 Say 18 goto GoChoose>
	GoLvl2 <ifG PCRep 6 10 Else GoLvl1 V= 1  100000 E= 8 2 Say 19 goto GoChoose>
	GoLvl1 <ifG PCRep 6  0 Else GoLvl0 V= 1   40000 E= 8 1 Say 20 goto GoChoose>
	GoLvl0 <V= 1  20000 E= 8 1 Say 20 goto GoChoose>

	% The encounter has been described, and a threat rating been set.
	% See whether or not the PC will accept the job.
	GoChoose <NewChat AddChat 6>

	Result6 <EndChat Say 21 P= 2 1 SavePos AddReact 2 Dynamic 2 V1 FrzNU1 FrzNU2 Encounter 15 25 .enemydata>
	FrzNU1 <if= T1 0 Return>
	FrzNU2 <if= T2 0 Salvage Return>
	.enemydata <Chaotic Bandit +ECRA>

	Msg1 <I have to find a pilot for some corporate work. If you had a mecha, I'd offer you the job.>
	Msg2 <I'm very busy right now. Please come back later.>
	Msg3 <There are lots of oppurtunities avaliable for mecha pilots in our company.>
	Msg5 <Have a good day.>
	Msg6 <Please go away. You are wasting my time.>
	Msg7 <I don't think you're the kind of person we're looking for.>
	Msg8 <As a matter of fact we do. One of our business ventures is being threatened by outside forces. Would you be interested in running a mission for our us?>
	Msg9 <I believe you might be... Our company's interests are currently being threatened by outside forces. How would you like to run a fixer mission?>
	Msg10 <A company job offers stable pay, health insurance, and a decent retirement package. Think about it.>

	Msg11 <A powerful force of unknown mecha has been attacking our vital interests. It is not known currently whether they are thieves, or if they have some other motive. Eliminate them for $148000 plus salvage.>
	Msg12 <Several bandit gangs have recently been united under one leader. If their mecha could be disabled, it might spell an end to this dangerous alliance. Pay is $80000 and salvage.>
	Msg13 <A rival corporation has hired a mercenary team to eliminate our key factories. Take out the enemy units for $40000 plus salvage.>
	Msg14 <An ambitious mecha thief has moved from assaulting our company's trucks to assulating our factories themselves. This has to be stopped. Eliminate the bandits for $21000 plus mecha salvage.>
	Msg15 <A band of eco-terrorists armed with heavy mecha have been sabotaging our commercial interests. It's thought that they are being financed by a rival corporation. Eliminate their mecha for $10800 plus salvage.>
	Msg16 <One of the local mecha gangs has been getting too powerful. They've grown increasingly bold in attacks against our trucks. I need you to put an end to this. Pay is $6000 and salvage.>
	Msg17 <Our company has many enemies. A small team of saboteurs, apparenly hired by a rival corporation, has been attacking our factories. Stopping them will earn you $3600 and the salvage rights to their machines.>
	Msg18 <In the modern era mecha-equipped thieves are the greatest bane to industry and trade. A small but well equipped gang has been raiding our convoys. They need to be removed. Pay is $2400 plus salvage rights.>
	Msg19 <A team of mecha bandits has been stealing from our trucks. I would like for you to eliminate them. Pay is $1200 plus salvage, collectable upon completion.>
	Msg20 <As you probably know, our company loses in excess of $15G to mecha thieves every year. I would like for you to act as a convoy guard. Eliminate the bandits, earn $1000 plus salvage.>

	Msg21 <Here is all the information that you will need. Report back here after your mission has been completed.>

	prompt1 <I'm a good pilot! Any jobs for me?>
	prompt2 <If you need a pilot, I'm the best.>
	prompt3 <Sorry, not interested in corporate work.>
	prompt4 <I'd like to. Tell me more.>
	prompt5 <I'm not interested.>
	prompt6 <I'll do it.>


	Plot 1
		% The player lost the battle.
		% Time limit - this plot will fade after a short time.
		START <if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 500>
		GotoCheckTime <ifG ComTime V1 AdvancePlot 0>
	sub
		Persona 1
		% The exact message given by the NPC will vary depending on
		% whether or not the PC is well-liked...
		greeting <NewChat AdvancePlot 0 ifG React 75 else GoMedReact ifG PCRep 6 50 else GoMedReact Say 1 AddReact -10 Reputation 6 -10 CashPrize 150000>
		GoMedReact <ifG React 50 else GoMedium2 Say 2 AddReact -5 CashPrize 500>
		GoMedium2 <ifG React 15 else GoLowReact Say 3 AddReact -5 CashPrize 300>
		GoLowReact <Say 4 AddReact -5 CashPrize 300>

		Msg1 <The mission was a failure. However, our company still has great faith in your abilities... Here is a mecha allowance. Go repair your machine, or buy a better one. I trust you will do better on the next mission.>
		Msg2 <You failed to perform the assigned duties. However, the company always takes care of its employees. Here is your repair allowance. I hope that it covers the cost of service on your machine.>
		Msg3 <Your mission was a failure. Here is your repair allowance. Please do not fail again.>
		Msg4 <The mission was a complete failure. I do not think that we will require your services in the future. Here is your repair allowance.>
	end

	Plot 2
		% The player won the battle.
		% Time limit - this plot will fade after a short time.
		START <if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 17500>
		GotoCheckTime <ifG ComTime V1 AdvancePlot 0>
	sub
		Persona 1
		greeting <NewChat AdvancePlot 0 if= E8 10 Else GoLvl9 CashPrize 148000 Goto GoSaySomething>
		GoLvl9 <if= E8 9 Else GoLvl8 CashPrize 80000 Goto GoSaySomething>
		GoLvl8 <if= E8 8 Else GoLvl7 CashPrize 40000 Goto GoSaySomething>
		GoLvl7 <if= E8 7 Else GoLvl6 CashPrize 21000 Goto GoSaySomething>
		GoLvl6 <if= E8 6 Else GoLvl5 CashPrize 10800 Goto GoSaySomething>
		GoLvl5 <if= E8 5 Else GoLvl4 CashPrize  6000 Goto GoSaySomething>
		GoLvl4 <if= E8 4 Else GoLvl3 CashPrize  3600 Goto GoSaySomething>
		GoLvl3 <if= E8 3 Else GoLvl2 CashPrize  2400 Goto GoSaySomething>
		GoLvl2 <if= E8 2 Else GoLvl1 CashPrize  1200 Goto GoSaySomething>
		GoLvl1 <CashPrize 1000 Goto GoSaySomething>
		GoSaySomething <if= d6 1 else GoSay2 Say 1>
		GoSay2 <if= d5 1 else GoSay3 Say 2>
		GoSay3 <if= d4 1 else GoSay4 Say 3>
		GoSay4 <if= d3 1 else GoSay5 Say 4>
		GoSay5 <if= d2 1 else GoSay6 Say 5>
		GoSay6 <Say 6>

		Msg1 <Here is your pay. It's been a pleasure doing business with you.>
		Msg2 <Here are your earnings. I think you have a bright future with this company.>
		Msg3 <Here's the money you earned for that mission. Good job.>
		Msg4 <Congradulations on a mission well done. I'm sure you'll be promoted in no time.>
		Msg5 <The company values people like you. Here's your pay.>
		Msg6 <Here's your pay. The mission was a complete success.>
	end


end

