Plot 0
	name <PLOT: CorpJob1>
	% VARIABLES USED
	% 1 -> Time Limit Timer
	% 2 -> Combat Indicator

	element1 <Grab 1>
	element2 <Character Corporate !Comrade 1>


	% Time limit - this plot will fade after a short time.
	% At timeout, it may or may not add a point to the Corporate Victory
	% counter.
	START <ifPersona E2 else GoDelete if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 120000>
	GotoCheckTime <ifG ComTime V1 if= V2 0 AdvancePlot 0 if= d3 1 S+ 101 1>
	GoDelete <AdvancePlot 0>

	% On a cleanup request, just get rid of this plot; unless, of
	% course, the PC has entered combat and is awaiting payment.
	CleanUp <ifG V2 0 AdvancePlot 0>

	% If combat has been entered, V2 = 1. This is important to keep
	% the events below from activating in scenes other than the
	% plot's combat...
	% After combat V2=2 for a loss, V2=3 for a win
	NU1 <if= T1 0 if= V2 1 V= 2 2 Reputation 6 -9>
	NU2 <if= T2 0 if= V2 1 V= 2 3 XPV 100 Reputation 6 1  S+ 101 1>

sub
	Persona 2
	rumor <!2 is going to hire a mecha pilot.>
	% The NPC who will offer the job.
	% PCs who don't have mecha will be sent elsewhere...
	% Only PCs with good reaction score will be offered a job.
	% V1 = Offered Mission
	% V2 = Message Randomizer
	% V3 = Difficulcy Level
	greeting <NewChat if= P2 3 else GoCheckLoss Say 33 CashPrize Reward Threat V3 100 100 AdvancePlot 0>
	GoCheckLoss <if= P2 2 else GoCheckMission Say 34 AdvancePlot 0>
	GoCheckMission <if= V1 1 else GoCheckDenial V= 2 10 V+ 2 d2 Say V2 AddChat 1 AddChat 2 AddChat 3>
	GoCheckDenial <if= V1 -1 else GoFirstTime SayAnything>

	% If the PC is a member of the corporate faction, he will
	% immediately be offered the job.
	GoFirstTime <ifG PCMeks 0 else GoNoMeks V= 3 FacVar N1 1000 V+ 3 d10 V+ 3 -d10 if= PCFac N1 else GoNoMember V= 1 1 V= 2 2 V+ 2 d3 Say V2 Memo 13 AddChat 1 AddChat 2 AddChat 3>

	% Otherwise, he will be offered the job if he is well-liked by
	% the NPC.
	GoNoMember <ifG React d50 else GoSmallChance ifG PCRep 6 V3 else GoSmallChance V= 2 5 V+ 2 d5 Say V2 AddChat 4 AddChat 5>
	GoSmallChance <ifG React -d15 else GoNoChance V= 2 14 V+ 2 d6 Say V2 V= 2 5 V+ 2 d2 AddChat V2 V= 2 7 V+ 2 d2 AddChat V2 V= 2 9 V+ 2 d2 AddChat V2>
	GoNoChance <V= 1 -1 SayAnything>

	GoNoMeks <Print d2>

	result1 <EndChat V= 2 30 V+ 2 d2 Say V2 SavePos P= 2 1 Dynamic 2 Threat V3 100 .nu1 .nu2 Encounter 5 20 .edesc>
	.nu1 <if= T1 0 Return>
	.nu2 <if= T2 0 Return>
	.edesc <Bandit Chaotic +PCRA>
	result2 <NewChat Say 21>
	result3 <NewChat Say 22 AddChat 1 AddChat 2>
	result4 <NewChat V= 1 1 V= 2 2 V+ 2 d3 Say V2 Memo 13 AddChat 1 AddChat 2 AddChat 3>
	result5 <NewChat V= 1 -1 Say 14>

	result6 <NewChat Reputation 4 -d10 ifG Intimidation 10 else GoR6789NoRoll V= 1 1 Memo 13 V= 2 25 V+ 2 d5 Say V2 AddChat 1 AddChat 2 AddChat 3>
	GoR6789NoRoll <V= 1 -1 V= 2 23 V+ 2 d2 Say V2>
	result7 <Goto result6>
	result8 <NewChat ifG Conversation 10 else GoR6789NoRoll V= 1 1 Memo 13  V= 2 25 V+ 2 d5 Say V2 AddChat 1 AddChat 2 AddChat 3>
	result9 <Goto result8>
	result10 <NewChat Reputation 5 d6 Reputation 4 d8 V= 1 -1 Say 23>
	result11 <Goto result10>


	Msg1 <I have a job avaliable for a mecha pilot. It's too bad that you don't have a mecha.>
	Msg2 <If you're looking for a job with \NARRATIVE 1 , you should buy yourself a mecha.>
	Msg3 <\NARRATIVE 2 and his bandits have just launched another raid against one of our warehouses. Your pay will be $ \VAL Reward Threat V3 100 100 .>
	Msg4 <The \NARRATIVE 2 raiders have just attacked one of our warehouses. I need you to move out immediately and stop them. The reward for this mission is $ \VAL Reward Threat V3 100 100 .>
	Msg5 <One of our warehouses is under attack by mecha-equipped raiders. I need you to move out right away and defend our corporate property. You'll earn $ \VAL Reward Threat V3 100 100 for this contract.>

	Msg6 <Are you looking for some work? I have a corporate defense mission that needs doing, if you're interested.>
	Msg7 <How would you like to run a mission for \NARRATIVE 1 ? I have a single contract avaliable, if you're interested.>
	Msg8 <If you're looking for a job, I have a one-time contract for a mecha pilot to run a single corporate defense mission.>
	Msg9 <I need a mecha pilot immediately. Are you looking for work?>
	Msg10 <You should know that \NARRATIVE 1 generously rewards those who serve it. I have a single mission for a mecha pilot avaliable, if you're interested in earning a bit of cash.>

	Msg11 <Are you ready for that job yet?>
	Msg12 <If you're ready you can start that mission we spoke about earlier.>
	Msg13 <\ELEMENT 2 in \SCENE EScene 2 has offered you a defense mission for \NARRATIVE 1 .>
	Msg14 <That's too bad.>
	Msg15 <\NARRATIVE 1 is under attack from ruthless bandits.>
	Msg16 <I'm very busy right now... The \SCENE EScene 2 warehouse is being attacked by bandits!>
	Msg17 <In the modern age, armored bandits are the greatest threat to international commerce.>
	Msg18 <Our company has been having bandit problems.>
	Msg19 <The recent losses by \NARRATIVE 1 have been caused by bandit raiders, but there is absolutely no reason for our stockholders to worry.>
	Msg20 <It's a busy day. Another one of our convoys has been hit by bandits... the trucking union's on my back, there's a load of paperwork to fill out, so on and so on...>

	Msg21 <Make sure your equipment is in order, then report back here to start the mission.>
	Msg22 <The bandits have about \VAL Threat V3 100 tactical points worth of mecha.>
	Msg23 <Things should be looking better by the next quarter, I hope...>
	Msg24 <No, we currently have all the mecha pilots that we need.>
	Msg25 <Sorry, \NARRATIVE 1 is not currently hiring any new pilots.>

	Msg26 <Maybe you could help us. A bandit assault group has been spotted outside of one of our warehouses, and it needs to be eliminated. Your pay will be $ \VAL Reward Threat V3 100 100 .>
	Msg27 <I think that's a good idea. I can offer you $ \VAL Reward Threat V3 100 100 to eliminate a gang of bandits which has been attacking our convoys.>
	Msg28 <I would be glad to work with you. A gang of bandits has been attacking our trucks; eliminate them for $ \VAL Reward Threat V3 100 100 .>
	Msg29 <I can offer you $ \VAL Reward Threat V3 100 100 to eliminate a gang of bandits that's been giving us trouble.>
	Msg30 <If you're interested in a job, here are the details. For $ \VAL Reward Threat V3 100 100 you will engage and defeat a bandit gang which has been raiding our facilities.>

	Msg31 <Here are the coordinates. Eliminate the bandits then return here to receive your pay.>
	Msg32 <This is the last known position of the gang. Intercept and destroy them, then come back here for your pay.>
	Msg33 <Good work. Here's your pay.>
	Msg34 <The mission was a failure.>

	Prompt1 <I'm ready to move out.>
	Prompt2 <I need some time to prepare.>
	Prompt3 <What will I be facing out there?>
	Prompt4 <Give me the details.>
	Prompt5 <Sorry, I have other things to do.>

	Prompt6 <I could get rid of them, for a price...>
	Prompt7 <You need an ace pilot... That's me.>
	Prompt8 <Maybe I could help you. I'm a mecha pilot.>
	Prompt9 <Will you be hiring someone to fight them?>
	Prompt10 <That's too bad.>
	Prompt11 <Hope it clears up.>

end

