Plot 0
	name <ARC: Bandit SubContract>

	% **********************
	% *** ELEMENTS BLOCK ***
	% **********************
	% This plot will likely be called from a faction story.
	% So, it will grab the identity of the faction as its first
	% element, and a member of the faction to give the job to
	% the PC.

	% E1 is the faction behind the story
	Element1 <Grab 1>

	% E2 is the NPC who will give the PC the mission.
	Element2 <Character Bandit Sociable HasMecha>


	% ********************
	% *** SCRIPT BLOCK ***
	% ********************
	% V1 = Time Limit
	% V2 = Combat Indicator, if V2=1 combat has been entered
	% V3 = Email sent indicator.

	% On a cleanup request, delete this plot unless combat has been
	% entered.
	cleanup <if= V2 0 AdvancePlot 0>

	% Time limit. This plot will conclude in one day, or immediately
	% if NPC E2 is killed.
	start <ifPersona E2 else GoDelete if= V1 0 else GoCheckTime V= 1 ComTime V+ 1 86400>
	GoCheckTime <if= V2 0 ifG ComTime V1 AdvancePlot 0 if= d3 1 S+ 101 -1>
	GoDelete <AdvancePlot 0>

	% Combat check. If combat has been entered, V2=1.
	% Combat ends in victory if the number of active masters on
	% team two drops to zero, or ends in defeat is the number of
	% active masters on team one drops to zero. After combat, V2=3
	% if the player was victorious or V2=2 is the player lost.
	% Finally, if the player won, the calling story's faction victory
	% count (by default now story variable 101) will be increased.
	nu1 <if= T1 0 if= V2 1  V= 2 2  Reputation 6 -7>
	nu2 <if= T2 0 if= V2 1  V= 2 3  Reputation 6  1  XPV 50  S+ 101 -1>

