Plot 0
	name <PLOT: You are in Danger!>

	% E1 is the scene for the current episode.
	% E2 is the character who will tell the PC where to go.
	% E3 is the scene to be used in the next episode.
	% E4 is the scene to be used in the second part of this episode.
	Element1 <Grab 3>
	Element2 <Prefab>
	Element3 <Scene Town Target !Far 1>
	Element4 <Scene Town Target !Far 1 !Far 3>

	% V1 = Time limit for move

	% On a cleanup request just delete this plot.
	cleanup <AdvancePlot 0>

	% If Persona E2 dies, load a new plot.
	start <ifPersona E2 else GoDelete if# V1 0 ifG ComTime V1 MoveCHar E2 E4 N= 3 E4 AdvancePlot 1>
	GoDelete <S= 101 1 AdvancePlot 0>

sub
	Persona 2
	rumor <!2 seems to know something about you...>

	greeting <NewChat Say 1 AddChat 1 AddChat 2>

	% Freze the NPC and start the countdown until the meeting.
	GoStartCountdown <Memo 101 P= 1 ComTime P+ 1 172800 FreezeChar E2>

	result1 <NewChat Say 2 Goto GoStartCountdown>
	result2 <NewChat Say 3 Goto GoStartCountdown>

	Msg1 <I know who you are, and I must warn you... You are in grave danger here.>
	Msg2 <You could say that we have a common enemy. I can tell you more, but not here... Meet me in \ELEMENT 4 in two days.>
	Msg3 <There's someone trying to kill you. I can tell you more, but not here... Meet me in \ELEMENT 4 in two days.>

	% 101 - Memo message
	Msg101 <\ELEMENT 2 asked you to meet in \ELEMENT 4 in two days.>

	Prompt1 <How do you know who I am?>
	Prompt2 <What kind of danger?>

	Plot 1
		% The NPC has moved to the new location, and is now
		% waiting for the PC to arrive.

		% V1 = Initialization Counter
		% V2 = Has entered combat

		% On a cleanup request just delete this plot.
		cleanup <AdvancePlot 0>

		% If Persona E2 dies, load a new plot.
		% Perform initialization here as well.
		start <ifPersona E2 else GoDelete if= V1 0 V= 1 1 Memo 1 Compose EWM E4 .startcombat>
		GoDelete <S= 101 1 AdvancePlot 0>
		.startcombat <Block ifYesNo 101 102 103 SavePos P= 2 1 Dynamic 2 Threat S103 100 .nu1 .nu2 Encounter 0 25 .nodesc PassVar 1 E4>
		.nu1 <if= T1 0 Return>
		.nu2 <if= T2 0 Salvage Exit L1 SeekGate 1>

		Msg1 <\ELEMENT 2 asked you to come to \ELEMENT 4 . It's time to go.>

		Msg101 <While appraoching \ELEMENT 4 , you are approached by a force of hostile mecha. They seem to have been waiting for you.>
		Msg102 <Attack them!>
		Msg103 <Run away.>

	sub
		Persona 2
		greeting <NewChat  Say 1 AddChat 1 AddChat 2>

		result1 <Reputation 4 -d8 Goto result2>
		result2 <NewChat if= d3 1 else GoR1Faction ifPersona N1 else GoR1Faction  XREnemy NAV_XRECharacter Say 2 History 4 Goto GoEndMission>
		GoR1Faction <XREnemy NAV_XREFaction Say 3 History 5 Goto GoEndMission>


		% Do everything here that has to be done. If some of the ExtraRandom
		% parameters need to be changed, do that here as well.
		GoEndMission <FreezeChar E2 PCAlly E2 S= 101 1 S+ 102 1 N= 3 E3 AdvancePlot 0>

		Msg1 <I tried to evade them, but this town isn't safe either. They followed me, or possibly you... they know that I've had contact with you.>
		Msg2 <It's very complicated, I don't have enough time to tell you everything, but you should know this: \NARRATIVE 1 is trying to kill you, and will stop at nothing until you're dead. I have to go now but I will help you again.>
		Msg3 <It's too complicated to explain right now... You'll find out the details soon enough. This is the most important thing you should know: \NARRATIVE 2 wants you dead. I have to go now but I will help you again.>
		Msg4 <\ELEMENT 2 told you that \NARRATIVE 1 wants you dead.>
		Msg5 <\ELEMENT 2 told you that \NARRATIVE 2 wants you dead.>

		Prompt1 <I'm tired of games. Tell me everything.>
		Prompt2 <Who are they? Tell me now.>

	end
end
inv
	NPC Soldier
	job <Mercenary>
	place <1 pass>
	mecha <Century.txt>

end
