Plot 0
	name <School Pals>

	% Turns out the PC went to school with his enemy. Will meet an
	% old classmate (the lost love?) who will ask the PC to go speak
	% with the enemy. Just outside the town of the last meeting the
	% PC will be attacked by his enemy, who will explain that <FACTION>
	% has supplied him with GARU serum and training.

	% Mostly this is a social episode with a fight scene in the middle.

	% E1 is the scene where the old school chum (possible lover) is.
	% E2 is that character.
	% E3 is the scene where N1 is hiding.
	% E4 is N1 himself.
	% E5 is the scene for the next episode.
	% E6 is a replacement faction, in case the story doesn't yet have one.
	Element1 <Grab 3>
	Element2 <Prefab>
	Element3 <Scene Town Target !Far 1>
	Element4 <Grab 1>
	Element5 <Scene Town Target !Far 1 !Far 3>
	Element6 <Faction GoodEnemy>

	% P1 = Initialization Counter
	% P2 = Combat Indicator
	% P3 = Start-the-fight-upon-entering-E3 indicator
	%      if P3=1, PC will fight E4 at E3
	% P4 = Have convinced E4 to change his ways

	% At startup, do initialization.
	% Also check to make sure E2 is alive and well, since otherwise there
	% will be problems.
	start <ifPersona E2 else GoDelete if= P1 0 P= 1 1 FreezeChar E6 MoveChar E2 E1 ConGen E2 AddNPCReact E2 50 NPCLevel E2 S103 EMail 1 Goto GoSetTriggers>
	GoSetTriggers <Compose EWM E3 .ewm ifFaction N2 else GoReplaceFaction E= 6 N2>
	GoReplaceFaction <N= 2 E6>
	GoDelete <S= 101 1 N= 3 E3 AdvancePlot 0>

	% if PC has spoken to E2, the next time he tries to enter E3 he'll be attacked by E4.
	% Got all that? Good. Include a START label in the dynamic scene so that when the fight
	% begins the PC will speak with E4.
	.ewm <if= P3 1 BLOCK Alert 2 XREnemy NAV_XREFaction Goto GoStartCombat>
	GoStartCombat <Dynamic 2 Threat S103 200 .nu1 .nu2 PassVar 1 E3 PassVar 2 E4 P= 2 1 ComposeD START .estart>
	.estart <if= V3 0 V= 3 1 ForceChat V2>
	.nu1 <if= T1 0 Exit 1 SeekGate V1>
	.nu2 <if= T2 0 Exit V1 SeekGate 1>

	NU1 <if= T1 0 if= P2 1 P= 2 2 Reputation 6 -5 S= 101 1 N= 3 E5          AdvancePlot 2>
	NU2 <if= T2 0 if= P2 1 P= 2 3 Reputation 6 1  XPV 200 S= 101 1 S+ 102 1 N= 3 E5 if= V4 1 else GoJustWin MoveChar E4 E3 N= 1 0 AdvancePlot 1>
	GoJustWin <AdvancePlot 1>

	Msg1 <\ELEMENT 2 @ \ELEMENT 1 :// Remember me from our school days? I have to speak with you- meet me soon.>
	Msg1_1 <\ELEMENT 2 @ \ELEMENT 1 :// I haven't seen you in ages! There's something important I have to discuss- meet me here as soon as possible.>

	Msg2 <As you approach \ELEMENT 3 , you are attacked by mecha bearing the colors of \NARRATIVE 2 !>

