story
	name <STORY: Bandit vs Big Business>

	% A bandit has launched an apparently personal campaign against
	% one corporation.
	% This story has two threads: Defense and Investigation.
	%
	% By defense, the PC can weaken the bandit's assault and
	% eventually end it. Route favored by Corporate Executives.
	%
	% By investigation, the PC can discover who the bandit is and
	% why they are launching this attack, and eventually put an end
	% to them. Route favored by Guardians.
	%
	%
	% Other associated plots...
	% - Bandits offering sub-contract work against the corporation
	% - Truckers and Corp Execs offering independant missions against
	%   bandits

	% Element 1 = Controlling Faction
	% Element 2 is the bandit
	Element2 <Prefab>

	% Element 3 is a town used in the investigation
	Element3 <Scene Town>


	% V2 = Time Limit, activated after the story has officially ended.
	% V3 = Message Randomizer
	% V4 = Clues Accumulated
	% V5 = Load investigation thread story if V5=0
	% V101 = Corporate Victories

	hour <ifG 20 V101 ifG V101 -20 Storyline .defstory else GoLoadInv Goto GoLoadInv>
	.defstory <TS_CORP_PLOT_BVX_*.txt>

	% Load an investigation-thread story if appropriate.
	GoLoadInv <if= V5 0 ifG 5 V4 else GoLoadConclusion Storyline .invstory V= 5 1>
	.invstory <TS_CORP_PLOT_BVXi_*.txt>
	GoLoadConclusion <Storyline .constory V= 5 1>
	.constory <TS_CORP_PLOT_BVXc_*.txt>

	% If the end-news timer hasn't been set, display a new
	% news article every quarter.
	Quarter <if= V2 0 ifG V101 0 else GoCorpLosing V= 3 100 V+ 3 d10 News V3>
	GoCorpLosing <V= 3 200 V+ 3 d10 News V3>

	% If a timer has been set, end the story when time runs out.
	start <ifPersona N2 else GoEndStory ifG V4 0 else GoCheckTimer Memo 1001 Goto GoCheckTimer>
	GoCheckTimer <if# V2 0 else GoCheckWin ifG ComTime V2 EndStory>
	GoCheckWin <ifG V101 19 else GoCheckLoss PurgeStory News d5 Trigger FACWIN N1 V= 2 ComTime V+ 2 86400>
	GoCheckLoss <ifG -19 V101  PurgeStory V= 3 50 V+ 3 d5 News V3 Trigger FACLOSE N1 V= 2 ComTime V+ 2 86400>
	GoEndStory <EndStory>

	% End-of-story news articles: Corporation won.
	Msg1 <Stock value rises as \NARRATIVE 1 defeats bandit threat.>
	Msg2 <\NARRATIVE 1 crushes bandit threat; sends strong message to all others who would interfere in free business.>
	Msg3 <\NARRATIVE 1 has declared bandit crisis officially over. Victory credited to superior mecha technology.>
	Msg4 <Shipping costs expected to drop now that \NARRATIVE 1 has defeated bandits.>
	Msg5 <FedTer safe for commerce once again due to \NARRATIVE 1 new mecha technology.>

	% End-of-story news articles: Corporation lost.
	Msg51 <\NARRATIVE 1 abandons expansion plan due to bandit raids. Layoffs, salary rollbacks expected.>
	Msg52 <The bandit attacks against \NARRATIVE 1 have been stopped, but corporate infrastructure is in ruins.>
	Msg53 <Factories, warehouses lie in ruins as \NARRATIVE 1 struggles to recover from worst anti-corp violence in recent history.>
	Msg54 <\NARRATIVE 1 may not recover from recent losses for a long time, says industry analyst.>
	Msg55 <The bandit attacks have ended, but maybe because \NARRATIVE 1 has nothing left to steal. Layoffs expected.>

	% In-Story news articles: Corporation is winning
	Msg101 <Bandit lord \NARRATIVE 2 has launched personal campaign against \NARRATIVE 1 .>
	Msg102 <\NARRATIVE 1 stock value holds steady despite bandit attacks.>
	Msg103 <Bandits attack \NARRATIVE 1 facilities moreso than any other corporation.>
	Msg104 <Corporate leaders at \NARRATIVE 1 plan to expand their security forces.>
	Msg105 <\NARRATIVE 2 leads string of bandit raids against \NARRATIVE 1 .>
	Msg106 <\narrative 1 security forces show true grit in face of criminal aggression.>
	Msg107 <\narrative 1 announces new jobs available in corporate security force.>
	Msg108 <\narrative 1 declares war on bandits; says it will take fight to illicit dead-zone trading camps.>
	Msg109 <Despite bandit attacks, \NARRATIVE 1 expected to make record profits this quarter.>
	Msg110 <\NARRATIVE 1 pledges funds and mecha to protect union trucks against highway robbery.>

	% In-Story news articles: Corporation is losing
	Msg201 <Bandit lord \NARRATIVE 2 has significantly weakened \NARRATIVE 1 ; corporate heads call for Guardian involvement.>
	Msg202 <\NARRATIVE 1 experiences lost revenue due to bandit attacks. Stock prices plummet.>
	Msg203 <Bandits attacks against \NARRATIVE 1 appear to be some sort of vendetta.>
	Msg204 <Corporate leaders at \NARRATIVE 1 seek to minimize damages following a string of bandit raids.>
	Msg205 <\NARRATIVE 2 leads string of wildly successful bandit raids against \NARRATIVE 1 .>
	Msg206 <\narrative 1 suffers economic loss due to security failure; layoffs expected.>
	Msg207 <\narrative 2 leads raids against \narrative 1 facilities. Motive behind attacks still unknown.>
	Msg208 <\NARRATIVE 1 unable to deal with bandit raids. Corporate leaders appeal to guardians, military for help.>
	Msg209 <Leaders of \NARRATIVE 1 appeal to Defense Force for protection of trade routes against highway robbery.>
	Msg210 <Bandits target \NARRATIVE 1 as most vunerable corporation to attack.>

	% Investigation memo
	Msg1001 <You have heard that there are many bandits around \NARRATIVE 3 lately.>


inv
	NPC Soldier
	job <Renegade>
	mecha <Daum.txt>
	EquipChar 17000
	chardesc Chaotic Passionate

end
