Plot 0
	name <ARC: Revenge Seeker>
	% The PC will get the chance to meet the NPC with the
	% vendetta against N1, and learn the reason for the
	% attacks...

	Element1 <Grab 2>
	Element2 <Scene Town>
	Element3 <Prefab>
	Element4 <Grab 1>

	% V1 = Initialization counter; there's no real time limit
	% V101 = Spoke with E1
	% V103 = Spoke with E2

	cleanup <AdvancePlot 0>

	start <if= V1 0 V= 1 1 MoveChar E1 N3 SetNPCFaction E3 E4>

sub
	Persona 1
	rumor <!1 has a personal vendetta against the corporations.>
	greeting <NewChat Say 1 AddChat 1 AddChat 2 AddChat 3>

	result1 <NewChat Say 2 AddChat 4 AddChat 5 AddChat 6 if= V101 0 V= 101 1 Reputation 4 d12>
	result2 <NewChat ifG NPCRep E1 1 -1 else GoR2NPCVillain Say 3 AddChat 7 AddChat 9 AddChat 10>
	GoR2NPCVillain <Say 4 AddChat 7 AddChat 8 AddChat 10>
	result3 <NewChat Say 5 AddChat 11 AddChat 12 if= V102 0 V= 102 1 Reputation 1 d3>
	result4 <NewChat Say 6 AddChat 13 AddChat 14>
	result5 <Goto Prompt3>
	result6 <NewChat if= PCFac E4 else GoR6NoCorp Say 7 AddChat 12 AddChat 15>
	GoR6NoCorp <Say 8 AddChat 11 AddChat 12>
	result7 <NewChat Say 9 AddChat 16 AddChat 18 ifG NPCRep E1 1 -1 AddChat 17>
	result8 <NewChat Say 10 AddChat 7 AddChat 10>
	result9 <NewChat Say 11 AddChat 20 AddChat 19>
	result10 <NewChat Say 12 SoloAttack E1 ifG NPCRep E1 1 -1 Reputation 1 -5>
	result11 <NewChat Say 13 AddChat 10 AddChat 13>
	result12 <NewChat Goto result2>
	result13 <NewChat Say 14>
	result14 <NewChat Goto result2>
	result15 <NewChat Say 15 SoloAttack E1 ifG NPCRep E1 1 -1 Reputation 1 -5>
	result16 <NewChat Say 16 AdvancePlot 1 if= PCFac E4 Reputation 6 -30 Reputation 2 -10>
	result17 <NewChat if= PCFac 3 else GoR17NoGuard Say 17 AdvancePlot 2>
	GoR17NoGuard <Say 18 AddChat 21 AddChat 22 AddChat 18>
	result18 <Goto result13>
	result19 <Goto result17>
	result20 <Goto result16>
	result21 <NewChat Say 19 AdvancePlot 2 Reputation 1 1 Reputation 2 1>
	result22 <Goto result16>

	Msg1 <You've done a lot of work to find me. I guess you must know who I am by now.>
	Msg2 <Really? I know you've done much to find me... for no reason, knowing not what you were searching for? Possible, I suppose. Tell me, what is it that you seek?>
	Msg3 <\ELEMENT 3 of \ELEMENT 4 had my father killed for speaking out against the company. The guardian who investigated was paid off and the case dropped... I seek justice, by the only means I have left.>
	Msg4 <I was fired from their company... Can you imagine? Me, fired! But I will have my revenge, one way or the other...>
	Msg5 <Justice? That word rings hollow to my ears. There is no justice in this world, save that which can be taken by the barrel of a gun. If you care to be educated, I can tell you how I know this...>
	Msg6 <Well, I have an adventure for you, if you're willing to play along...>
	Msg7 <Doing your job? I hope you realize what a soulless abherration it is that you serve... \ELEMENT 4 is far worse than any criminals which oppose it. It is evil, sickening, and I intend to cleanse it from the earth...>
	Msg8 <Doing your job? I guess you could say that I am doing the same thing... I can tell you my reasons, if you have the time to listen.>
	Msg9 <The corporation needs to be shattered. I have one last job planned... If you would be my pilot, we could cripple \ELEMENT 4 forever.>
	Msg10 <They destroyed my career, my dreams, my financial security! It may be cruel and petty to attack them for this, but it is no more cruel and petty than they are themselves.>
	Msg11 <What other options are there? They are too powerful in society... criminal action is the only choice we have.>
	Msg12 <You may try if you'd like, but I've killed before and am not ready to be stopped by you...>
	Msg13 <So what now? Will you try to stop me, even without knowing what it is that I am doing?>
	Msg14 <Then leave me be, so I may finish my work.>
	Msg15 <If you would die to protect those snakes, I am more than willing to oblige you!>
	Msg16 <Go get your equipment in order, then meet me back here in an hour. You've progressed this far so I have no doubt that you can complete the rest of this task.>
	Msg17 <Really? Hm, I guess not all guardians are as corrupt as I thought... \ELEMENT 3 lives in \ELEMENT 2 . Do what you can, but if you fail then I will do what I must...>
	Msg18 <What good would it do? The guardians have already been bought off, the corporation always protects its own... there is only one path left open to me!>
	Msg19 <You are an optimist. Life has long beaten that out of me... \ELEMENT 3 may be found in \ELEMENT 2 . Go do as you can, but if you fail then I will do what I must.>

	Prompt1 <Actually, no I don't...>
	Prompt2 <Why are you fighting \NARRATIVE 1 ?>
	Prompt3 <I'm here to bring you to justice.>
	Prompt4 <Adventure.>
	Prompt5 <Justice.>
	Prompt6 <I'm just doing my job.>
	Prompt7 <I want to join your cause.>
	Prompt8 <All this because you were fired!?>
	Prompt9 <I'm no outlaw, but I want to help.>
	Prompt10 <I will stop you.>
	Prompt11 <I don't want to hear it.>
	Prompt12 <Tell me what you're talking about.>
	Prompt13 <No, I don't want to get involved.>
	Prompt14 <Alright, tell me about it.>
	Prompt15 <You won't talk about my company like that!>
	Prompt16 <Let's do that.>
	Prompt17 <I can't do that, but I can find \ELEMENT 3 .>
	Prompt18 <On second thought, I want no part of this.>
	Prompt19 <\ELEMENT 3 can be brought to justice.>
	Prompt20 <Maybe you're right...>
	Prompt21 <I have to try.>
	Prompt22 <You're right. Let's just attack.>

	Persona 3
	rumor <!3 enforces the policies of !4 with an iron fist.>
	greeting <NewChat SayAnything>


	Plot 1
		% NPC will make one last attack against E4, possibly
		% destroying it...
		start <ifPersona E1 else GoDelete ifFaction E4 else GoDelete if= V1 0 memo 1 V= 1 1 FreezeNPC E3 PCEnemy E3 E= 3 0>
		GoDelete <AdvancePlot 0>

		% Combat check. If combat has been entered, V2=1.
		nu1 <if= T1 0 if= V2 1  V= 2 2  Reputation 6 -7>
		nu2 <if= T2 0 if= V2 1  V= 2 3  Reputation 6  1  XPV 50>

		Msg1 <\ELEMENT 1 in \SCENE ESCene 1 wants you to help attack \ELEMENT 4 .>
	sub
		Persona 1
		% V3 = Threat Value
		% V4 = Mission Pay
		greeting <NewChat V= 3 Threat FacVar E4 1000 150 V= 4 Reward V3 200 if= P2 3 else GoCheckLoss Say 2 CashPrize V4 S= 101 -750 PCAlly E1 AdvancePlot 0>
		GoCheckLoss <if= P2 2 else GoSayMission PCAlly E1 Say 3 AdvancePlot 0>
		GoSayMission <Say 1 AddChat 1 AddChat 2 AddChat 3>

		result1 <EndChat Say 4 SavePos P= 2 1 Dynamic 2 V3 .nu1 .nu2 Encounter 99 0 .edesc Reputation 2 -5 ifG NPCRep E1 1 -1 Reputation 1 1>
		.nu1 <if= T1 0 Return>
		.nu2 <if= T2 0 Salvage Return>
		.edesc <CORPORATE +PCRA>
		result2 <NewChat Say 5 AddChat 1 AddChat 3>
		result3 <NewChat Say 6>

		Msg1 <I have the details all worked out. The \ELEMENT 4 "enforcer" squad is currently deployed at a vunerable position. If we strike now, we can destroy them, and with them the corp's ability to assert its power.>
		Msg2 <With their main enforcement team destroyed, \ELEMENT 4 has been crippled! Now, hopefully they will never be able to do again what they did to me... Here's the pay I promised you.>
		Msg3 <You did not complete the mission... \ELEMENT 4 will not be careless enough to give us a chance like that again for a long time. But, when they do make a mistake, I will be ready to strike...>
		Msg4 <These are the coordinates. Proceed to the strike zone, and disable all the corporate wage-slaves you encounter.>
		Msg5 <The corp has about \VAL V3 threat points worth of mecha, all of which needs to be disabled in order to make this worth our while. I'll pay you a reward of $ \VAL V4 upon completing the mission.>
		Msg6 <You better do that. This is going to be a hard battle.>

		Prompt1 <Let's get this mission started.>
		Prompt2 <Tell me the details of the operation.>
		Prompt3 <Maybe I should get ready, first.>

	end

	Plot 2
		% PC will talk with E3, thereby ending the adventure
		% in a  big fight.
		start <ifPersona E1 else GoE1Dead ifPersona E3 else GoE3Dead if= V1 0 memo 1 V= 1 1>
		GoE1Dead <ifPersona E3 else GoDelete>
		GoE3Dead <ifPersona E1 else GoDelete>
		GoDelete <AdvancePlot 0>

		Msg1 <\ELEMENT 1 in \SCENE ESCene 1 wants you to help bring \ELEMENT 3 in \SCENE EScene 3 to justice.>
	sub
		Persona 1
		greeting <NewChat ifPersona E3 else GoE3Dead Say 1>
		GoE3Dead <Say 2 PCAlly E1 XPV 1000 Reputation 1 1 Reputation 6 d3 EndStory AdvancePlot 0 if= d2 1 AddChat 1>
		result1 <NewChat Say 3>
		Msg1 <\ELEMENT 3 must be punished for what he did to my father...>
		Msg2 <I can't believe that you have done it... My quest is finished. My father's spirit can finally rest in peace. I will always be thankful for what you have done.>
		Msg3 <Still, I can't help but wonder... Why did he give his own life so easily? Is there some greater secret about \ELEMENT 4 that he died to protect?>
		Prompt1 <You're welcome.>

		Persona 3
		rumor <!3 enforces the policies of !4 with an iron fist.>
		greeting <NewChat Say 1 AddChat 1 AddChat 2 AddChat 3>

		% Once the PC confronts the NPC, he will be subject to
		% a series of bribes and threats...
		GoStartPath <NewChat if= PCFac E4 else GoSPNoMem Say 7 AddChat 10 AddChat 11>
		GoSPNoMem <Say 8 AddChat 12 AddChat 13>

		% If the PC agrees to the NPC's demands, the plot ends in
		% a bad way.
		GoSellOut <Reputation 1 -10 Reputation 2 -10 Reputation 6 -10 FreezeChar E1 PCEnemy E1 PCEnemy E3 storyline .assassin else GoEndPlot AdvancePlot 0>
		.assassin <TS_PLOT_Assassin_*.txt>
		GoEndPlot <AdvancePlot 0>

		result1 <Goto GoStartPath>
		result2 <NewChat Say 2 AddChat 4 AddChat 5>
		result3 <NewChat if= PCFac E4 else GoR3NoMember Say 3 AddChat 6 AddChat 7>
		GoR3NoMember <Say 4  AddChat 8 AddChat 9>
		result4 <NewChat Say 5 CashPrize Reward Threat PCRep 6 100 500 Goto GoSellOut>
		result5 <Goto GoStartPath>
		result6 <NewChat Say 6 Goto GoSellOut>
		result7 <Goto GoStartPath>
		result8 <Goto result4>
		result9 <Goto GoStartPath>
		result10 <NewChat Say 9 AddChat 14 AddChat 15>
		result11 <Goto result4>
		result12 <Goto result10>
		result13 <Goto result4>
		result14 <NewChat Say 10 Goto GoSellOut>
		result15 <EndChat Say 11 Reputation 1 1 Reputation 2 1 SoloAttack E3>

		Msg1 <Yes, what do you want? I am far too busy to chat with every mongrel who wanders in off the street.>
		Msg2 <This better be important.>
		Msg3 <That fool's father was going to disclose private corporate records to the media. I couldn't allow that... \ELEMENT 1 went on to become a bandit. Obviously these are dangerous, unstable people. You see now I was justified in what I did.>
		Msg4 <\ELEMENT 1 ? The name doesn't sound familiar. I deal with so many unimportant people on a daily basis, I can't be expected to remember each one. Tell me, what is this really about? You're here for money, is that it?>
		Msg5 <Is that all? I won't even bother asking whose family sent you here; it's not important. Take this cash and forget everything you know about me, and about \ELEMENT 4 .>
		Msg6 <Then run along, and trust the operation of this company to your superiors. I expect that you will have no further difficult questions.>
		Msg7 <Anything I have done, it has been for the good of \ELEMENT 4 . You wouldn't throw your entire career away just to confront me over such a trivial matter, would you?>
		Msg8 <Surely we can come to an arrangement... There's no need for you to make a big deal out of this, I can make sure that your life will be very comfortable...>
		Msg9 <Don't play with fire. \ELEMENT 4 is very powerful... press too far, and you will get burned. I'm giving you one last chance to pull back. If you proceed in this matter, I promise that you will regret it dearly...>
		Msg10 <In the years to come, I'm sure you will be thankful that you were so reasonable today. Forget everything you know about me, and about \ELEMENT 4 .>
		Msg11 <Since you feel so strongly about it... I cannot allow you to leave this place alive. \ELEMENT 4 must be protected at all costs.>

		Prompt1 <I know that you're a murderer.>
		Prompt2 <I have a business offer for you.>
		Prompt3 <Tell me about \ELEMENT 1 .>
		Prompt4 <Give me money or I turn you in.>
		Prompt5 <Turn yourself in, or I kick your ass.>
		Prompt6 <Yes, of course. Sorry for troubling you.>
		Prompt7 <No, I don't see that at all.>
		Prompt8 <Yes, that's it.>
		Prompt9 <No, I'm here for justice.>
		Prompt10 <I think I would.>
		Prompt11 <Some cash would change my mind.>
		Prompt12 <No deals. You're going down.>
		Prompt13 <Sounds nice, I'll take the deal.>
		Prompt14 <Okay, I'd like to live, I'll go away...>
		Prompt15 <Don't count on it. I'm not afraid of you.>

	end

end
inv
	NPC Corporate Executive
	EquipChar 15000
	chardesc Pragmatic Villainous
	place <2 ally pass>
	skill 33 10
	skill 1 8
	skill 2 8
	skill 3 8
	skill 4 8
	skill 5 8
	skill 6 8
	skill 7 8
	skill 8 8
	skill 9 8
	skill 10 8
	mecha <Jos.txt>

end