sub
	% This next bit is the conversation which will happen when the
	% PC speaks to E2.
	Persona 2

	% Fill in something for the rumor string, so the PC will know who
	% has a job to offer. !2 will add the name of the NPC, while !1
	% will add the name of the faction.
	rumor <!2 has a big job planned.>


	% ********************
	% *** SCRIPT BLOCK ***
	% ********************
	% If you're feeling faint of heart, just skip this
	% and jump straight to the messages block below.
	% Here are the variables used in this conversation:
	%  V1 = Job offer counter, V1=1 is job offered, V1=-1 if job denied
	%  V2 = Message Randomizer
	%  V3 = Threat value of enemy mecha
	%  V4 = Reward offered to PC for the mission
	% At startup, first check to see whether the PC has already
	% completed the mission or not.
	Greeting <NewChat if= P2 3 else GoCheckLoss Say d5 CashPrize V4 AdvancePlot 0>
	GoCheckLoss <if= P2 2 else GoCheckJob V= 2 5 V+ 2 d5 Say V2 AdvancePlot 0>
	GoCheckJob <if= V1 1 else GoCheckFirst Say 101 Goto GoAddComOps>

	% The first time the PC meets the NPC, the PC will be given the
	% mission automatically if he's part of the same faction, or if
	% he is a friend of the NPC, or if he's already been sent email.
	GoCheckFirst <if= V1 0 else GoDenied V= 1 -1 V= 3 Threat FacVar E1 1000 120 V= 4 Reward V3 140 ifG React 80 else GoNoAutomatic ifG 50 PCRep 2 else GoDenied V= 2 10 V+ 2 d5 Say V2 Goto GoAddComOps>
	% If the PC is not automatically offered the job, there's still
	% a chance to get the job... as long as the NPC doesn't hate him.
	GoNoAutomatic <ifG React -d10 else GoDenied ifG d10 PCRep 2 else GoDenied V= 2 20 V+ 2 d5 Say V2 V= 2 10 V+ 2 d3 AddChat V2 V= 2 13 V+ 2 d3 AddChat V2 V= 2 16 V+ 2 d3 AddChat V2>
	GoDenied <V= 1 -1 SayAnything>

	GoAddComOps <V= 1 1 AddChat d2 V= 2 2 V+ 2 d2 AddChat V2 V= 2 4 V+ 2 d2 AddChat V2 Memo 107>

	% The PC will enter combat here.
	result1 <EndChat V= 2 35 V+ 2 d5 Say V2 SavePos P= 2 1 Reputation 2 -3 Dynamic 2 V3 .nu1 .nu2 Encounter 2 0 .edesc>
	.nu1 <if= T1 0 Return>
	.nu2 <if= T2 0 Salvage Return>
	.edesc <Lawful Bounty Hunter>
	result2 <Goto Result1>

	% The PC needs some time to get ready.
	result3 <NewChat Say 103>
	result4 <Goto Result3>

	% The PC will be told the enemy's point value.
	result5 <NewChat V= 2 25 V+ 2 d5 Say V2 AddChat 1 AddChat 3>
	result6 <Goto result5>

	% The PC accepts the job offer.
	result7 <NewChat V= 2 10 V+ 2 d5 Say V2 Goto GoAddComOps>
	result8 <Goto result7>

	% The PC refuses the job offer.
	result9 <NewChat Say 102 V= 1 -1>
	result10 <Goto result9>

	% The PC tries to get the job via "PLAN A"- be forceful and
	% convincing. This plan uses Intimidation skill in order to
	% succeed. If you want to change it, some alternate "PLAN A"
	% types are presented... uncomment the one you like.
	result11 <NewChat ifG Intimidation 10 else GoR11Lose V= 2 30 V+ 2 d5 Say V2 V= 2 6 V+ 2 d2 AddChat V2 V= 2 8 V+ 2 d2 AddChat V2>
	result12 <Goto result11>
	result13 <Goto result11>

	% PLAN "A", whatever it was, has failed...
	GoR11Lose <NewChat Say 104 V= 1 -1>


	% The PC tries to get the job via "PLAN A"- be friendly.
	% The PC will impress the NPC with CHAOTIC reputation...
	result14 <NewChat ifG -PCRep 2 d75 1000 else GoR14Lose V= 2 30 V+ 2 d5 Say V2 V= 2 6 V+ 2 d2 AddChat V2 V= 2 8 V+ 2 d2 AddChat V2>
	result15 <Goto result14>
	result16 <Goto result14>

	% PLAN "B", whatever it was, has failed...
	GoR14Lose <NewChat Say 105 V= 1 -1>

	% The player doesn't want this stinkin' job.
	result17 <NewChat Say 106 V= 1 -1>
	result18 <Goto result17>
	result19 <Goto result17>


	% *********************
	% *** MESSAGE BLOCK ***
	% *********************

	% 01 - 05 :  Player has won the battle and is being paid.
	Msg1 <That showed those corporate blighters! Here's your cut of the take.>
	Msg2 <That went better than I had expected... Here's your cut.>
	Msg3 <You really nailed them! Here's the cash you earned.>
	Msg4 <\NARRATIVE 2 should be happy with that. Here's your pay.>
	Msg5 <A job well done. Here's your cash.>

	% 06 - 10 :  Player has lost the battle.
	Msg6 <That didn't go so well...>
	Msg7 <Argh, we messed up. The mission was a disaster.>
	Msg8 <What happened out there!? Everything went wrong...>
	Msg9 <That wasn't much of a battle, now was it?>
	Msg10 <We got trashed...>

	% 11 - 15 :  Description of mission.
	%  use "$ \VAL V4 " to insert the pay for the mission,
	%  and don't forget to mention that the PC also gets salvage.
	Msg11 <A certain crime lord has been handing out contracts against \NARRATIVE 1 . Basically we have to smash the defenses near their warehouse, grab whatever loot we want, and it'll be worth $ \VAL V4 .>
	Msg12 <My target is \NARRATIVE 1 . \NARRATIVE 2 will pay us to attack their factory. He's got some kind of a vendetta, none of my business to ask... We'll get paid $ \VAL V4 plus whatever loot we snatch for the job.>
	Msg13 <This is an easy mission. \NARRATIVE 2 will hire us to attack a \NARRATIVE 1 factory. There's nothing to grab, no special instructions, just destroy everything and we get $ \VAL V4 . Plus whatever we can grab ourselves, of course.>
	Msg14 <\NARRATIVE 2 has something against \NARRATIVE 1 . I've been offered a job to smash up one of their factories... I can give you $ \VAL V4 if you'd like to join the party.>
	Msg15 <There's an underworld bounty for attacking \NARRATIVE 1 . All we need to do is smash one of their warehouses to get $ \VAL V4 each... plus whatever loot we can find in the rubble, of course.>

	% 21 - 25 :  NPC implies job, PC might have chance to get it.
	Msg21 <It's a good time to be a crook, with people willing to pay top money for easy jobs...>
	Msg22 <\NARRATIVE 2 has been hiring people to attack \NARRATIVE 1 . It's pretty good work, if you're on the take...>
	Msg23 <I've got the inside deal on a great contract...>
	Msg24 <I've got some wild schemes cooking...>
	Msg25 <Once I pull off this next heist, I'll be rich... For a while, at least.>

	% 26 - 30 :  PC will be told exact enemy point value.
	%  use "\VAL V3 " to insert the value.
	Msg26 <The corp has about \VAL V3 threat points worth of hardware guarding their stuff. Do you feel up to the challenge?>
	Msg27 <Think you can handle \VAL V3 threat points worth of defense? That's what you'll be up against out there.>
	Msg28 <They've got around \VAL V3 points worth of mecha guarding the base. You'll need to eliminate all of it to earn your pay.>
	Msg29 <I expect they'll have around \VAL V3 tactical points worth of guards. That seems to be pretty standard these days.>
	Msg30 <I think they'll have \VAL V3 threat points worth of mecha. You can take that, can't you? I heard you were a badass.>

	% 31 - 35 :  "PLAN A" or "PLAN B" worked... the PC is offered
	%  a job and may choose either prompt7/8 to accept or prompt9/10
	%  to reject it.
	Msg31 <Maybe you could help me out, if you're interested in a bit of dirty work...>
	Msg32 <If you don't mind getting your hands dirty, I may just have a job for you...>
	Msg33 <What do you say to working together on this one? I have a mission lined up, all I need is someone with a mecha...>
	Msg34 <You wanna take part? You can do that, if you're up to the challenge...>
	Msg35 <You want to bash some of those rich pigs too, huh? Well, I need a mecha pilot, so if you want in all you have to do is ask...>

	% 36 - 40 :  Combat is starting.
	Msg36 <Here are the target coordinates. Come back once you've completely trashed the place and we'll split the loot.>
	Msg37 <The warehouse we're gonna destroy is hidden on the edge of the dead zone, but \NARRATIVE 2 knew how to get there... Come back after you've done the job and I'll give you your cut.>
	Msg38 <We're heading to a secret factory that \NARRATIVE 1 hid on the edge of the wasteland. They didn't hide it well enough. Come back after you've done everything and I'll pay you then.>
	Msg39 <Here's a map showing where you'll find the target. Get rid of all the defenses and smash anything that moves.>
	Msg40 <I'll send the data to your nav computer. I'll give you your pay once the job is finished.>


	% 101 :  Player accepted job, then left to get ready.
	Msg101 <Are you ready to roll out yet?>
	% 102 :  Player has refused to take job; answer to prompts 9-10.
	Msg102 <It's your loss.>
	% 103 :  Player has asked for some time to get ready.
	Msg103 <Make sure everything's in working order, then come back and we can start the run.>
	% 104 :  "PLAN A" has failed, and the PC is not offered a job.
	Msg104 <Don't even try it. If you were such a bigshot, \NARRATIVE 2 would've offered you a contract himself.>
	% 105 :  "PLAN B" has failed, and the PC is not offered a job.
	Msg105 <You're not exactly the type of partner I'm looking for... Only professional criminals need apply.>
	% 106 :  Player doesn't want job; answer to prompts 17-19.
	msg106 <That's your loss.>
	% 107 :  Memo
	msg107 <\ELEMENT 2 in \SCENE EScene 2 offered you $ \VAL V4 to attack \NARRATIVE 1 .>

	% 01 - 02 :  Ready to start the mission
	Prompt1 <I'm ready to go.>
	Prompt2 <Let's get the party started.>

	% 03 - 04 :  Need time to get ready first.
	Prompt3 <Give me some time to get ready.>
	Prompt4 <I better service my mek first.>

	% 05 - 06 :  What is the enemy point value?
	Prompt5 <What am I up against out there?>
	Prompt6 <How much defense does the corp have?>

	% 07 - 08 :  After being asked if he wants a job, PC says yes.
	Prompt7 <Absolutely.>
	Prompt8 <I could do that.>

	% 09 - 10 :  After being asked if he wants a job, PC says no.
	Prompt9 <Definitely not.>
	Prompt10 <That's not my kind of work.>

	% 11 - 13 : Player tries to get job using PLAN "A".
	%   By default, PLAN "A" is to sound tough and experienced.
	Prompt11 <I'm a serious badass. You need me.>
	Prompt12 <I want a cut of the action.>
	Prompt13 <You better have a cut for me, then.>

	% 14 - 16 : Player tries to get job using PLAN "B".
	Prompt14 <Need a hardened thief on your team?>
	Prompt15 <I've got lots of experience raiding corps.>
	Prompt16 <I can do dirty deeds, dirt cheap too!>

	% 17 - 19 : Player doesn't much care for the job.
	Prompt17 <I'm not into that kind of thing.>
	Prompt18 <Not interested.>
	Prompt19 <I don't do this kind of job.>


end

