Plot 0
	name <ARC: Organ Thief Fight 1>

	% VARIABLES USED
	% 1 -> Time Limit Timer
	% 2 -> Combat Indicator
	% 3 -> Email indicator

	element1 <Character Guardian>

	% Time limit - this plot will fade after a short time.
	START <ifPersona E1 else GoDelete if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 155000 S+ 102 1>
	GotoCheckTime <ifG ComTime V1 if= V2 0 if= d5 1 else GoDelete S+ 101 1 AdvancePlot 0>
	GoDelete <AdvancePlot 0>

	% Upon recieving a cleanup trigger, just clean up.
	Cleanup <if= V2 0 AdvancePlot 0>

	% Check for email every five minutes.
	% The PC will only get email if he's a guardian.
	5min <if= V3 0 if= d50 23 if= PCFac N1 ifG RReact E1 d30 V= 3 1 Email d5>

	Msg1 <\ELEMENT 1 @ \SCENE EScene 1 //: I'm working on a murder case here in \SCENE EScene 1 and could use your help.>
	Msg2 <\ELEMENT 1 @ \SCENE EScene 1 //: If you're going to be in \SCENE EScene 1 soon, I have a hunting job for you.>
	Msg3 <\ELEMENT 1 @ \SCENE EScene 1 //: Big trouble in \SCENE EScene 1 . Please report here as soon as possible.>
	Msg4 <\ELEMENT 1 @ \SCENE EScene 1 //: I need help bringing in a group of killers. Come to \SCENE EScene 1 and give me a hand.>
	Msg5 <\ELEMENT 1 @ \SCENE EScene 1 //: There's been a murder in \SCENE EScene 1 . I could use your assistance on the case.>

	% If combat has been entered, V2 = 1. This is important to keep
	% the events below from activating in scenes other than the
	% plot's combat...
	NU1 <if= T1 0 if= V2 1 V= 2 2 Reputation 6 -4>
	NU2 <if= T2 0 if= V2 1 V= 2 3 XPV 100 Reputation 6 1>

