Plot 0
	name <PLOT: GuardJob1>
	% VARIABLES USED
	% 1 -> Time Limit Timer
	% 2 -> Combat Indicator

	element1 <Character Guardian>
	% Element 2 -> Difficulcy Level

	rumor <!1 may have a job opening for a mecha pilot.>

	% Time limit - this plot will fade after a short time.
	START <if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 25000>
	GotoCheckTime <ifG ComTime V1 if= V2 0 AdvancePlot 0>

	% If combat has been entered, V2 = 1. This is important to keep
	% the events below from activating in scenes other than the
	% plot's combat...
	NU1 <if= T1 0 if= V2 1 AdvancePlot 1 Reputation 6 -8          V= 2 2>
	NU2 <if= T2 0 if= V2 1 AdvancePlot 2 XPV 50 Reputation 6 1    V= 2 2>

sub
	Persona 1
	% The NPC who will offer the job.
	% PCs who don't have mecha will be sent elsewhere...
	% Only PCs with good reaction score will be offered a job.
	greeting <NewChat ifG PCMeks 0 else GoNoMeks ifG React 45 else GoMedReact Goto GoJobDesc>

	% PCs with a medium reaction score have a chance to get offered a job,
	% if they make a good impression on the NPC.
	GoMedReact <ifG React 25 else GoMed2 Say 22 AddChat 4 AddChat 5>

	GoMed2 <ifG React 10 else GoLowReact Say 3 AddChat 1 AddChat 2 AddChat 3>

	% PCs with a low reaction score will most likely be told to buzz off.
	GoLowReact <EndChat Say 4>

	% With no meks, the PC won't get offered a job at all, but may be told
	% about it.
	GoNoMeks <ifG React 30 else GoNMMedReact Say 1>
	GoNMMedReact <Say 2>
	GoNMLowReact <EndChat Say 4>

	% Result 1 -> The player will try to charm the NPC with CONVERSATION
	result1 <ifG SkRoll 19 10 else GoNoCon NewChat Say 8 AddChat 4 AddChat 5>
	GoNoCon <NewChat Say 7>

	% Result 2 -> The player will try to impress the NPC with INTIMIDATION
	result2 <Reputation 2 -1 ifG SkRoll 28 15 else GoNoInt NewChat Say 9 AddChat 4 AddChat 5>
	GoNoInt <AdvancePlot 0 Reputation 1 -1 Reputation 6 -1 Say 6 EndChat>

	% Result 3 -> The player goes quietly away.
	result3 <NewChat Say 5>

	% Result 4 -> Go straight to the job description.
	result4 <Goto GoJobDesc>

	% Result 5 -> Go away.
	result5 <NewChat Say 10>

	% The NPC will describe the job being offered. This will depend upon the
	% PC's reputation.
	% V1 = Threat Value of Encounter
	GoJobDesc <ifG PCRep 6 90 Else GoLvl9 V= 1 12000000 E= 2 10 Say 11 goto GoChoose>
	GoLvl9 <ifG PCRep 6 80 Else GoLvl8 V= 1 6500000 E= 2 9 Say 12 goto GoChoose>
	GoLvl8 <ifG PCRep 6 70 Else GoLvl7 V= 1 3300000 E= 2 8 Say 13 goto GoChoose>
	GoLvl7 <ifG PCRep 6 60 Else GoLvl6 V= 1 1700000 E= 2 7 Say 14 goto GoChoose>
	GoLvl6 <ifG PCRep 6 50 Else GoLvl5 V= 1  900000 E= 2 6 Say 15 goto GoChoose>
	GoLvl5 <ifG PCRep 6 40 Else GoLvl4 V= 1  500000 E= 2 5 Say 16 goto GoChoose>
	GoLvl4 <ifG PCRep 6 30 Else GoLvl3 V= 1  300000 E= 2 4 Say 17 goto GoChoose>
	GoLvl3 <ifG PCRep 6 20 Else GoLvl2 V= 1  200000 E= 2 3 Say 18 goto GoChoose>
	GoLvl2 <ifG PCRep 6 10 Else GoLvl1 V= 1  100000 E= 2 2 Say 19 goto GoChoose>
	GoLvl1 <ifG PCRep 6  0 Else GoLvl0 V= 1   75000 E= 2 1 Say 20 goto GoChoose>
	GoLvl0 <V= 1  50000 E= 2 1 Say 20 goto GoChoose>

	% The encounter has been described, and a threat rating been set.
	% See whether or not the PC will accept the job.
	GoChoose <NewChat AddChat 6>

	Result6 <EndChat Say 21 P= 2 1 SavePos Dynamic 2 V1 FrzNU1 FrzNU2 Encounter 2 5 .enemydata>
	FrzNU1 <if= T1 0 Return>
	FrzNU2 <if= T2 0 Salvage Return>
	.enemydata <Chaotic ArchEnemy +PCRA>

	Msg1 <I need a mecha pilot to run some patrols for us.>
	Msg2 <I'm very busy right now. Please come back later.>
	Msg3 <I'v very busy now; if you have a problem please take it to one of the other guardians.>
	Msg4 <I'm busy. Go away.>
	Msg5 <Take care, citizen.>
	Msg6 <I don't have time for this crap.>
	Msg7 <It's nothing that you can help me with. Good day.>
	Msg8 <If you must know... I need a mecha pilot to run some patrols for the guardians. Are you interested?>
	Msg9 <Maybe you're the kind of pilot I'm looking for... the guardians need someone to run a few patrols. You interested?>
	Msg10 <That's a shame. Well, take care, citizen.>

	Msg11 <A major force of unknown mecha has been assembling outside of town. Whatever they want, it can't possibly be good. I need you to eliminate their unit. Pay is $96000 plus salvage rights.>
	Msg12 <Some powerful mecha were stolen from an army base several days ago. Now they've been spotted in our jurisdiction. I need you to disable them. Pay is $52000 plus any salvage you can recover.>
	Msg13 <A group of unregistered mecha are moving towards the city powerplant. I need you to intercept and disable them. Pay is $26700 plus salvage rights.>
	Msg14 <Several mecha belonging to known criminals have entered our jurisdiction. I need you to eliminate their gang before they can cause any trouble. The reward is $13600 plus salvage.>
	Msg15 <A small force of unknown mecha has been assembling near here. I need you to investigate their camp, and eliminate them if they appear agressive. The pay is $7200 and possible salvage.>
	Msg16 <An unregistered mecha has been attacking travellers. No motive for these attacks can been determined. I need you to stop this pilot, using whatever means are necessary. Pay is $4000 plus the salvage rights to any leftover mecha.>
	Msg17 <One of the local crime gangs has recently acquired some military hardware. I need you to destroy their mecha before they have a chance to really use them. The reward is $2400 plus salvage rights.>
	Msg18 <A mecha gang has been terrorizing the highway leading into town. Sensor sweeps have finally picked up what seems to be their hideout... I need you to go there and eliminate them. Pay is $1600 plus salvage.>
	Msg19 <Mecha bandits have been robbing trucks outside of town. The trade union is gonna have a fit if we don't stop them soon. There's a reward of $800 if you can get rid of them, plus salvage.>
	Msg20 <There's been some criminal mecha activity in the area. They have a couple of powered armor units, nothing too major. I need you to eliminate them. Pay is $500 plus whatever salvage is left over when you're done.>

	Msg21 <I've uploaded all the relevant information to your mecha. Good luck.>

	Msg22 <How would you like to run a mission for the guardians?>

	prompt1 <What's going on?>
	prompt2 <You'll talk to me now.>
	prompt3 <Okay.>
	prompt4 <I'm interested.>
	prompt5 <I'm not interested.>
	prompt6 <I'll do it.>


	Plot 1
		% The player lost the battle.
		% Time limit - this plot will fade after a short time.
		START <if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 17500>
		GotoCheckTime <ifG ComTime V1 AdvancePlot 0>
	sub
		Persona 1
		% The exact message given by the NPC will vary depending on
		% whether or not the PC is well-liked...
		greeting <NewChat AdvancePlot 0 ifG React 50 else GoMedReact Say 1>
		GoMedReact <ifG PCRep 6 75 else GoMedRenown Say 2>
		GoMedRenown <ifG React 15 else GoLowReact Say 3>
		GoLowReact <ifG PCRep 6 25 else GoLowRenown Say 4>
		GoLowRenown <Say 5>

		Msg1 <You had some miserable luck out there. At least you came home in one piece, that's the important thing.>
		Msg2 <You had a rough time out there. I guess the criminals were more powerful than we thought.>
		Msg3 <You failed to stop the criminals. At least you didn't get hurt...>
		Msg4 <Your mission was a failure. I guess you aren't as deserving of your good reputation as we thought.>
		Msg5 <Your mission was a complete failure.>
	end

	Plot 2
		% The player won the battle.
		% Time limit - this plot will fade after a short time.
		START <if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 17500>
		GotoCheckTime <ifG ComTime V1 AdvancePlot 0>
	sub
		Persona 1
		greeting <NewChat AdvancePlot 0 if= E2 10 Else GoLvl9 CashPrize 96000 Say 1>
		GoLvl9 <if= E2 9 Else GoLvl8 CashPrize 52000 Say 2>
		GoLvl8 <if= E2 8 Else GoLvl7 CashPrize 26700 Say 3>
		GoLvl7 <if= E2 7 Else GoLvl6 CashPrize 13600 Say 4>
		GoLvl6 <if= E2 6 Else GoLvl5 CashPrize  7200 Say 5>
		GoLvl5 <if= E2 5 Else GoLvl4 CashPrize  4000 Say 6>
		GoLvl4 <if= E2 4 Else GoLvl3 CashPrize  2400 Say 7>
		GoLvl3 <if= E2 3 Else GoLvl2 CashPrize  1600 Say 8>
		GoLvl2 <if= E2 2 Else GoLvl1 CashPrize  800 Say 9>
		GoLvl1 <CashPrize 750 Say 10>

		Msg1 <That was an incredible battle! You truly are one of the best pilots anywhere. Here's your reward; you really earned it!>
		Msg2 <Excellent job! The mecha thieves have been stopped. Once again you've proven your worth as a pilot. Here's the reward, as promised.>
		Msg3 <You stopped the raiders before they could get to the powerplant. Our city owes you its gratitude! Here's your pay.>
		Msg4 <You have certainly lived up to your good reputation! Here's your pay for defeating the crime gang.>
		Msg5 <Very good work. The enemy mecha have been eliminated. Here's your pay.>
		Msg6 <Good job. I now see why people say you could become a great pilot. Here's your pay for that mission.>
		Msg7 <Good job. You performed very well on that mission. Here's your reward.>
		Msg8 <The mission was a complete success. Here's your pay.>
		Msg9 <With the bandits gone hopefully life here will return to normal... until the next emergency, of course. Here's your reward.>
		Msg10 <Congradulations, you stopped the mecha gang. Keep this up and you'll be known as a decent pilot in no time. Here's your pay.>
	end


end

