
#include "defines.txt"

if (new_room) {
  load.pic(room_no);
  draw.pic(room_no);
  discard.pic(room_no);
  set.horizon(50);

  show.pic();

  animate.obj(o1);
  load.view(9);
  set.view(o1,9);
  set.loop(o1,0);
  set.cel(o1,0);
  position(o1,63,104);
  release.loop(o1);
  wander(o1);
  draw(o1);

  animate.obj(o2);
  load.view(8);
  set.view(o2,8);
  set.loop(o2,1);
  set.cel(o2,0);
  v255=2;
  cycle.time(o2,v255);
  position(o2,84,94);
  set.priority(o2,4);
  draw(o2);

  end.of.loop(o2,f16);
}

v27--;

if(isset(f16)) {
  reset(f16);
  v27=12;
  print("Well, that went well. Now all you need to do is improve on the spell design. A softer landing would be nice. Being able to specify a destination would be nicer.");
}

if(v27==1) {
  set.loop(o2,2);
  end.of.loop(o2,f17);
}  

if(isset(f17)) {
  reset(f17);
  print("You are having a small degree of difficulty breathing, so the atmosphere must be marginally different to that of your home planet. A feeling of light-headedness indicates low gravity. Strange noises reach your ears. You can't help feeling that you've been here before.");
  print("(With apologies to Valve and Sierra)");
  accept.input();
  set(f200);
  position(ego,86,92);
  erase(o2);
  draw(ego);
}

if(isset(f3)) {
  erase(ego);
  death_type=2;
}


if (said("look")) {
  print("You are standing on a huge rock floating in an infinite void. The sky is hued in horrible smeary shades of blue and green A few examples of local wildlife are running around.");
}

if (said("look","wildlife")) {
  print("A little blue and yellow animal scampers about. Hopefully the rest of this world's fauna is similarly non-hostile.");
}

if (said("ride","wildlife")) {
  print("Are you some kind of weirdo who likes shattering the spines of innocent creatures?");
}

if (said("get","wildlife")) {
  print("You wouldn't want one of those scampering round in your pockets. You're ticklish.");
}

if (said("kill","wildlife")) {
  print("It's going too fast. And you wouldn't want to kill the poor thing anyway.");
}

if(v2==3) {
  new.room(7);
}

if(v2==4) {
  new.room(7);
}

return();


