Plot 0
	% The invention of the Virtual Reality Whack-A-Mole
	Element1 <Character Cheerful Heroic Knowledge Craft Charm>
	Rumor <!1 is working on a new invention.>

	% Time limit = 2 days.
	START <if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 172800>
	GotoCheckTime <ifG ComTime V1 AdvancePlot 1>

sub
	Persona 1
	% V1 = Player has already asked about VRWAM once.
	greeting <if= V1 1 else GoFirstGreeting Say 2 NewChat>
	GoFirstGreeting <V= 1 1 ifG React 19 else GoCoolGreeting say 1 NewChat AddChat 1 AddChat 2>
	GoCoolGreeting <SayAnything NewChat AddChat 3>
	GoWhackAMole <Say 3 NewChat AddChat 6 AddChat 7 AddChat 9>
	result1 <Reputation 5 1 Goto GoWhackAMole>
	result2 <Say 5 NewChat>
	result3 <V= 1 1 Say 4 NewChat AddChat 4 AddChat 5>
	result4 <Goto GoWhackAMole>
	result5 <Reputation 5 -1 Say 5 NewChat>
	result6 <Say 7 EndChat AddChat 8>
	result7 <Say 6 EndChat AddChat 8>
	result8 <Goto Result9>
	result9 <Say 8 NewChat AddChat 10 AddChat 2>
	result10 <Say 9 EndChat>
	Msg1 <Hi! Do I have something to show you... How'd you like to be the first to see the cutting-edge in electronic games?>
	Msg2 <I'm still working on the project... I hope to have it running by tomorrow.>
	Msg3 <This here is the Virtual Reality Whack-A-Mole! Yes, now you can enjoy all the excitement of Whack-A-Mole anywhere and anytime! Isn't it great?>
	Msg4 <Oh this? It's nothing... I'm working on something. Just a hobby project. I'm quite sure you wouldn't be interested.>
	Msg5 <I guess you're not the type to enjoy good virtual gaming.>
	Msg6 <Well, one of the problems is that I don't yet have a hammer object programmed in... When I finish it, though, it's going to be a great game!>
	Msg7 <Actually I stole the idea from someone else... but my implementation is flawless!>
	Msg8 <It's not really working yet, but come back in a little while and I'll let you be my play tester.>
	Prompt1 <I'd love to see! Bring it on!>
	Prompt2 <Maybe some other time.>
	Prompt3 <Why are you carrying a giant mallet?>
	Prompt4 <Come on, let me see what it is!>
	Prompt5 <I'm quite sure that you're right.>
	Prompt6 <What a great idea!>
	Prompt7 <If it's VR, why do you need that hammer?>
	Prompt8 <I see...>
	Prompt9 <Can I try it out?>
	Prompt10 <I'll do that.>

	% Sub-Plot... VRWAM is finished and needs a playtester.
	Plot 1
		Rumor <!1 has built something strange.>

		% Time limit = 1 day.
		START <if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 86400>
		GotoCheckTime <ifG ComTime V1 AdvancePlot 1>
	sub
		Persona 1
		% V1 = Player has already won VRWAM.
		% V2 = Number of moles hit. Need 5 to win.
		greeting <if= V1 1 else GoNoWin Say 1 NewChat>
		GoNoWin <Say 2 NewChat AddChat 1 V= 2 0>
		GoLoseGame <Say 5 Print 6 EndChat AddChat 5>
		Result1 <Say 3 NewChat AddChat 2 AddChat 3>
		result2 <Say 4 EndChat AddChat 4>
		result3 <Say 10 NewChat>
		% The player has to make a good ARMED COMBAT roll to win.
		result4 <ifG SkRoll 8  10  else GoLoseGame V+ 2 1 endchat addchat 4 Say 7 ifG V2 4 EndChat AddChat 6>
		result5 <Say 8 NewChat>
		result6 <Reputation 3 1 Reputation 5 2 V= 1 1 XPV 500 Say 9 NewChat>
		Msg1 <Thanks for your help! There are still a few bugs in Virtual Reality Whack-A-Mole, so I'll be calibrating the responsitrons for the rest of today.>
		Msg2 <I've done it! My Virtual Reality Whack-A-Mole game is up and running!>
		Msg3 <Sure... Mind you, this is a totally untested VR application. Any kind of thing could go wrong... Are you sure you're willing to risk permanent brain damage?>
		Msg4 <Take the hammer. Just a minute while I plug in the helmet...>
		Msg5 <You whack something soft and squishy!>
		Msg6 <You have struck \PERSONA E1 with the hammer.>
		Msg7 <You whack a mole on the head!>
		Msg8 <Ouch. I guess there are still a few problems I need to work on...>
		Msg9 <Congradulations, you've whacked all the moles!>
		msg10 <To be honest with you, I'm a bit scared to try it myself...>
		Prompt1 <Can I try it out?>
		Prompt2 <Absolutely! Let's go!>
		Prompt3 <On second thought, maybe not.>
		Prompt4 <( score = \VAL V2 )>
		Prompt5 <(continue)>
		Prompt6 <(continue)>
	end

end
