Story
	name <Story: Kidnapped!>
	% The niece of the town leader has been kidnapped!

	% Element 4 is a scene, but its value will change over the
	% course of the story. As the player tracks the kidnappers
	% across the FT, N1 will hold the value of the most recent
	% lead.
	% N1 will be the scene which generated this story
	element2 <Character !Near 1 Leader>
	element3 <Prefab>
	element4 <Scene Town !Near 1>

	% V1 = General Phase Counter; if V1#0, PC has been informed of mission
	% V2 = Reward Offered

	% V101 = Refresh Investigation
	%     if nonzero, need to reload a new investigation plot
	% V102 = Clues Accumulated by the PC
        %     Once the total is high enough, a conclusion will be loaded

	% V201 = Story Outcome
	%     if > 0, PC was successful and rescued the niece
	%     if < 0, PC failed and the niece died


	% This story will end if...
	%  - V201 is nonzero, and PC speaks with N2
	%  - N2 dies or is otherwise removed from the game

	start <ifPersona N2 else GoEndStory>
	GoEndStory <EndStory>

	% Every 5 minutes, check to see whether or not to load a
	% new investigation.
	5Min <if# V101 0 memo 101 if= V201 0 ifG 5 V102 else GoEndStory  storyline .investigation V= 101 0>
	.investigation <TS_Plot_UrbKN_Inv_*.txt>
	GoEndStory <storyline .conclusion V= 101 0>
	.conclusion <TS_Plot_UrbKN_End_*.txt>

	% Every half hour, check whether or not to announce the story.
	HalfHour <if= d10 1 if= V1 0 ifG RReact N2 d120 else GoCheckNews V= 1 1 EMail 102>
	GoCheckNews <V= 1 -1 News d5>

	% News Announcements
	Msg1 <\NARRATIVE 2 , the mayor of \NARRATIVE 1 , has offered a substantial reward for help in local kidnapping case.>
	Msg2 <There's trouble in \NARRATIVE 1 . The niece of town leader \NARRATIVE 2 has disappeared. The guardians are searching for any leads.>
	Msg3 <\NARRATIVE 3 , the niece of \NARRATIVE 1 mayor \NARRATIVE 2 , has been kidnapped.>
	Msg4 <\NARRATIVE 1 resident \NARRATIVE 3 has disappeared. She's the niece of town leader \NARRATIVE 2 ; police expect to recieve a ransom notice soon.>
	Msg5 <The niece of civic leader \NARRATIVE 2 has been kidnapped from her \NARRATIVE 1 home.>

	% Investigation memo
	Msg101 <\NARRATIVE 2 in \NARRATIVE 1 wants you to investigate the disapearance of \NARRATIVE 3 . \NARRATIVE 4 was her last known location.>
	Msg102 <\NARRATIVE 2 @ \NARRATIVE 1 :// I need your help immediately! Please see me in \SCENE N1 at once.>

sub
	Persona 2
	greeting <NewChat ifG S201 0 else GoCheckLoss Say 3 CashPrize S2 XPV 250 Reputation 6 1 History 15 EndStory>
	GoCheckLoss <ifG 0 S201 else GoCheckMission Say 2 EndStory>

	% if S1 = 2, PC has accepted misison.
	GoCheckMission <if= S1 2 else GoCheckEmail  Say 7>
	% if S1 = 1, PC has been emailed about the case.
	GoCheckEmail <if= S1 1 else GoCheckNews  Say 6  AddChat 1 AddChat 2 AddChat 3>
	% if S1 = -1, the case has been reported by the media.
	GoCheckNews <if= S1 -1 else GoNothing  Say 5  AddChat 1 AddChat 2 AddChat 3>

	% The PC may be offered this mission, as long as he is somewhat
	% well liked and not villainous.
	GoNothing <ifG React d23 else GoAway ifG PCRep 1 -d10 else GoAway  Say 4  AddChat 1 AddChat 2 AddChat 3>
	GoAway <Say 1>

	result1 <NewChat S= 2 15000 Say 8  Goto GoStart>
	result2 <NewChat S= 2 15000 Say 9 AddChat 4 AddChat 5>
	result3 <NewChat Reputation 5 d6 S= 2 15000 Say 10 AddChat 5>
	result4 <NewChat ifG dReward Threat PCRep 6 100 100 S2 else GoR4NoBetter S= 2 50000 Say 13 AddChat 5>
	GoR4NoBetter <ifG React d100 else GoR4Nothing  Say 12 AddChat 5>
	GoR4Nothing <Say 11 EndStory AddReact -d10>
	result5 <NewChat Say 14 Goto GoStart>

	GoStart <S= 101 1 S= 1 2>

	Msg1 <Yes, what is it? I'm far too busy. I have an entire city to look after, you know.>
	Msg2 <All has been lost...>
	Msg3 <Thank you for rescuing \NARRATIVE 3 ! Here is a small reward for your heroic deeds.>
	Msg4 <I need your help! My niece \NARRATIVE 3 has been kidnapped.>
	Msg5 <I suppose that you've heard the news. My niece \NARRATIVE 3 has been kidnapped. Any help or information leading to her safe return would be greatly appreciated.>

	Msg6 <Did you get my email!? My niece \NARRATIVE 3 has been kidnapped. Please find her for me!>
	Msg7 <Please find \NARRATIVE 3 !>
	Msg8 <Thank you very much! I'm afraid that there aren't many clues to help you. Return \NARRATIVE 3 to us safely and I'll give you a reward of $ \VAL S2 .>
	Msg9 <I can offer a reward of \VAL S2 for her safe return. There aren't many clues to go on at the moment. Please help me!>
	Msg10 <No, I can't trust that! The guardians won't get involved until she's been missing at least a week... \NARRATIVE 3 could be dead by then! Won't you help?>

	Msg11 <In that case I will find someone else to help me.>
	Msg12 <That's all I have to offer, I'm afraid. Please help me!>
	Msg13 <Alright, I know that you are not used to working for so little money... I can offer you $ \VAL S2 . Will that be enough?>
	Msg14 <That's good news! Please start looking for \PERSONA N3 right away.>
	Msg15 <You rescued the niece of \NARRATIVE 1 mayor \NARRATIVE 2 .>

	Prompt1 <I will help you.>
	Prompt2 <How much is the reward?>
	Prompt3 <I'm sure she'll turn up by herself.>
	Prompt4 <That's not enough.>
	Prompt5 <Okay, I'll do it.>

end

inv
	NPC Citizen
	chardesc Young Female

end
