Plot 0
	name <PLOT: Recruitment Drive>
	% The player will be given a chance to join a faction, maybe.

	Element1 <Faction Military>
	Element2 <Character !C 1 Sociable HasMecha>

	% Time limit code.
	START <ifPersona E2 else GoDelete if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 20000>
	GotoCheckTime <ifG ComTime V1  AdvancePlot 0>
	GoDelete <AdvancePlot 0>

sub
	Persona 2
	% V1 = Reaction + Reputation; high score = good mecha
	rumor <!2 has been trying to recruit new members for !1 lately.>

	greeting <NewChat  AdvancePlot 0  if= PCFac 0 else GoAlreadyHasFaction ifG PCRep 6 30 else GoNoChance ifG React d100 else GoMedReact Say 1  AddChat 1 AddChat 2 AddChat 3>
	GoMedReact <ifG PCRep 6 d120 else GoNoRep Say 2  AddChat 4 AddChat 5>
	GoNoRep <ifG PCRep 2 d100 else GoNoLaw Say 8  AddChat 10 AddChat 9>
	GoNoLaw <ifG PCRep 3 d100 else GoNoSoc Say 9  AddChat 10 AddChat 11>
	GoNoSoc <Say 10  AddChat 10 AddChat 12>

	GoAlreadyHasFaction <SayAnything>
	GoNoChance <SayAnything>

	result1 <NewChat Say 24  AddChat 14>
	result2 <NewChat ifG SkRoll 19 5 else GoR2NoCon Say 22>
	GoR2NoCon <AddReact -1 Say 23>
	result3 <NewChat Say 21  AddChat 8 AddChat 13>
	result4 <NewChat Say 3  AddChat 1 AddChat 2 AddChat 3>
	result5 <NewChat Say 4  AddChat 3 AddChat 6 AddChat 7>
	result6 <NewChat  AddChat 3 AddChat 8 AddChat 9  ifG PCRep 1 d100 else GoR6NoHero  Say 5>
	GoR6NoHero <ifG PCRep 2 d100 else GoR6NoLaw Say 6>
	GoR6NoLaw <Say 7>
	result7 <NewChat Say 25  AddChat 14>
	result8 <NewChat Say 26  AddChat 14>
	result9 <NewChat AddReact -2  ifG React d50 else GoR9NoLike Say 11>
	GoR9NoLike <AddReact -1  ifG SkRoll 19 5 else GoR9NoCon Say 12>
	GoR9NoCon <AddReact -4  Say 13>
	result10 <NewChat ifG SkRoll 19 8 else GoR10NoCon Say 16  AddChat 1 AddChat 2 AddChat 3>
	GoR10NoCon <ifG React d100 else GoR10NoLike Say 15 AddChat 1 AddChat 2 AddChat 3>
	GoR10NoLike <Say 14>
	result11 <NewChat ifG SkRoll 28 15 else GoR11NoInt Say 17  AddChat 7 AddChat 13>
	GoR11NoInt <Say 18  AddChat 10 AddChat 12>
	result12 <NewChat Say 19  AddChat 10 AddChat 13>
	result13 <NewChat Say 20>
	result14 <NewChat  Say 27  SetPlayerFaction E1  XPV 150  V= 1 React V+ 1 PCRep 6   ifG V1 100 else GoR14BasicPackage  ifG SkRoll 1 10 else GoR14Missile  MechaPrize .GunMek>
	GoR14Missile <ifG SkRoll 2 10 else GoR14Melee  MechaPrize .SupportMek>
	GoR14Melee <ifG SkRoll 3 10 else GoR14Brick  MechaPrize .CloseMek>
	GoR14Brick <ifG SkRoll 4 10 else GoR14Best  MechaPrize .BrickMek>
	GoR14Best <ifG SkRoll 5 23 else GoR14BasicPackage  MechaPrize .BestMek>
	% This character doesn't qualify for the advanced package.
	GoR14BasicPackage <MechaPrize .BasicMek>

	.BasicMek <BuruBuru.txt>
	.GunMek <Daum.txt>
	.SupportMek <Thorshammer.txt>
	.CloseMek <Fenris.txt>
	.BrickMek <Ovaknight.txt>
	.BestMek <Harpy.txt>

	Msg1 <Right now \ELEMENT 1 is looking for some good warriors to join our forces. Would you happen to be interested in signing up?>
	Msg2 <Your adventures have made you quite famous. Have you ever thought about how your talents could be put to better use?>
	Msg3 <At the moment \ELEMENT 1 is looking for new members. I think you'd be perfect for our organization. Are you interested in joining?>
	Msg4 <One lone pilot can't accomplish all that much. If you were a meber of \ELEMENT 1 then you would be helping to change the world. Join our ranks and we can help each other.>
	Msg5 <By helping \ELEMENT 1 to unite the world under one flag, you would be preventing the senseless waste of life caused by the never-ending wars which have dogged mankind throughout history.>
	Msg6 <By joining forces with \ELEMENT 1 you would be helping to bring order to this chaotic world. The entire planet could be unified under a single flag. Think of the possibility.>
	Msg7 <You should know that \ELEMENT 1 is fueled by a vision... It is this dream which we soldiers follow. Imagine the entire planet united under our flag... It is beautiful, is it not?>
	Msg8 <The dream of \ELEMENT 1 is nothing less than total global unity. One world, united under our banner. In the end we will be victorious.>
	Msg9 <There's a certain camraderie in being a soldier. The army is the best place for folks like us.>
	Msg10 <The forces of \ELEMENT 1 are the greatest in the world! We will be victorious.>
	Msg11 <You say that now, but you'll see differently later on.>
	Msg12 <What other alternatives are there? Think about it...>
	Msg13 <When the revolution comes, it's your type that will be first against the wall...>
	Msg14 <Yes, but we aren't looking for you. Maybe someday if we're really desperate for new members.>
	Msg15 <I like you so I'll let you in on this. Yes, we are currently looking for new recruits. Do you want to join?>
	Msg16 <Yes we are! You might just have what it takes to join us! Are you interested in signing up?>
	Msg17 <I'm a member of \ELEMENT 1 army. How'd you like to join?>
	Msg18 <I'm a member of \ELEMENT 1 army. We shall be victorious!>
	Msg19 <Victorious over the forces of our enemies, of course! Our manifest destiny is spectacular, is it not?>
	Msg20 <Well, that's your problem, I guess. For \ELEMENT 1 it is truly a momentous age!>
	Msg21 <To start with you'll be equipped with a mecha. Pay for the missions is very good, and there are plenty of oppurtunities for glory and promotion!>
	Msg22 <Remember my offer, though, just in case you change your mind.>
	Msg23 <Okay, but you don't have to be so negative about it...>
	Msg24 <Do you mean it? This is great! I really look foreward to serving alongside you!>
	Msg25 <There will be some paperwork to fill out, of course, but after that you'll be a full fledged member!>
	Msg26 <You won't regret this decision, I promise you.>
	Msg27 <On behaf of \ELEMENT 1 I'd like to welcome you to our ranks!>

	Prompt1 <Absolutely!>
	Prompt2 <No, I wouldn't.>
	Prompt3 <What's in it for me?>
	Prompt4 <Tell me about it.>
	Prompt5 <What kind of better use?>
	Prompt6 <Change the world how?>
	Prompt7 <Sounds good! Sign me up!>
	Prompt8 <Okay, I'll join.>
	Prompt9 <That's not my idea of utopia.>
	Prompt10 <Are you looking for new members?>
	Prompt11 <What army would that be?>
	Prompt12 <Victorious over what?>
	Prompt13 <I don't think I'm interested.>
	Prompt14 <I am now a \ELEMENT 1 member!>

end
