Plot 0
	name <PLOT: Rat Fight 1>

	% V1 = Time Limit
	% V2 = Combat Indicator

	Element1 <Grab 1>
	Element2 <Character Guardian !N 1>

	% On a cleanup, just get rid of this plot,
	% unless the PC has a reward pending.
	cleanup <if= V2 0 AdvancePlot 0>

	% Time limit - this plot will fade after a short time.
	START <ifPersona E2 else GoDelete if= V1 0 else GotoCheckTime V= 1 ComTime V+ 1 129600>
	GotoCheckTime <ifG ComTime V1 if= V2 0  AdvancePlot 0>
	GoDelete <AdvancePlot 0>

	% Combat Check - if V2 = 1 then we're in combat.
	% If the player won, then after combat V2 = 2.
	% If the player lost, then after combat V2 = 3.
	NU1 <if= T1 0 if= V2 1 V= 2 3 Reputation 6 -5>
	NU2 <if= T2 0 if= V2 1 V= 2 2 Reputation 6 1 XPV 100 S+ 1 d3>

sub
	Persona 2
	rumor <!2 spends an awful lot of time killing rats.>

	% V1 = First time counter
	% V2 = Randomizer
	% V10 = PV
	% V20 = Reward
	greeting <NewChat  if= P2 3 else GoCheckWin  Say 22 AdvancePlot 0>
	GoCheckWin <if= P2 2 else GoCheckContact  CashPrize V20 AddReact d3 Say 21 AdvancePlot 0>
	GoCheckContact <if= V1 1 else GoFirstTime  V= 2 3 V+ 2 d2 Say V2 AddChat 3 AddChat 4>
	GoFirstTime <V= 1 1  ifG React d80 else GoNoLike  Say 1 AddChat 1 AddChat 2>
	GoNoLike <ifG PCRep 6 d60 else GoNoRenown  Say 2 AddChat 1 AddChat 2>
	GoNoRenown <ifG PCRep 1 d20 else GoNoChance  Say 3 AddChat 1 AddChat 2>
	GoNoChance <SayAnything AdvancePlot 0>

	result1 <NewChat V= 10 PCRep 6 V+ 10 d10 V= 20 Reward Threat V10 100 300 V= 2 5 V+ 2 d5 Say V2 AddChat 3 AddChat 4 AddChat 5>
	result2 <NewChat ifG NPCRep E2 4 -d50 else GoR2Passion V= 2 10 V+ 2 d5 Say V2 AdvancePlot 0>
	GoR2Passion <Say 16 AddChat 6 AddChat 7 AddChat 8>
	result3 <EndChat V= 2 22 V+ 2 d2 Say V2 Memo 25 P= 2 1 SavePos MDynamic 0 V10 .ratdesc .nu1 .nu2>
	.ratdesc <Mutant Animal City Vermin>
	.nu1 <if= T1 0 Return>
	.NU2 <if= T2 0 Return>

	result4 <Goto result2>
	result5 <NewChat V= 2 17 V+ 2 d3 Say V2>

	result6 <Goto result3>
	result7 <Goto result5>
	result8 <NewChat Say 17 AdvancePlot 0>

	Msg1 <Are you looking for a job now? I've got something avaliable, if you're interested. It's not particularly glamorous but the pay is good.>
	Msg2 <Hey, I know you're no stranger to adventure, how'd you like to help \ELEMENT 1 and earn a few bucks at the same time?>
	Msg3 <Hey there, how'd you like to earn some money? I've got a lot of important work to do, so I could use some help with a number of menial duties.>
	Msg4 <Are you ready to clear out those rats now?>
	Msg5 <Have you done everything? Ready to take care of some rats?>

	Msg6 <As you might already know, there's a lot of rats in \ELEMENT 1 . Some big ones have moved into the city park, and need to be exterminated. The reward is $ \VAL V20 for the job.>
	Msg7 <We just discovered a rat's nest on the edge of town. Clear it out and you'll earn $ \VAL V20 . I'd do it myself but I'm busy with actual police work.>
	Msg8 <\ELEMENT 1 is a nice place to live, but there's too many rats. I need you to exterminate a hazardous pack for $ \VAL V20 plus a free tetanus shot afterwards.>
	Msg9 <A rat pack has moved into the school's playground. We need them eliminated before they eat a kid or anything. It's worth $ \VAL V20 if you can do that.>
	Msg10 <There's an infestation of rats just outside of town. It wouldn't be much of a problem, except for the fact that these particular rats weigh 40kg apiece. There's a reward of $ \VAL V20 to exterminate the pack.>

	Msg11 <Me too, that's why I'm trying to find someone to do it for me...>
	Msg12 <Why do you think I'm trying to pass it off on someone else? If I can't find anyone, I'll have to do it myself...>
	Msg13 <Fair enough. I'll keep looking.>
	Msg14 <Me either, which is why I'm trying to find someone to do it for me.>
	Msg15 <Nobody wants this job. That's the problem... Well, I guess I'll have to do it myself after all.>

	Msg16 <Oh, this is shameful, abandoning a chance to aid your fellow citizens like this... Don't you have any pride!? Come on, help keep \ELEMENT 1 clean!>
	Msg17 <I see now that you are absolutely hopeless. I will find someone else for the mission.>
	Msg18 <Make sure that all of your guns have enough ammunition; I hear that some of those rats are pretty nasty!>
	Msg19 <Get yourself in top shape then come back here and we'll start the job. Um, not for a half hour at least, though... My coffee break starts now.>
	Msg20 <Come back when you're ready and we can begin.>

	Msg21 <Good work there! Thanks for the help, here's your pay.>
	Msg22 <Tough luck out there, I guess those rats were bigger than we thought.>
	Msg23 <Good luck. Come back here either when you've eliminated all the vermin, or when they've eliminated you...>
	Msg24 <Here's the location of the pack. Get rid of them all and I'll fix you up with that reward.>
	Msg25 <\ELEMENT 2 in \ELEMENT 1 hired you to exterminate some giant rats.>

	Prompt1 <What kind of work?>
	Prompt2 <I'm not interested.>
	Prompt3 <I'm ready to go!>
	Prompt4 <Uh, I don't really want this job.>
	Prompt5 <I need some time to get ready.>

	Prompt6 <Alright! I'll do it!>
	Prompt7 <Give me some time to prepare.>
	Prompt8 <Nope, my mind is made up...>

end
