Plot 0
	name <PLOT: Hired Hunter>

	% E1 is the scene for the current episode.
	% E2 is the character who will tell the PC where to go.
	% E3 is the scene to be used in the next episode.
	% E4 is the hired hunter himself.
	% E5 is the faction that did the hiring.
	Element1 <Grab 3>
	Element2 <Character Bounty Hunter Heroic>
	Element3 <Scene Town Target !Far 1>
	Element4 <Prefab>
	Element5 <Grab 2>

	% V1 = Initialization / Combat Can Start
	% V2 = Combat Indicator
	% V3 = Email Counter

	rumor <!5 hired a bounty hunter to kill you.>

	% On a cleanup request just delete this plot.
	cleanup <AdvancePlot 0>

	% At startup, check for victory or failure.
	start <if= P2 3 else GoCheckLoss S= 101 1 S+ 102 1 N= 3 E3 AdvancePlot 0 ifPersona E4 Alert 2>
	GoCheckLoss <if= P2 2 else GoRealStart S= 101 1 N= 3 E3 AdvancePlot 0 ifPersona E4 Alert 3>

	% The first start, initialize everything.
	GoRealStart <ifPersona E2 else GoDelete if= V1 0 else GoCheckCombat V= 1 1 MoveChar E2 E1 ifPersona N1 else GoInsertE4>
	GoInsertE4 <N= 1 E4>
	GoCheckCombat <if= V1 2 if= SceneID 1 Goto GoStartCombat>
	GoDelete <S= 101 1 N= 3 E3 AdvancePlot 0>

	GoStartCombat <Print 101 Block SavePos P= 1 3 P= 2 1 Dynamic 2 Threat S103 120 .nu1 .nu2 Goto GoPrepNPC>
	GoPrepNPC <PCEnemy E4 NPCLevel E4 S103 DynaNPC E4 2 ComposeD START .start PassVar 1 E4>
	.nu1 <if= T1 0 if= L2 0 L= 2 1 Return>
	.nu2 <if= T2 0 if= L2 0 L= 2 1 XPV 100 Salvage Return>
	.start <if# L1 0 ForceChat L1 L= 1 0>

	% Combat check. If combat has been entered, V2=1.
	% Combat ends in victory if the number of active masters on
	% team two drops to zero, or ends in defeat is the number of
	% active masters on team one drops to zero. After combat, V2=3
	% if the player was victorious or V2=2 is the player lost.
	nu1 <if= T1 0 if= V2 1  V= 2 2  History 4  Reputation 6 -7>
	nu2 <if= T2 0 if= V2 1  V= 2 3  History 5  Reputation 6  1>

	5Min <if= d30 1 if= P1 1 ifG RReact E2 d50 if= P3 0 P= 3 1 Email 1>

	Msg1 <\ELEMENT 2 @ \ELEMENT 1 :// I have some information for you. It's delicate... Come see me ASAP.>

	Msg2 <\ELEMENT 4 : You've got some skills... Killing you will be a challenge! We shall meet again, shortly...>
	Msg3 <\ELEMENT 4 : That was too easy. Next time, I'll really destroy you!>

	Msg4 <You were defeated by the bounty hunter \ELEMENT 4 .>
	Msg5 <You defeated \ELEMENT 4 , a bounty hunter sent by \ELEMENT 5 .>

	Msg101 <As you leave town, you are attacked by mecha bearing \ELEMENT 5 insignia!>

sub
	Persona 2
	rumor <!2 heard something you might need to know.>
	greeting <NewChat if= P1 1 else GoNoStart Say 1 P= 1 2>
	GoNoStart <SayAnything>
	Msg1 <You should know that \ELEMENT 5 hired a bounty hunter to kill you. Goes by the name of \ELEMENT 4 ; was in town a while back asking questions. Be careful, there may be an ambush waiting when you leave town...>

	Persona 4
	greeting <EndChat Say 1>
	Msg1 <Hello \PC . I am \ELEMENT 4 ; \ELEMENT 5 hired me to kill you. Well, that's enough for introductions... now we must fight!!!>

end
inv
	NPC Bounty Hunter
	EquipChar 45000
	CharDesc Villainous

end

