Plot 0
	name <ARC: Organ Thief Convoy 1>

	% VARIABLES USED
	% 1 -> Time Limit Timer
	% 2 -> Combat Indicator

	element1 <Character Guardian Pragmatic>
	% Element 2 stores a general notification variable

	% Time limit - this plot will fade after a short time.
	START <ifPersona E1 else GoDelete if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 155000>
	GotoCheckTime <ifG ComTime V1 if= V2 0 ifG NPCRep E1 7 d100 else GoDelete S+ 101 d10 AdvancePlot 1>
	GoDelete <AdvancePlot 2>

	% Upon recieving a cleanup trigger, just clean up.
	Cleanup <if= V2 0 else GoCheck2 AdvancePlot 0>
	GoCheck2 <if= V2 2 AdvancePlot 0>

	% Check for email every five minutes.
	% The PC will only get email if he's a guardian,
	% and if some progress has already been made in the case.
	5min <if= E2 0 ifG S101 0 if= d100 23 if= PCFac N1 ifG RReact E1 d70 E= 2 1 Email d5>

	Msg1 <\ELEMENT 1 @ \SCENE EScene 1 //: Be on the lookout for a cold storage truck with blue markings. May be connected to the organ thief case.>
	Msg2 <\ELEMENT 1 @ \SCENE EScene 1 //: Searching for a blue medical truck connected to organ thief murders. You may spot it while travelling.>
	Msg3 <\ELEMENT 1 @ \SCENE EScene 1 //: Blue medical truck may be linked to organ thief case. If you see it while travelling, capture immediately.>
	Msg4 <\ELEMENT 1 @ \SCENE EScene 1 //: There's been a clue in the organ thief case: A blue medical truck with no registration. If you see it, stop it.>
	Msg5 <\ELEMENT 1 @ \SCENE EScene 1 //: Be on lookout for an unregistered cold transport truck. May be connected to the organ thief case.>

	% This encounter may be met instead of a normal encounter.
	ENC2 <if= E2 1 if= V2 0 ifYesNo 6 7 8 SavePos  V= 2 1 Staged .convoy Threat PCRep 6 55>
	Msg6 <In the distance you spot a blue medical storage truck guarded by several mecha.>
	Msg7 <Approach the convoy.>
	Msg8 <Leave them alone.>
	.convoy <TS_Scene_GRD_OTConvoy1.txt>

	% If combat has been entered, V2 = 1. This is important to keep
	% the events below from activating in scenes other than the
	% plot's combat...
	% On a win T2 = 3
	% On a loss T2 = 2
	NU1 <if= T1 0 if= V2 1  V= 2 2   Print 11 Return>
	NU2 <if= T2 0 if= V2 1  Salvage  ifG T3 0 else GoLoss  if= L1 1  L= 1 2  ForceChat -1 V= 2 3 Print 9 Return S+ 101 d6 S+ 101 d6>
	GoLoss <Print 10 V= 2 2 Return S+ 101 1>

	Msg9 <You have captured the medical truck! A guardian team has been dispatched to arrest the driver and collect evidence. \PERSONA E1 will want to hear about your success.>
	Msg10 <The medical truck has been destroyed. A guardian team has been dispatched to clean up the area and see if any clues might have survived.>
	Msg11 <The convoy got away.>