sub
	Persona 2
	rumor <!2 has been waiting for you.>
	greeting <NewChat if= P3 1 else GoNoMission Say 1>
	GoNoMission <Say 2 XRBadThing NAV_XRBResolved AddChat 1 AddCHat 2 AddChat 3>
	result1 <NewChat  Say 3  Reputation 5  d8  AddChat 4 AddChat 5>
	result2 <NewChat  Say 4  Reputation 5 -d8  AddChat 4 AddChat 5>
	result3 <NewChat  Say 5  Reputation 4  d8  AddChat 4 AddChat 5>
	result4 <NewChat  Say 6  Reputation 4 -d8  P= 3 1  Memo 10 History 11  AddChat 6 AddChat 7>
	result5 <NewChat  Say 7                    P= 3 1  Memo 10 History 11  AddChat 6 AddChat 7>
	result6 <NewChat  Say 8>
	result7 <NewChat  Say 9>
	Msg1 <I really think you ought to go see what \ELEMENT 4 has been doing in \ELEMENT 3 . I know the two of you never got along very well, but I have a feeling this could be very important for us all!>
	Msg2 <\PC ! I haevn't seen you in ages... not since graduation, I think. How have you been? I'm sorry that I didn't write to you all this time but it was a lot of work in the piloting academy, you know?>
	Msg3 <I wish our meeting could be under happier circumstances, though. I've got a problem. Tell me... Do you remember \ELEMENT 4 ? We all went to school together. I kind of remember that the two of you didn't get along.>
	Msg4 <I'm a bit embarassed but very happy to hear that. I missed you too. I called you here for a reason today, Tell me... Do you remember \ELEMENT 4 ? We all went to school together. I kind of remember that the two of you didn't get along.>
	Msg5 <You're right, we both should have. Anyway, there's a reason why I asked you here today. Tell me... Do you remember \ELEMENT 4 ? We all went to school together. I kind of remember that the two of you didn't get along.>
	Msg6 <I can't say I'm surprised. After graduation we both applied to the academy... but during training \OPR E4 began to change. Soon \OPR E4 dropped out. I kept contact with \SPR E4 for a while. I'm certain \OPR E4 got involved in something bad...>
	Msg7 <After graduation both \ELEMENT 4 and I applied to the academy... but during training \OPR E4 began to change. Soon \OPR E4 dropped out. I kept contact with \SPR E4 for a while. I'm certain \OPR E4 got involved in something bad...>
	Msg8 <I can't say I much care for the person \OPR E4 has become... but for the person \OPR E4 used to be, and for my sake, could you go to \ELEMENT 3 and check up on \SPR E4 ? I have this awful feeling that something terrible is about to happen.>
	Msg9 <Go to \ELEMENT 3 and talk to \SPR E4 . You know, \OPR E4 used to really look up to you in our school days. That's why \OPR E4 decided to be a pilot. Please do this for me. I have this awful feeling that something terrible is about to happen.>
	Msg10 <\ELEMENT 2 in \ELEMENT 1 asked you to speak with \ELEMENT 4 in \ELEMENT 3 .>
	Msg11 <Your school friend \ELEMENT 2 sent you to talk with \ELEMENT 4 .>
	Prompt1 <It's great to see you!>
	Prompt2 <I missed you very much...>
	Prompt3 <Eh, I should've written to you too.>
	Prompt4 <That bastard tried to kill me.>
	Prompt5 <Yes, I remember.>
	Prompt6 <I don't care about \ELEMENT 4 .>
	Prompt7 <What do you expect me to do about \SPR E4 ?>

	Persona 4
	greeting <EndChat Say 1 History 4 AddChat 1 AddChat 2>
	result1 <EndChat Say 2 Reputation 4 -d10>
	result2 <EndCHat Say 3 AddChat 3 AddChat 4>
	result3 <EndChat Say 5>
	result4 <EndChat Say 6 AddChat 5 AddChat 6>
	result5 <EndChat ifG 5 TruePCSkillVal 24 else GoR5Fail Say 8 AddChat 7 AddChat 8>
	GoR5Fail <Say 7>
	result6 <EndChat ifG PCRep 1 25 else GoR6Fail Say 10 AddChat 7 AddChat 8>
	GoR6Fail <Say 9>
	result7 <EndChat ifG PCRep 4 0 else GoR7Fail Say 11 P= 4 1>
	GoR7Fail <Say 12>
	result8 <EndChat ifG 0 PCRep 4 else GoR8Fail Say 13 P= 4 1>
	GoR8Fail <Say 14>
	Msg1 <Why are you here? That fool \ELEMENT 2 sent you, didn't \OPR E2 ? I told \SPR E2 that I didn't need \SPR E2 anymore... \ELEMENT 6 has turned me into a greater pilot than I ever dreamt possible!>
	Msg2 <Then you'll be disappointed I'm afraid. I have other things to take care of... My men will handle you by themselves.>
	Msg3 <Why? I had nothing! You were always better than me... \ELEMENT 2 always loved you more, no matter what I did... It was \ELEMENT 6 that showed how my dreams can be realized! They gave me the power to destroy you!>
	Msg4 <You discovered \ELEMENT 4 was working for \ELEMENT 6 .>
	Msg5 <You'll have to prove yourself worthy of my new talents first. I've been taking GARU serum... it's boosted my abilities to beyond human levels. My men should be able to kill you themselves. If not, then we'll meet again someday...>
	Msg6 <I've been taking GARU serum. My abilities have been pumped to beyond human levels... Now, I am far more powerful than you! I no longer have to feel the shame of being second best! When \ELEMENT 6 takes over, I will be a lord!>
	Msg7 <That could apply to both of us, couldn't it? Well, my masters have ordered me elsewhere. My men should be able to handle you by themselves. Goodbye, old friend... may your death be more painless than my life has been...>
	Msg8 <You can't speak of me that way! I'm powerful! No-one has the right to... but, it's too late. My choices have been made. There's no way to redemption for me any more, is there?>
	Msg9 <You've never cared about anyone but yourself, for as long as you've been alive... \ELEMENT 6 has given me exactly what I need. When my men kill you, I'll laugh on your corpse. Goodbye old friend...>
	Msg10 <What kind of help can you offer me? I am no longer a mere human... there is no way back from where I am now. Can't you see that?>
	Msg11 <I'm so confused... I need time to think... Men, finish him off...>
	Msg12 <This must be the only thing you're not sure of... I must guess you don't want to speak the truth of your mind. Men, finish him off... I have business elsewhere...>
	Msg13 <You really think that a beast like me can find salvation? You must be a true believer... My head is so confused... Men, finish him off. I have to go away.>
	Msg14 <There's uncertainty in your voice... I know that my destiny is already sealed, and it is to become the lord over this entire planet! Men, finish him off... I have business elsewhere...>
	Prompt1 <Actually, I'm here to destroy you.>
	Prompt2 <I want to talk to you.>
	Prompt3 <If it's what you want, let's fight!>
	Prompt4 <What have you done to yourself?>
	Prompt5 <But you're losing your humanity.>
	Prompt6 <You're talking crazy... You need help.>
	Prompt7 <I don't know.>
	Prompt8 <There's always a way out.>

	Plot 1
		% PC has won the fight

		% V1 = Timer / Initialization
		% V2 = Have redeemed E4

		start <if= V1 0 else GoCheckTime ifNPCInPlay E4 else GoInit Print 2 ForceChat E4 Goto GoInit>
		GoInit <V= 1 ComTime V+ 1 86400 Memo 1>
		GoCheckTime <ifG ComTime V1 AdvancePlot 0>
		Msg1 <\ELEMENT 2 in \ELEMENT 1 sent you to check up on \ELEMENT 4 .>
		Msg2 <Upon entering \ELEMENT 3 , you find \ELEMENT 4 in a weakened state.>

	sub
		Persona 2
		greeting <NewChat  AdvancePlot 0  Say 1 AddChat 1 AddChat 2 if= P2 1 AddChat 3>
		result1 <NewChat Say 2  AddChat 4 AddChat 5>
		result2 <NewChat Say 3  AddChat 4 AddChat 5  Reputation 5 -d8>
		result3 <NewChat Say 4  AddChat 4 AddChat 5  Reputation 5  d8>
		result4 <NewChat Say 6  History 7  AddChat 6  AddChat 7>
		result5 <NewChat Say 5  Reputation 3 -d10>
		result6 <NewChat Say 8>
		result7 <Say 9 PCLover E2 NewChat>
		Msg1 <So, did you speak with \ELEMENT 4 ? I was worried when I didn't hear back from you. Tell me everything!>
		Msg2 <I should've known something like that could happen. The world seems to be getting crazier every day... I feel like we're moving towards something big and really bad. Look, I've got something else to tell you... Want to hear?>
		Msg3 <I get the feeling that I won't be hearing from \ELEMENT 4 ever again. Something big is getting ready to happen and I just know it isn't going to be good. Um, I have something I never told you before... if you want to listen...>
		Msg4 <Really? Still, I get the feeling that I won't hear from \ELEMENT 4 ever again... and some big things are soon going to happen. Before then I have something to tell you, if you want to hear it...>
		Msg5 <You're probably right... The world is changing, it's foolish to try hanging on to the past. Still I'm very glad that we could see each other again.>
		Msg6 <All these years... Ever since our school days together, really... I've cared very deeply for you. I always wanted to be near you. That's why I decided to be a pilot... I don't guess there's any way my feelings could be returned...>
		Msg7 <\ELEMENT 2 confessed \PPR E2 feelings for you.>
		Msg8 <I know. I knew before you told me... but I wanted to let you know how I feel. I'm still very glad that we could see each other again, and I hope that you'll come by to talk every once in a while.>
		Msg9 <Really? I should have told you that years ago! You've made me very happy! Um, if you're not doing anything, maybe we could spend some time together?>
		Prompt1 <\ELEMENT 4 attacked me.>
		Prompt2 <You're better off not knowing.>
		Prompt3 <It all worked out for the best...>
		Prompt4 <Alright, tell me.>
		Prompt5 <Some things are best left in the past.>
		Prompt6 <Sorry, I don't feel the same way.>
		Prompt7 <Maybe they could be...>

		Persona 4
		% If E4 is in this scene, it's because he was redeemed by the PC in
		% the previous battle.
		greeting <NewCHat if= P2 0 else GoNothing P= 2 1 Say 1 History 2 Reputation 1 1 AddChat 1 AddChat 2>
		GoNothing <SayAnything>
		result1 <NewChat Say 3 Reputation 5 d8   AddChat 3>
		result2 <NewChat Say 4 Reputation 5 -d8  AddChat 3>
		result3 <NewChat Say 5>
		Msg1 <You were right. I am heading down a dark path... I feel like I am going crazy... I don't want this anymore. I don't want anything.>
		Msg2 <You convinced \ELEMENT 4 to quit \ELEMENT 6 .>
		Msg3 <I think I've needed help for a long time... You've shown me something I had almost forgotten. I will never be the same as I was, but I can try to start a new life.>
		Msg4 <I've decided to quit \ELEMENT 6 ... I can never go back to the way things were, but I can make the most of that time I have left... I feel that without the GARU serum my body is dying... at least I will die a person, not a monster.>
		Msg5 <Control. They want to control everything. And I was so willing to get it for them, so long as they fed my delusions... You were always stronger than me, \PC . It may be up to the people like you to protect this world from them.>
		Prompt1 <It's alright. You can get help.>
		Prompt2 <You should pay for what you've done.>
		Prompt3 <What does \ELEMENT 6 want?>

	end



	Plot 2
		% PC has lost the fight
		% This plot is just a wrap-up for the events put into motion above.
		% The next extra-random plot was set by the end of the above fight.
		start <ifPersona E2 else GoDelete if= V1 0 else GoCheckTime V= 1 ComTime V+ 1 86400 Memo 1>
		GoCheckTime <ifG Comtime V1 AdvancePlot 0>
		GoDelete <AdvancePlot 0>
		Msg1 <\ELEMENT 2 in \ELEMENT 1 sent you to check up on \ELEMENT 4 .>
	sub
		Persona 2
		greeting <NewChat Say 1 AddChat 1 AddChat 2>
		result1 <NewChat Say 2 AdvancePlot 0>
		result2 <NewChat Say 3 Reputation 3 -d10 AdvancePlot 0>
		Msg1 <So, did you speak with \ELEMENT 4 ? What's \OPR E4 gotten into?>
		Msg2 <So it's as I feared... \OPR E4 may well be beyond redemption. You know, I used to have strong feelings for both of you, while we were in school. I think I need to be alone for a while.>
		Msg3 <You don't have to say; I can tell what happened from your eyes. You know, I used to have strong feelings for both you and \SPR E4 , while we were in school. I think I need to be alone for a while.>
		Prompt1 <Yes; \OPR E4 attacked me.>
		Prompt2 <I don't want to say.>
	end


end
inv
	NPC Mecha Pilot
	Charm 14
	Chardesc Sociable Cheerful Heroic
	teamdesc <PASS>

end
