Plot 0
	% The PC's sister needs money. Once the PC provides that money, the next
	% phase of the adventure can start.
	name <PLOT: Money for Sibling>

	element1 <Grab 3>
	element2 <Prefab>
	element3 <Scene Target Town !Far 1>

	start <ifPersona E2 else GoDelete if= V1 0 PCAlly E2 if= d3 1 Email d5 V= 1 1>
	GoDelete <S= 101 1 AdvancePlot 0>

	Msg1 <\ELEMENT 2 @ \SCENE EScene 2 :// Hey! It's your sister calling. I need some money, come see me...>
	Msg2 <\ELEMENT 2 @ \SCENE EScene 2 :// It's me, your sister. I've got a favor to ask but I need to do it in person. TTYL>
	Msg3 <\ELEMENT 2 @ \SCENE EScene 2 :// Hey there sib! It's your little sister calling. I need some cash. Can you help?>
	Msg4 <\ELEMENT 2 @ \SCENE EScene 2 :// Sorry I haven't written more. Things have been tough since Mom and Dad died... I need your help.>
	Msg5 <\ELEMENT 2 @ \SCENE EScene 2 :// This is your sister, I need help right away. Stop driving robots and come see me!>

	cleanup <AdvancePlot 0>

sub
	Persona 2
	% V1 = Initialization counter
	% V3 = Needed money
	greeting <NewChat if# V1 2 else GoEndingSpeech V= 3 Threat S103 30 Memo 9 if= V1 0 else GoBeenBefore V= 1 1 Say 1 AddChat 1 AddChat 2 AddChat 3>
	rumor <!2 has been waiting to talk with you.>

	GoBeenBefore <Say 2 AddChat 4 AddChat 5 ifG PC$ V3 AddChat 6>

	result1 <NewChat Say 3 Reputation 1 1 AddChat 7 AddChat 8 ifG PC$ V3 AddChat 6>
	result2 <NewChat Reputation 1 -1 Reputation 3 -d10 Say 4 AddChat 9 AddChat 10>
	result3 <NewChat Say 5 AddReact d10 AddChat 7 AddChat 8 ifG PC$ V3 AddChat 6>
	result4 <NewChat Say 6>
	result5 <NewChat Say 7>
	result6 <NewChat Cash+ -V3 Reputation 1 1 Reputation 6 1 Goto GoEndingSpeech>
	result7 <NewChat Say 8>
	result8 <NewChat Say 10 Reputation 7 d10>
	result9 <NewChat Say 11 Reputation 5 d10  AddChat 7 AddChat 8 ifG PC$ V3 AddChat 6>
	result10 <NewChat Say 12 Reputation 5 -d10 Reputation 1 -2 Reputation 2 -2>

	Msg1 <You've got to help me! Mom and Dad left some money for us when they went away, but it wasn't much. There's not much left. I'll have to spend the last of it on either food or school. Please, I haven't called for help before...>
	Msg2 <I still need $ \VAL V3 to pay for my school and living expenses.>
	Msg3 <I need $ \VAl V3 to cover everything, and even with that I'll be living on ramen for a while.>
	Msg4 <You're mean! You're the only person I have in the world to turn to...>
	Msg5 <You're the greatest! It'll take $ \VAL V3 to cover rent, food, and tuition until the end of the semester.>
	Msg6 <Please remember while you're driving your robot that your poor little sister is cold and hungry.>
	Msg7 <You're still mean.>
	Msg8 <Please do that.>
	Msg9 <Your sister \ELEMENT 2 in \SCENE EScene 2 needs $ \VAL V3 to pay for living expenses.>
	Msg10 <I can't get a job because I haven't graduated school! I can't graduate school unless I can pay for tuition! Please help me out here...>
	Msg11 <Aieee... being out in the world sure hasn't helped you to grow up any. I need $ \VAL V3 to pay for my school and living expenses.>
	Msg12 <You wouldn't dare say that if our parents were still alive...>

	Prompt1 <How much do you need?>
	Prompt2 <I don't care. Get the money yourself.>
	Prompt3 <You're my sister; of course I'll help.>
	Prompt4 <I'm still working on it.>
	Prompt5 <Like I told you before, buzz off.>
	Prompt6 <Here's the money. [Give Cash]>
	Prompt7 <I'll get the money for you.>
	Prompt8 <Maybe you should find a job.>
	Prompt9 <Calm down, I was just joking!>
	Prompt10 <Life's tough. Deal with it.>

	GoEndingSpeech <V= 1 2 Say 101 AddChat 101 AddChat 102 AddChat 103>

	result101 <NewChat Reputation 3 d10 Say 102 Goto GoEndPlot>
	result102 <NewChat Reputation 7 -d10 Say 103 Goto GoEndPlot>
	result103 <NewChat Reputation 5 -d10 Say 104 Goto GoEndPlot>

	Msg101 <Thank you! Oh, this should cover just about everything... You really stick by, y'know? If Mom and Dad were here they'd be proud. I miss them so much sometimes...>
	Msg102 <I'm glad I still have you. I found a book while cleaning up the house a while back. It says we might have family in \ELEMENT 3 . Maybe while you're travelling you can check it out.>
	Msg103 <I wish I could believe that as strongly as you... Hm, a few days ago I found something interesting. I wanted to tell you but forgot. We might have family in \ELEMENT 3 . Maybe you could go check it out someday.>
	Msg104 <I know, but I still miss them now. I did find something interesting while cleaning the house a few days ago... we might have family in \ELEMENT 3 . Maybe if you're there sometime you can check it out.>

	Prompt101 <I miss them too.>
	Prompt102 <They've gone to a better place.>
	Prompt103 <Someday we'll join them.>

	GoEndPlot <XRBadThing NAV_XRBResolved S= 101 1 S+ 102 1 N= 3 E3 History 201 AdvancePlot 0>

	Msg201 <You gave your sister \ELEMENT 2 $ \VAL V3 for tuition and living expenses.>

end
inv
	NPC Citizen
	job <Sister>
	chardesc Young Easygoing Female Heroic
	place <1 Pass Ally>

end