sub
	Persona 1
	% V2 = Message Randomizer
	% If the PC is a guardian, E1 will inform him of the truck.
	% Otherwise, E1 won't do anything, as this is a guardian matter
	% moreso than a mission that outsiders can take part in.

	% First, check to see whether or not the truck has been encountered
	% already by the PC.
	greeting <NewChat if= P2 3 else GoCheckLoss V= 2 15 V+ 2 d5 Say V2 AddReact d6 AdvancePlot 0>
	GoCheckLoss <if= P2 2 else GoCheckInform V= 2 10 V+ 2 d5 Say V2 AdvancePlot 0>
	GoCheckInform <ifG E2 0 else GoInform V= 2 6 V+ 2 d4 Say V2>
	GoInform <if= PCFac N1 else GoNoGuardian Say d5 E= 2 1 Memo 6>

	GoNoGuardian <SayAnything>

	Msg1 <Be on the lookout for a blue cold storage truck, the kind they use to transport medical supplies in. It may be connected to the organ thief case.>
	Msg2 <If you see a blue medical supply truck anywhere, be sure to check its registration. It may be connected to the organ thief murders.>
	Msg3 <Keep your eyes peeled for a cold transport truck with blue and white markings. It may be connected to the organ harvester case. We've been trying to capture it but so far haven't had much luck.>
	Msg4 <We're searching for a blue medical truck that's been liked to the FedTer organ thief. If you see a truck like this, pull it over and check the registration. If it's the truck we're after you should arrest the driver.>
	Msg5 <I know you do a fair bit of travelling... If you see a blue mecical transport vehicle out there anywhere, check its registration. We're searching for a vehicle matching that description in connection with the organ theif case.>

	Msg6 <\ELEMENT 1 in \SCENE EScene 1 has asked you to look for a blue medical truck.>
	Msg7 <I'm still looking for that truck. There have been reports of it travelling between cities along the main trade routes, but that's a lot of territory to patrol.>
	Msg8 <Any luck finding the truck I asked you about? Huh, me either. Well, keep looking for it.>
	Msg9 <Keep searching for that blue truck. It's been sighted on the outskirts of several different cities, so we know that it's still operating in the area.>
	Msg10 <The truck I told you about is still at large. Keep up the search.>

	Msg11 <It's a shame that you couldn't capture the truck... We could have learned a lot from it.>
	Msg12 <The convoy escaped, along with any evidence they may have had. Now that they know we're looking for them they'll probably change trucks or leave the area.>
	Msg13 <We have to work harder, to gather evidence before this organ thief can kill again!>
	Msg14 <The cold storage truck is gone, along with any evidence it may have contained.>
	Msg15 <The investigation into the medical truck has been closed. We'll never find what we were looking for now.>

	Msg16 <I've been speaking with the forensics department, and they've recovered genetic samples belonging to the murder victims from that truck. This will really help our investigation.>
	Msg17 <We've examined the truck. It was, as suspected, transporting body parts taken from the murder victims. The doctor who performed the extractions has not been captured.>
	Msg18 <That truck you stopped? It was full of contraband biomaterial... the lab boys matched some organs to one of the murder victims. This new evidence should bring us closer to the head behind the operation.>
	Msg19 <In that truck, forensics found vials of blood taken from one of the murder victims, and a portable cryogenics lab that could have been used for the extractions. All this is bringing us closer to finding their leader.>
	Msg20 <The lab boys went over that truck with a fine tooth comb. They found a tiny blood stain belonging to one of the murder victims... We're running the fingerprints and skin samples found through the computer now.>

	Plot 1
		% Truck has been captured by other guardians.
		% Time limit - this plot will fade after a short time.
		START <ifPersona E1 else GoDelete if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 10800 ifG E2 0 Mail d3>
		GotoCheckTime <ifG ComTime V1 else GoCheckNews  AdvancePlot 0>
		GoCheckNews <ifG S101 d50 News 4>
		GoDelete <AdvancePlot 0>
		Msg1 <\ELEMENT 1 @ \SCENE EScene 1 //: The blue medical truck we've been looking for has been captured. Forensics is examining it now.>
		Msg2 <\ELEMENT 1 @ \SCENE EScene 1 //: Our highway patrol stopped that blue truck and arrested the driver. He'll be held on registration charges for now.>
		Msg3 <\ELEMENT 1 @ \SCENE EScene 1 //: The blue truck has been captured. This will shed more light on the organ thief case.>
		Msg4 <The capture of an unregistered biomass-handling truck by guardian \ELEMENT 1 will provide new clues in organ thief case.>

	Plot 2
		% Truck has left the area.
		% Time limit - this plot will fade after a short time.
		START <ifPersona E1 else GoDelete if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 10800 ifG E2 0 Mail d3>
		GotoCheckTime <ifG ComTime V1  AdvancePlot 0>
		GoDelete <AdvancePlot 0>
		Msg1 <\ELEMENT 1 @ \SCENE EScene 1 //: It seems like the truck we've been looking for is no longer in the area.>
		Msg2 <\ELEMENT 1 @ \SCENE EScene 1 //: There have been no sightings of the blue truck recently. The search has been called off.>
		Msg3 <\ELEMENT 1 @ \SCENE EScene 1 //: They must have know we were onto them. The blue truck has disappeared. The search operation has been placed on indefinite hold.>


end
