Plot 0
	% To start with, the bully and the victim.
	Element1 <Character Young Villainous Chaotic>
	Element2 <Character Young Lawful !Near 1>

	rumor <teenage gangsters have been extorting money from their peers.>

	% Window of oppurtunity - this plot will fade after a time.
	START <if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 10000>
	GotoCheckTime <ifG ComTime V1 AdvancePlot 0>
sub
	Persona 2
		greeting <NewChat ifG React 50 else GoNoNews Say 1 AddChat 1>
		GoNoNews <SayAnything ifG SkRoll 11 25 AddChat 2>
		result1 <Reputation 1 2 AdvancePlot 1 Say 3 NewChat AddChat 5 AddChat 6>
		result2 <Say 2 NewChat AddChat 3 AddChat 4>
		result3 <Reputation 1 1 AdvancePlot 1 Say 3 NewChat AddChat 5 AddChat 6>
		result4 <Reputation 5 -1 AdvancePlot 0 Say 4>
		result5 <Say 5 Reputation 1 1 NewChat>
		result6 <Say 6 Reputation 3 -1 NewChat>
		Msg1 <I've got a bit of trouble, and I don't know who to talk to... maybe you can help me?>
		Msg2 <It's nothing... I got into a bit of a fight at school...>
		Msg3 <\PERSONA E1 has been stealing money from the guys. I wouldn't give mine over, so this is what happened... can you do anything about it?>
		Msg4 <Yeah, thanks for the advice...>
		Msg5 <Thanks! I knew I could count on you.>
		Msg6 <They won't do anything about this... Look, if you don't go talk to \PERSONA E1 I know nothing is going to change.>
		Prompt1 <What's the matter?>
		Prompt2 <What happened to your face?>
		Prompt3 <A fight? With who?>
		Prompt4 <You should learn to defend yourself.>
		Prompt5 <I'll see what I can do.>
		Prompt6 <Maybe we should tell the authorities.>

	Plot 1
		% The player has learned about the kangpae, and may
		% try to confront that character.
		rumor <teenage gangsters have been extorting money from their peers.>

		% Window of oppurtunity - this plot will fade after a time.
		START <if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 10000>
		GotoCheckTime <ifG ComTime V1 AdvancePlot 0>
	sub
		Persona 1
		% The deliquent who's been stealing lunch money.
			greeting <Say 1 EndChat AddChat 1 AddChat 2>
			result1 <Say 2 EndChat>
			result2 <Say 3 EndChat AddChat 3 AddChat 4 AddChat 5>
			% Must make an INTIMIDATION roll vs 15
			result3 <Reputation 2 1 ifG SkRoll 28 15 else GoBad3 say 4 EndChat AdvancePlot 1 XPV 50>
			GoBad3 <Say 5 EndChat AdvancePlot 2>
			% Must make an INTIMIDATION roll vs 9
			result4 <Reputation 2 -1 ifG SkRoll 28 9 else GoBad4 say 6 EndChat AdvancePlot 1 XPV 50>
			GoBad4 <Say 7 EndChat AdvancePlot 2>
			result5 <Reputation 4 1 Say 8 NewChat AddChat 6 AddChat 7>
			result6 <Reputation 5 1 ifG React 30 else GoBad6 say 9 NewChat AdvancePlot 1 XPV 50>
			GoBad6 <Say 10 EndChat AdvancePlot 2>
			% Must make a CONVERSATION roll vs 9
			result7 <Reputation 5 -1 ifG SkRoll 19 9 else GoBad7 say 9 EndChat AdvancePlot 1 XPV 50>
			GoBad7 <Say 10 EndChat AdvancePlot 2>
			Msg1 <What do you want, loser?>
			Msg2 <Whatever.>
			Msg3 <Is that so? I do all kinds of things. I do whatever I want. And what do you think you can do to stop me, huh?>
			Msg4 <Okay, okay, I get the message... I'll stop harassing \PERSONA E2 if that's what you want.>
			Msg5 <Oh, I'm so worried. Maybe you should threaten that you're gonna call my mom?>
			Msg6 <Don't hurt me! I'll stop picking on \PERSONA E2 just leave me alone!>
			Msg7 <If you wanna try to fight me, go right ahead. I think I'm harder than you.>
			Msg8 <Just want to talk? That's a new one... shoot.>
			Msg9 <I guess so. If it means anything to you I'll stop picking on \Persona E2 so much, okay?>
			Msg10 <What is that supposed to mean!? I don't think you understand anything...>
			Prompt1 <Nothing... I'll be going now.>
			Prompt2 <I know what you've been doing.>
			Prompt3 <I'm going to call the police.>
			Prompt4 <I'm going to kick your sorry ass.>
			Prompt5 <I just want to talk with you.>
			Prompt6 <There are better things for you than this.>
			Prompt7 <Violence only leads to pain and death.>

		Persona 2
			greeting <Say 1 NewChat AddChat 1>
			result1 <NewChat Say 2>
			Msg1 <Have you spoken to \PERSONA E1 yet?>
			Msg2 <Please hurry... we're all counting on you!>
			Prompt1 <I need a bit more time...>

		Plot 1
			% Sub-Plot... the deliquent repents.
			START <if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 3000>
			GotoCheckTime <ifG ComTime V1 AdvancePlot 0>
		sub
			Persona 2
				greeting <Say 1 NewChat AddChat 1>
				result1 <NewChat Say 2 AdvancePlot 0 XPV 25>
				Msg1 <Have you spoken to \PERSONA E1 yet?>
				Msg2 <Great! I knew you'd come through!>
				Prompt1 <All taken care of.>
		end

		Plot 2
			rumor <teenage gangsters have been extorting money from their peers.>
			% Sub-Plot... the mission is a failure.
			START <if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 10000>
			GotoCheckTime <ifG ComTime V1 AdvancePlot 0>
		sub
			Persona 2
				greeting <Say 1 NewChat AddChat 1>
				result1 <NewChat Say 2 AdvancePlot 0 XPV 25>
				Msg1 <Have you spoken to \PERSONA E1 yet?>
				Msg2 <I thought this would be difficult. Don't give up yet though! I know you can do it!>
				Prompt1 <Things didn't go so well...>
			Persona 1
				% V1 = Annoyance Counter
				greeting <ifG V1 8 else GoRegGreeting Say 2 AdvancePlot 0 XPV 50 EndChat>
				GoRegGreeting <V+ 1 1 Say 1 EndChat AddChat 1 AddChat 2>
				% Intimidation roll vs. 10
				result1 <ifG SkRoll 28 10 else GoBad1 say 3 EndChat AdvancePlot 1 XPV 75>
				GoBad1 <Say 4 EndChat>
				% Conversation roll vs. 15
				result1 <ifG SkRoll 19 15 else GoBad2 say 5 EndChat AdvancePlot 1 XPV 75>
				GoBad1 <Say 4 EndChat>
				Msg1 <Back again? I though I told you to scram last time...>
				Msg2 <Argh! What do I have to do to get rid of you!?!? All right, I'll do as you say... just leave me alone!!!>
				Msg3 <I don't want any trouble... I'll stop collecting protection money if that'll get you off my back.>
				Msg4 <Come back when you've got something worth saying, loser.>
				msg5 <Okay, sure. I'll stop being mean to the others. Will that get you off my case?>
				Prompt1 <Listen punk, you better wise up!>
				Prompt2 <Stop picking on \PERSONA E2 you bully!>
		end

	end

end
