
#include "defines.txt"

if (new_room) {
  load.pic(room_no);
  draw.pic(room_no);
  discard.pic(room_no);
  set.horizon(30);

  show.pic();

  if(v1==13) {
   position(ego,3,126);
   draw(ego);
  }

}


if (said("look")) {
  print("This is another section of the rock formation floating in this strange parallel universe. A weird crystal thing grows here.");
}

if (said("look","crystal")) {
  print("It seems to be glowing faintly from within, not unlike you once did after the cat jogged your arm during a lengthy ritual.");
  print("Took a bit of explaining, as did the cat suddenly growing demon wings.");
  if(isset(f28)) {
     print("Some smaller crystals are gathered on the floor near the big crystal.");
  }
}

if (said("get","crystal")) {
  print("Yowser, it's a bit big and a bit solid and a bit heavily-embedded-in-the-bedrock for that.");
}

if (said("look","crystals")) {
  v255=17;
  if((isset(f28)) && (obj.in.room("Glowing crystals",v255))) {
      print("A few bits of crystal lying at the foot of the big one.");
     }
    else {
   reset(input_parsed);
  }
}

if (said("get","crystals")) {
  v255=17;
  if((isset(f28)) && (obj.in.room("Glowing crystals",v255))) {
    if(posn(ego,57,71,76,86)) {
      erase(o1);
      reset(f28);
      get("Glowing crystals");
      }
     else {
      print("Come a little closer!");
     }
    }
    else {
   reset(input_parsed);
  }
}

if ((said("shoot","crystal") ||
    said("shoot","gun") ||
    said("shoot","gun","crystal") ||
    said("shoot","crystal","gun"))) {
   if(has("Shotgun")) {
     if(!isset(f28)) {
      if(posn(ego,57,71,76,86)) {
       move.obj(ego,45,85,1,f16);
       }
      else {
       print("Come a little closer!");
      }
     }
     else {
     print("You have shot it enough today.");
    }
   }
   else {
  print("Sorry, did you acquire a gun when I wasn't looking?");
  }
}

if(isset(f16)) {
   reset(f16);
  animate.obj(o1);
  load.view(20);
  set.view(o1,20);
  set.loop(o1,0);
  set.cel(o1,0);
  v255=2;
  cycle.time(o1,v255);
  position(o1,45,85);
  set.priority(o1,4);
  ignore.objs(o1);
  stop.cycling(o1);
  erase(ego);
  draw(o1);
   end.of.loop(o1,f17);
}

if(isset(f17)) {
   reset(f17);
   v6 = 3;
   draw(ego);
   set.loop(o1,1);
   set.cel(o1,0);
   position(o1,67,85);
   end.of.loop(o1,f18);
}  

if(isset(f18)) {
   reset(f18);
   set(f28);
   drop("Shotgun");
   print("The shotgun blast has knocked some small crystal bits off the main crystal. You could be the next Duke Nukem.");
   print("The shotgun, now devoid of shells, is no longer useful, so you discard it.");
}  

if (said("look","sky")) {
  print("If only your girlfriend was here, this'd be so romantic.");
  print("Just don't take the constant danger of horrible violent death into account.");
}


if(isset(f3)) {
  erase(ego);
  death_type=2;
}

if(v2==4) {
  new.room(13);
}

return();