sub
	Persona 1
	% Standard NPC-offers-PC-combat-job persona.
	% V1 = Phase counter, 1=Offered Mission, -1=Denied Mission
	% V2 = Randomizer
	% V3 = Encounter level
	rumor <!1 has been investigating a murder case.>
	% First, since the PC is talking to the NPC, cancel the email var
	% Then, check to see whether or not the PC has already completed
	% the mission for the guardian, or whether he has already been
	% offered the job.
	greeting <NewChat P= 3 1 if= P2 3 else GoCheckLoss S+ 101 1 CashPrize Reward Threat V3 100 150 AdvancePlot 0 Reputation 1 1 V= 2 31 V+ 2 d5 Say V2 AddReact d3>
	GoCheckLoss <if= P2 2 else GoCheckMission V= 2 36 V+ 2 d4 Say V2 AdvancePlot 0>
	GoCheckMission <if= V1 1 else GoFirstTime Say d5 AddChat 7 Goto GoAddComOps>
	GoFirstTime <V= 3 PCRep 6 V+ 3 d8 V+ 3 -d8  if= V1 0 else GoNoOffer if= PCFac N1 else GoNoGuardian V= 1 1 V= 2 5 V+ 2 d5 Say V2 AddChat 8 Goto GoAddComOps>
	GoNoOffer <SayAnything>

	GoAddComOps <AddChat d3 V= 2 3 V+ 2 d3 AddChat V2 Memo 11>

	% If the PC isn't a guardian, whether or not he will be offered
	% the job depends upon his relationship with this NPC.
	GoNoGuardian <ifG React 50 else GoNoFriend ifG PCRep 1 0 else GoNoFriend Say 12 AddChat 9 AddChat 10 AddChat 11 AddChat 13>
	GoNoFriend <ifG React -1 else GoNoHero ifG PCRep 6 d60 else GoNoHero ifG PCRep 2 d50 else GoNoHero V= 2 12 V+ 2 d3 Say V2 AddChat 10 AddChat 11 AddChat 12 AddChat 13>
	GoNoHero <ifG React d20 else GoAbsolutelyNothing ifG PCRep 1 0 else GoAbsolutelyNothing  V= 2 40 V+ 2 d2 Say V2 AddChat 16 AddChat 17>
	GoAbsolutelyNothing <V= 1 -1 Say 16>

	result1 <EndChat V= 2 16 V+ 2 d4 Say V2 P= 2 1 SavePos MDynamic 0 V3 .mdesc .nu1 .nu2 Reputation 2 1 SetMapType CityMap>
	.mdesc <CRIMINAL>
	.NU1 <if= T1 0 Return>
	.NU2 <if= T2 0 Return>
	result2 <Goto result1>
	result3 <Goto result1>
	result4 <NewChat Say 21>
	result5 <Goto result4>
	result6 <Goto result4>

	result7 <NewChat Say 22 AddChat 3 AddChat 6>
	result8 <NewChat ifG S101 d6 else GoR8NoClues Say 23 AddChat 3 AddChat 6>
	GoR8NoClues <ifG S102 1 else GoR8Nothing Say 24  AddChat 1 AddChat 6>
	GoR8Nothing <Say 25 AddChat 2 AddChat 5>
	result9 <NewChat V= 1 -1 Say 26>
	result10 <NewChat V= 1 1 V= 2 5 V+ 2 d5 Say V2 Goto GoAddComOps>

	result11 <NewChat V= 1 -1 Say 27>
	result12 <NewChat V= 1 -1 Say 28>
	result13 <NewChat V= 2 28 V+ 2 d2 Say V2 AddChat 14 AddChat 15>
	result14 <NewChat V= 1 -1 Say 31>
	result15 <Goto result10>

	result16 <NewChat Say 43 AddChat 12 AddChat 13 AddChat 18>
	result17 <NewChat Say 44 V= 1 -1 Reputation 3 -d10  Reputation 1 -1  AddReact -d6>
	result18 <Goto Result10>

	Msg1 <Are you ready to start the mission?>
	Msg2 <I trust that you've had enough time to prepare. Are you ready to go after these suspects?>
	Msg3 <I don't want these punks to get away. Are you ready to start the mission now?>
	Msg4 <I have some coordinates for you to investigate. Are you ready to begin?>
	Msg5 <Ready to go?>

	Msg6 <A few nights ago someone was murdered. We've traced the killers to a hideout just outside of town. I need you to go there and bring them in... You are cleared to use deadly force, if they act agressive.>
	Msg7 <There's been a murder. It is believed that the killers were a local criminal gang. It is also thought that they were working for someone else. In any case, I need them to be brought in... Dead, if necessary.>
	Msg8 <Three days ago we found a body. It had been severely mutilated and has not yet been identified, but fingerprints at the scene connect the victim to a local crime gang. I need them to be brought in, dead or alive.>
	Msg9 <A mutilated body was found near the highway. The victim hasn't been identified, but we think we know the killers. They're a local crime gang. Investigate their hideout, and bring them in dead or alive.>
	Msg10 <One of the local street gangs is wanted in connection with a murder. I need you to bring them in as soon as possible, dead or alive.>

	Msg11 <\ELEMENT 1 in \SCENE EScene 1 wants you to aprehend some murder suspects.>
	Msg12 <I could really use your help with something. I've been working on a case, and need a hunter to go bring in the perps.>
	Msg13 <There's a bounty avaliable for a group of murderers. I'm looking for a hunter to take the contract.>
	Msg14 <I have a bounty hunting job avaliable for any adventurer who wants it.>
	Msg15 <There's a lot of money avaliable in bounty hunting, you know. I've got a contract avaliable right now if you've got the nerve for this type of business.>

	Msg16 <I've got a lot of work to do right now.>
	Msg17 <Here are the last known coordinates of the gang. You'll need to investigate on foot.>
	Msg18 <Here's all the information that you should need to find them. Head back here afterwards and I'll give you your reward.>
	Msg19 <Here are the last known coordinates of the gang. Be careful out there.>
	Msg20 <The killers are hiding in an old warehouse district. Here are the coordinates. Good luck.>

	Msg21 <Hurry back. We can't be sure how long the killers are going to stay in this area, so we need to strike them before they make a run for it.>
	Msg22 <There's a group of killers hiding out in an abandoned section of the city, and I need a hunter to bring them to justice. Maybe you better lay off the video games for a while... I think they're affecting your memory.>
	Msg23 <It seems likely that this murder was commsioned by the organ harvesting ring that's been operating in the FedTer. I trust that you see why it's so important we catch these thugs quickly.>
	Msg24 <There have been a number of murders lately, and though this one doesn't seem connected to the others the mutilation of the body afterwards is the same. I trust you see why we have to get these thugs quickly.>
	Msg25 <No motive for the killing has been established, nor was there any link between the victim and the killers. Maybe after we examine the gang's hideout we can learn more.>

	Msg26 <You're right, I did know that. Sorry.>
	Msg27 <That's a shame. Well, good luck, and be careful out there...>
	Msg28 <This is a dangerous job, one which will require a professional.>
	Msg29 <The job pays $ \VAL Reward Threat V3 100 150 . Interested in signing up?>
	Msg30 <There's a reward of $ \VAL Reward Threat V3 100 150 for completing this mission. So how about it, do you want the job?>

	Msg31 <Well, that's all the department has budgeted for this mission. I'm sure I can find a hunter somewhere who can take it.>
	Msg32 <Good job. Here's your reward for stopping the criminals.>
	Msg33 <Justice has been served. Here's the bounty that you've earned.>
	Msg34 <Very good. Here's your pay for a job well done.>
	Msg35 <Congradulations, you stopped the criminals. Here's your reward.>

	Msg36 <Here's the cash you earned for stopping those lowlifes.>
	Msg37 <You didn't manage to catch the crooks. I hope you have better luck next time.>
	Msg38 <The criminals got away, but at least you live to fight again.>
	Msg39 <Maybe bounty hunting isn't such a good job choice for you. It's never too late to go back to university.>
	Msg40 <I know that you're very good at many things... apparently bounty hunting isn't one of them.>

	Msg41 <Have you been keeping up with the news? There's a killer on the loose, so all civilians be cautious. I've been investigating the case myself.>
	Msg42 <There's a serial killer on the loose. Every guardian in the FedTer is busy working on this case.>
	Msg43 <There may be... Are you a bounty hunter? There's a gang which needs to be brought down. They may be connected with the murders.>
	Msg44 <Maybe it should.>

	Prompt1 <Let's get this mission started.>
	Prompt2 <I'll bring them to justice.>
	Prompt3 <I'm ready to go.>

	Prompt4 <First I need to buy ammo.>
	Prompt5 <I need some time to prepare.>
	Prompt6 <I can't go yet.>

	Prompt7 <What kind of mission is this again?>
	Prompt8 <What do we know about the killers?>
	Prompt9 <You should know that I'm not a hunter.>
	Prompt10 <Tell me about the case.>

	Prompt11 <I'm too busy to help right now.>
	Prompt12 <Sorry, I'm not into that line of work.>
	Prompt13 <What does the job pay?>
	Prompt14 <No, not really.>
	Prompt15 <I'll do it.>

	Prompt16 <Is there anything I can do to help?>
	Prompt17 <That doesn't concern me.>
	Prompt18 <I can do that.>

end
