Plot 0
	name <You will join me on the dark side>

	% The PC will discover (*SHOCK!*) that his father used to
	% work for [insert evil faction], as does [enemy], and
	% now he must either join them or die! Or fight them off
	% and move on with his life...

	% **********************
	% *** ELEMENTS BLOCK ***
	% **********************

	% E1 is the scene where the combat will take place.
	element1 <Grab 3>

	element2 <Grab 1>

	% E4 is the next scene
	element3 <Scene !Far 1 Town Target>

	% E4 is the enemy faction, if N2 isn't valid.
	element4 <Faction GoodEnemy>

	% ********************
	% *** SCRIPT BLOCK ***
	% ********************
	%  V1 = Initialization Counter
	%  V2 = Combat Indicator
	%  V3 = Conversation Indicator
	%  V4 = Email Indicator

	% On a cleanup request, delete this plot unless combat has been
	% entered.
	cleanup <if= V2 0 AdvancePlot 0>

	start <ifPersona E2 else GoDelete if= V1 0 else GoCheckC2 V= 1 1 Compose EWM E1 .entrycombat ifFaction N2 else GoReplaceFaction>
	GoReplaceFaction <N= 2 E4>
	GoCheckC2 <ifG V2 1 else GoCheckC1 ForceChat E2>
	GoCheckC1 <if= V2 1 if= V3 0 V= 3 1 ForceChat E2>
	GoDelete <S= 101 1   XREnemy NAV_XREUnknown   AdvancePlot 0>
	.entrycombat <Block Print 101 SavePos Dynamic 2 Threat S103 100 .nu1 .nu2 V= 2 1 PassVar 1 E1>
	.nu1 <if= T1 0 Return>
	.nu2 <if= T2 0 Exit L1 SeekGate 1>

	% Combat check. If combat has been entered, V2=1.
	% Combat ends in victory if the number of active masters on
	% team two drops to zero, or ends in defeat is the number of
	% active masters on team one drops to zero. After combat, V2=3
	% if the player was victorious or V2=2 is the player lost.
	nu1 <if= T1 0 if= V2 1  V= 2 2  Reputation 6 -3  N= 3 E3  S= 101 1>
	nu2 <if= T2 0 if= V2 1  V= 2 3  Reputation 6 1 XPV 100 N= 3 E3 S= 101 1 S+ 102 1>

	% Email check - every 5 minutes, check for an email.
	% The NPC might send an email and he might not, so it's very
	% unlikely each 5MIN that the email will be sent... Chances
	% are 1 in 1200, meaning it should be sent once in 4 days.
	5MIN <if= V2 0 ifG V1 0 if= V4 0 if= d1200 23 EMail d3 V= 4 1>

	Msg1 <\ELEMENT 2 @ \ELEMENT 1 :// I have something to show you in \ELEMENT 1 . Meet me near town, if you aren't afraid to learn.>
	Msg2 <\ELEMENT 2 @ \ELEMENT 1 :// I will be waiting for you in \ELEMENT 1 . Surely you aren't too afraid to meet me.>
	Msg3 <\ELEMENT 2 @ \ELEMENT 1 :// I grow impatient. Come to \ELEMENT 1 and we can settle matters between us.>

	Msg101 <As you approach \ELEMENT 1 , you are attacked by mecha!>

sub
	Persona 2
	% The PC's enemy, who will frame the meeting.
	greeting <EndChat if= P2 3 else GoCheckLoss Say 201 History 202 XRBadThing NAV_XRBExMember AdvancePlot 0 AddChat 201 AddChat 202 AddChat 203>
	result201 <EndChat Reputation 3 d4  Say 203>
	result202 <EndChat Say 204>
	result203 <EndChat Reputation 4 -d8 Say 205>
	Msg201 <You're much better than I expected. Maybe they're right about your talents. You could very well be as good as your father. He used to be one of our agents, until that one time... There was no way we could let him survive, you understand.>
	Msg202 <\ELEMENT 2 said your father once worked for \NARRATIVE 2 .>
	Msg203 <As I said, he was one of our best operatives. Very good at keeping secrets. The command thinks you might be an adequate replacement for him. In time, you may be given a choice... Join us, or die like your parents.>
	Msg204 <Me? I want nothing... but my employers may think you're ready to replace your father in our organization. If they make that decision, you will be given a choice... join us and serve our will, or join your family in the next world.>
	Msg205 <You still don't understand. Your father brought his death upon himself for failing to carry out his orders. Someday you will understand, and you will join us... or I will kill you as easily as I killed your parents.>
	Prompt201 <You're lying!>
	Prompt202 <What do you want from me!?>
	Prompt203 <I'll kill you for what you've done.>
	GoCheckLoss <if= P2 2 else GoFirstTime Say 101 AdvancePlot 0>
	Msg101 <As I expected, you are weak. I don't expect that \NARRATIVE 2 will have any further interest in you.>
	GoFirstTime <if= V1 0 else GoAnything V= 1 1 Say 1 History 3 XREnemy NAV_XREFaction AddChat 1 AddChat 2 AddChat 3>
	GoAnything <SayAnything>
	result1 <Reputation 4 -d8 goto result2>
	result2 <EndCHat Say 2>
	result3 <Reputation 4 d8 goto result2>
	Msg1 <Greetings, \PC . We meet again. My employers think it's time you learned the truth... I am working for \NARRATIVE 2 , and they have a small test for you.>
	Msg2 <My employers are very interested in your combat abilities. You will see the team I have chosen for you to battle... you will defeat them, or be defeated by them. We will see how great you truly are.>
	Msg3 <\ELEMENT 2 revealed that he was taking orders from \NARRATIVE 2 .>
	Prompt1 <Tell \NARRATIVE 2 to shove it.>
	Prompt2 <What kind of test?>
	Prompt3 <Let's get this over with quickly...>

end
