
#include "defines.txt"

if (new_room) {
  load.pic(room_no);
  draw.pic(room_no);
  discard.pic(room_no);
  set.horizon(30);

  show.pic();

  if(v1==14) {
   position(ego,154,115);
   draw(ego);
  }
  if(v1==16) {
   position(ego,3,115);
   draw(ego);
  }
  if(v1==18) {
   position(ego,84,163);
   draw(ego);
  }

  v255=15;

  if(obj.in.room("Shotgun",v255)) {
  animate.obj(o1);
  load.view(19);
  set.view(o1,19);
  set.loop(o1,0);
  set.cel(o1,0);
  position(o1,58,114);
  set.priority(o1,4);
  ignore.objs(o1);
  stop.cycling(o1);
  draw(o1);
  }
}


if (said("look")) {
  print("This is another section of the rock formation floating in this strange parallel universe.");
  v255=15;
  if(obj.in.room("Shotgun",v255)) {
    print("Why look! Someone has carelessly left a shotgun lying around.");
  }
}

if (said("look","gun")) {
  v255=15;
  if(obj.in.room("Shotgun",v255)) {
     print("A double-barrelled pump-action shotgun. I wonder who it belongs to.");
  }
  else {
  reset(input_parsed);
  }
}

if (said("get","gun")) {
  v255=15;
  if(obj.in.room("Shotgun",v255)) {
    if(posn(ego,50,104,66,125)) {
      erase(o1);
      get("Shotgun");
      print("You take the shotgun. Now you feel powerful.");
    }
    else {
     print("Come a little closer!");
    }
  }
  else {
  reset(input_parsed);
  }
}

if (said("look","sky")) {
  print("Hey, that cloud looks like a dog poo.");
}

if(isset(f3)) {
  erase(ego);
  death_type=2;
}

if(v2==2) {
  new.room(14);
}

if(v2==3) {
  new.room(18);
}

if(v2==4) {
  new.room(16);
}

return();



