Plot 0
	name <PLOT: Investigate Cause>
	% The PC's parents have died.
	% Now the PC must help investigate who killed them.

	element1 <Grab 3>
	element2 <Character Guardian !Near 1 Heroic>
	element3 <Scene Target Town !Far 1>

	start <ifPersona E2 else GoDelete>
	GoDelete <S= 101 1 AdvancePlot 0>
	cleanup <AdvancePlot 0>

	% V2 = Combat Indicator
	% V3 = Email Indicator

	% Combat check. If combat has been entered, V2=1.
	% Combat ends in victory if the number of active masters on
	% team two drops to zero, or ends in defeat is the number of
	% active masters on team one drops to zero. After combat, V2=3
	% if the player was victorious or V2=2 is the player lost.
	nu1 <if= T1 0 if= V2 1  V= 2 2  Reputation 6 -10>
	nu2 <if= T2 0 if= V2 1  V= 2 3  Reputation 6  1  XPV 50>

	5Min <if= V3 0 if= d100 23 email d5 V= 3 1>
	Msg1 <\ELEMENT 2 @ \SCENE EScene 2 :// I need to speak with you regarding the investigation into your parent's death.>
	Msg2 <\ELEMENT 2 @ \SCENE EScene 2 :// I am conducting an investigation into your parents death. Please report here for questioning.>
	Msg3 <\ELEMENT 2 @ \SCENE EScene 2 :// I must question you in regard to your parents death. Please report here at once.>
	Msg4 <\ELEMENT 2 @ \SCENE EScene 2 :// I am collecting evidence regarding your parents death. Any information would be helpful.>
	Msg5 <\ELEMENT 2 @ \SCENE EScene 2 :// Please report here for Guardian questioning at earliest possible convenience.>


sub
	Persona 2
	rumor <!2 has been investigating a murder case.>
	% V11 = PC was difficult...

	Greeting <NewChat P= 3 1 if= P2 3 else GoCheckLoss if= V11 1 else GoEP2 if= d2 1 else GoEP2 Say 101 History 151 XRBadThing NAV_XRBIncriminated Goto GoEndPlot>
	GoEP2 <ifPersona N1 else GoEP3 if= d2 1 else GoEP3 Say 102 History 152 XREnemy NAV_XRECharacter Goto GoEndPlot>
	GoEP3 <Say 103 History 153 XREnemy NAV_XREFaction Goto GoEndPlot>

	GoEndPlot <S= 101 1 S+ 102 1 N= 3 E3 AdvancePlot 0>

	Msg101 <By the time our crews arrived on the scene, the computer core was destroyed... apparently by heavy weapons fire. You wouldn't know anything about that, would you? Of course I don't suspect you, but others in the department...>
	Msg151 <You were falsely implicated in the death of your parents.>
	Msg102 <Ever hear the name \NARRATIVE 1 before? According to the files, he's the one who staged the hit on your parents. The Guardian's office in \ELEMENT 3 has started an investigation of their own. You may want to head there.>
	Msg152 <You discovered that \NARRATIVE 1 killed your parents.>
	Msg103 <The hit against your parents seems to have been financed by \NARRATIVE 2 . I'll need more evidence before charges can be placed. The Guardian's office in \ELEMENT 3 has started an investigation of their own. You may want to head there.>
	Msg153 <You discovered that \NARRATIVE 2 arranged for your parents to be killed.>

	GoCheckLoss <if= P2 2 else GoCheckJob Say 1 S= 101 1 N= 3 E3 AdvancePlot 0>
	GoCheckJob <if= V1 1 else GoFirstTime  Say 3 AddChat 1 AddChat 2 AddChat 3>
	GoFirstTime <Say 4 AddChat 4 AddChat 5>

	result1 <EndChat Say 5 SavePos P= 2 1 Dynamic 2 Threat S103 190 .nu1 .nu2>
	.nu1 <if= T1 0 Return>
	.nu2 <if= T2 0 Salvage Return>
	result2 <NewChat Say 6>
	result3 <NewChat Say 7 AddChat 1 AddChat 2>
	result4 <NewChat Say 8 Memo 9 V= 1 1 Reputation 4 -d8 AddChat 6 AddChat 7>
	result5 <NewChat Say 10 Memo 9 V= 1 1 AddChat 6 AddChat 7>
	result6 <NewChat Say 11 AddChat 1 AddChat 2 AddChat 3>
	result7 <NewChat Say 12 Reputation 2 -1 V= 11 1>

	Msg1 <The mission was a failure, and now that the ravagers know we're after them we'll never recover that data.>

	Msg3 <The mission to assault the deadzone encampment and retrieve the evidence from their database is ready to go. Are you ready?>
	Msg4 <Hello. I wanted to speak with you, with regard to the death of your parents... We believe that they were murdered. At the moment we are attempting to obtain evidence which could confirm that.>
	Msg5 <Come back here once you've eliminated the guardian mecha. Our forensic cryptologists will then be able to scour their computer systems for the contract.>
	Msg6 <Make sure your equipment is in perfect working order, then we can start the mission.>
	Msg7 <The guards have about \VAL Threat S103 190 points worth of mecha guarding their computer center. If you don't eliminate them all and capture the base, they're just going to move camp and we may never find them again.>
	Msg8 <Well, to prove that, I'm going to need some data. You're an adventurer, right? Evidence suggests there was a contract on your parents lives. I could use your help to recover the details.>
	Msg9 <\ELEMENT 2 in \SCENE EScene 2 wants you to help investigate the death of your parents.>
	Msg10 <A contract on their lives, specifically, and the identity of whoever paid their killers. This information likely resides in an underworld data center in the dead zone, but I'm going to need a pilot to help recover it.>
	Msg11 <The data bank where we can find the contract is out in the dead zone, protected by ravager mecha. I need you to disable the guards so our lab boys can recover the evidence. You better do well the first time, since we only get one chance.>
	Msg12 <We don't have enough manpower to go around. Without outside assistance, this investigation might be left for weeks... The evidence could be destroyed by then. Of course you're under no obligation to help but things would be quicker if you did.>

	Prompt1 <Let's go!>
	Prompt2 <Maybe some time later...>
	Prompt3 <What do they have out there?>
	Prompt4 <I know they were murdered.>
	Prompt5 <What kind of evidence?>
	Prompt6 <I'll help you.>
	Prompt7 <You should do your own work.>

end
