Story
	% This should be a sub-story of the organ theif story.

	% The niece of an important person has been kidnapped.
	% There's a time limit before the victim is killed- the
	% clock starts ticking as soon as the player is informed
	% of the event (either in person or via the news).

	% This is kind of a rough first draft of the story as I
	% envisioned it. It doesn't do all the things I had planned
	% yet... However, I'd like to play through it a few times
	% before I go making it too complex.

	% Element 1 is a scene, but its value will change over the
	% course of the story. As the player tracks the kidnappers
	% across the FT, N1 will hold the value of the most recent
	% lead.
	element1 <Scene Town>
	element2 <Character !N 1 Leader Renowned>
	element3 <Prefab>

	% V1 = Time Limit
	%     The time limit only starts after the PC is informed
	%     of the story.

	% V2 = Reward Offered

	% V101 = Refresh Investigation
	%     if nonzero, need to reload a new investigation plot
	% V102 = Clues Accumulated by the PC
        %     Once the total is high enough, a conclusion will be loaded

	% V201 = Story Outcome
	%     if > 0, PC was successful and rescued the niece
	%     if < 0, PC failed and the niece died

	% Every 5 minutes, check to see whether or not to load a
	% new investigation.
	5Min <if# V101 0 memo 101 if= V201 0 ifG 3 V102 else GoEndStory ifG V1 ComTime else GoTimeOver storyline .investigation V= 101 0>
	.investigation <SS_Kidnapped_Inv_*.txt>
	GoEndStory <storyline .conclusion V= 101 0>
	.conclusion <SS_Kidnapped_End_*.txt>
	GoTimeOver <email 3 V= 101 0 V= 201 -1>

	% Every half hour, check whether or not to announce the story.
	HalfHour <if= d100 23 if= V1 0 ifG RReact N2 d120 else GoCheckNPC EMail 2 V= 1 ComTime V+ 1 168000>
	GoCheckNPC <storyline .npcgetsinvolved>
	.npcgetsinvolved <SS_Kidnapped_NPC_*.txt>

	% Investigation memo
	Msg101 <\NARRATIVE 2 wants you to investigate the disapearance of \NARRATIVE 3 . \NARRATIVE 1 was her last known location.>

	Msg2 <\NARRATIVE 2 @ \SCENE N2 :// I need your help immediately! Please see me in \SCENE N2 at once.>

	cleanup <if= V1 0 else GoCheckProgress  EndStory>
	GoCheckProgress <ifG 3 V102 EndStory>

sub
	Persona 2
	greeting <NewChat ifG S201 0 else GoCheckLoss Say 3 CashPrize S2 XPV 250 EndStory>
	
	GoCheckLoss <ifG 0 S201 else GoStart Say 2 EndStory>
	GoStart <Say 1 S= 101 1 S= 2 150000 S= 1 ComTime S+ 1 129600>
	Msg1 <Please find my niece \NARRATIVE 3 ! She went missing, and we think she's been kidnapped.>
	Msg2 <All has been lost...>
	Msg3 <Thank you for rescuing \NARRATIVE 3 ! Here is a small reward for your heroic deeds.>

end

inv
	NPC Citizen
	chardesc Young Female

end
