plot 0
	name <You Know Too Much>

	% The PC knows too much about something... An NPC will attack
	% him in town, then he'll be attacked again when leaving town.

	% V1 = Initialization Counter

	Element1 <Grab 3>
	Element2 <Scene Town Target !Far 1>
	Element3 <Prefab>

	start <ifPersona E3 else GoEndPlot  if= V1 0 else GoSetOrder V= 1 1 Compose UTD E3 .killerdies Goto GoSetOrder>
	GoEndPlot <S= 101 1 AdvancePlot 0>
	.killerdies <if# V1 5 V= 1 5 ForceChat E3 History 2>
	GoSetOrder <ifNPCInPlay E3 NPCGoPC E3>

	TM1 <if= SceneID E1 ifNPCinPlay E3 if= V1 1 ifG 6 Range PCUID NPCUID E3  Print 1 ForceChat E3>
	Msg1 <\ELEMENT 3 strikes up a conversation with you.>

	Msg2 <You survived an ambush by the bounty hunter \ELEMENT 3 .>

sub
	Persona 3
	rumor <!3 will take a contract to kill anybody, as long as the price is right.>
	% V2 = Message Randomizer
	greeting <NewChat ifPersona E3 else GoE3Dead P= 1 2 if# d4 1 else GoMisc ifPersona N1 else GoCheckFaction Say 2 Goto GoAddOps>
	GoCheckFaction <ifFaction N2 else GoMisc Say 1 Goto GoAddOps>
	GoMisc <V= 2 2 V+ 2 d3 Say V2 Goto GoAddOps>
	GoAddOps <AddChat d3 V= 2 3 V+ 2 d3 AddChat V2>
	result1 <Reputation 3 -d8 Goto GoStartFight>
	result2 <Reputation 4  d8 Goto GoStartFight>
	result3 <Reputation 5  d8 Goto GoStartFight>
	result4 <Reputation 3  d8 Goto GoStartFight>
	result5 <Reputation 4 -d8 Goto GoStartFight>
	result6 <Reputation 5 -d8 Goto GoStartFight>
	GoStartFight <EndChat V= 2 5 V+ 2 d5 Say V2 SoloAttack E3>
	Msg1 <You're \PC , right? I have a message for you, from \NARRATIVE 2 .>
	Msg2 <Hey \PC , I have a message for you straight from \NARRATIVE 1 . You want to hear it?>
	Msg3 <I have a message for you. You gonna listen?>
	Msg4 <You're \PC . I've been looking for you. There's a message that I have to deliver.>
	Msg5 <What about that. Here I was looking for \PC , and you come find me. I have a message to deliver. Wanna hear it?>
	Msg6 <The message is... you know too much, and you'll never leave \ELEMENT 1 alive!!!>
	Msg7 <The message is, that you know far too much information for us to allow you to live. Goodbye \PC .>
	Msg8 <You know too much to live, so now I'm gonna silence you perminently!>
	Msg9 <You know too much about my employer, so now you gotta die!>
	Msg10 <You're getting too close to my employer, if you catch my meaning. So now I've got to kill you.>
	Prompt1 <I'm not interested in hearing.>
	Prompt2 <Yeah, I know, you're here to kill me.>
	Prompt3 <What? No singing telegram?>
	Prompt4 <Go on. I'm listening.>
	Prompt5 <Hurry up, get to the point.>
	Prompt6 <This had better be important.>

	GoE3Dead <EndChat V= 2 100 V+ 2 d5 Say V2 AdvancePlot 1>
	Msg101 <That was a lucky shot... but there's no way you're leaving town alive...>
	Msg102 <I have failed... but you will still die today...>
	Msg103 <You... you won't get out alive...>
	Msg104 <I die... We'll meet again when you try to leave town...>
	Msg105 <Don't think that you've survived... starting today, I'm the least of your worries...>


	Plot 1
		% The PC survived the assassination attempt... now he
		% will be attacked by mecha when he leaves town.
		% V2 = Combat Indicator
		start <if= SceneID 1 Block Print 1 SavePos Dynamic 2 Threat S103 100 .nu1 .nu2 V= 2 1>
		.nu1 <if= T1 0 Return>
		.nu2 <if= T2 0 Return>

		nu1 <if= T1 0 if= V2 1  V= 2 2  Reputation 6 -2 S= 101 1 AdvancePlot 0>
		nu2 <if= T2 0 if= V2 1  V= 2 3  Reputation 6  1  XPV 100 S= 101 1 S+ 102 1 N= 3 E2 AdvancePlot 0>

		Msg1 <As you leave town, you are ambushed by mecha!>

end
inv
	NPC Bounty Hunter
	CharDesc Chaotic
	EquipChar 10000
	place <1 pass>

end
