plot 0
	name <PLOT: Plantation>

	% E1 is the scene for the current episode.
	% E2 is the character who will give the PC a mission.
	% E3 is the scene to be used in the next episode.
	Element1 <Grab 3>
	Element2 <Prefab>
	Element3 <Scene Town Target !Far 1>
	Element4 <Grab 2>

	% V2 = Combat Counter


	% On a cleanup request just delete this plot.
	cleanup <AdvancePlot 0>

	% If Persona E2 dies, load a new plot.
	start <ifPersona E2 else GoDelete>
	GoDelete <S= 101 1 AdvancePlot 0>

	% Combat check. If combat has been entered, V2=1.
	% Combat ends in victory if the number of active masters on
	% team two drops to zero, or ends in defeat is the number of
	% active masters on team one drops to zero. After combat, V2=3
	% if the player was victorious or V2=2 is the player lost.
	nu1 <if= T1 0 if= V2 1  V= 2 2  Reputation 6 -7>
	nu2 <if= T2 0 if= V2 1  V= 2 3  Reputation 6  1  XPV 100>

sub
	Persona 2

	% Fill in something for the rumor string, so the PC will know who
	% has a job to offer. !2 will add the name of the NPC, while !1
	% will add the name of the faction.
	rumor <!2 has lost a lot of money from bandit attacks.>

	% ********************
	% *** SCRIPT BLOCK ***
	% ********************
	% If you're feeling faint of heart, just skip this
	% and jump straight to the messages block below.
	% Here are the variables used in this conversation:
	%  V1 = Job offer counter, V1=1 is job offered, V1=-1 if job denied
	%  V2 = Message Randomizer
	%  V3 = Threat value of enemy mecha
	%  V4 = Reward offered to PC for the mission
	%  V5 = Recharge time if mission fails
	% At startup, first check to see whether the PC has already
	% completed the mission or not.

	greeting <NewChat if= P2 3 else GoCheckLoss  Say 1 CashPrize V4 PCAlly E2 Goto GoEndMission>
	GoCheckLoss <if= P2 2 else GoCheckMission ifG ComTime V5 else GoWaitRecharge P= 2 0 Say 2 AddChat 1 AddChat 2 AddChat 3>
	GoWaitRecharge <Say 3>
	GoCheckMission <if= V1 1 else GoFirstTime Say 4 AddChat 1 AddChat 2 AddChat 3>

	% Unlike most combat missions, the PC is guaranteed to be offered
	% this one, since it's personal.
	% Set V1, V3, V4 here.
	GoFirstTime <V= 3 Threat S103 200  V= 4 Reward V3 150 Memo 11 Say 6 AddChat 4 AddChat 5>

	% Do everything here that has to be done. If some of the ExtraRandom
	% parameters need to be changed, do that here as well.
	GoEndMission <S= 101 1 S+ 102 1 N= 3 E3 History 101 AdvancePlot 0>

	result1 <EndChat Say 5 SavePos P= 2 1 V= 5 ComTime V+ 5 86400 Dynamic 2 V3 .nu1 .nu2>
	.nu1 <if= T1 0 Return>
	.nu2 <if= T2 0 Salvage Return>
	result2 <NewChat Say 7>
	result3 <NewChat Say 8 AddChat 1 AddChat 2>
	result4 <NewChat Say 9 AddChat 6>
	result5 <NewChat Say 10 AddChat 6>
	result6 <NewChat Say 12 Memo 11 AddChat 1 AddChat 2 AddChat 3>

	% 1 : Player has won the mission
	%    Should mention that next episode will happen in \ELEMENT 3
	Msg1 <Here's your pay. Those mecha were marked by \ELEMENT 4 all right. I got a call from the Guardian's office in \ELEMENT 3 , said that they were stolen. I still have no idea what any of this means but at least my farm should be safe from now on.>

	% 2 : Player lost mission previously, now time to try again
	Msg2 <Think you can take on the raiders again? Hopefully you can defeat them, this time...>

	% 3 : Player has lost mission, must wait until tomorrow to try again
	Msg3 <They'll be back tomorrow, strong as ever... I wouldn't blame you if you want to give up.>

	% 4 : Player has accepted mission, has returned from repair
	Msg4 <Are you ready to go now? Those invaders will be back at the farm any time now...>

	% 5 : Combat is starting
	Msg5 <Come back here when you're finished with them, and I'll see about providing that reward.>

	% 6 : NPC explains what the PC should do in this mission, and why
	Msg6 <My farm has been attacked by mecha several times in the past month. Every time we rebuild, they come back to destroy everything again. I only wish I knew why...>

	% 7 : PC needs some time to get ready
	Msg7 <Alright. Hurry back after you've fixed up your ride.>

	% 8 : How many points? Use "\VAL V3 " for that
	Msg8 <I don't really know. I'm not really an expert on mecha myself... I can offer you $ \VAL V4 to get rid of them, though.>

	% 9 : Response to Prompt4
	Msg9 <I could certainly use some help. I can even offer you a small reward for it... One thing though, these guys aren't normal bandits. >

	% 10 : Response to Prompt5
	Msg10 <I don't know! My main crops are cabbage and parsnips... As far as I know, there's no big black market demand for either of those. One thing though, these guys aren't normal bandits.>

	% 11 : Memo
	Msg11 <\ELEMENT 2 in \SCENE EScene 2 wants you to help protect the farm.>

	Msg12 <To start with, they never steal anything, just destroy stuff. Secondly, because one of the field hands who saw them says they were marked with \ELEMENT 4 insignia. So, will you help me?>

	Msg101 <You defended the farm of \ELEMENT 2 against \NARRATIVE 2 .>

	Prompt1 <I'll show those bandits something.>
	Prompt2 <My mecha needs repair first.>
	Prompt3 <Any idea how many mecha they have?>
	Prompt4 <I'd like to help you.>
	Prompt5 <Who are they, and why attack a farm?>
	Prompt6 <How do you know that?>

end
inv
	NPC Citizen
	Job <Farmer>
	CharDesc Lawful
	Place <1 Ally Pass>

end
