
#include "defines.txt"

if (new_room) {
  load.pic(room_no);
  draw.pic(room_no);
  discard.pic(room_no);
  set.horizon(50);

  show.pic();

  if(v1==7) {
   position(ego,152,126);
   draw(ego);
  }

  if(v1==9) {
   position(ego,3,126);
   draw(ego);
  }

  v255=8;

  if(obj.in.room("Rock",v255)) {
  animate.obj(o1);
  load.view(11);
  set.view(o1,11);
  set.loop(o1,0);
  set.cel(o1,0);
  position(o1,39,138);
  set.priority(o1,4);
  ignore.objs(o1);
  v255=2;
  cycle.time(o1,v255);
  stop.cycling(o1);
  draw(o1);
  }

}


if (said("look")) {
  print("This is another section of the rock formation floating in this strange parallel universe.");
  if(obj.in.room("Rock",v255)) {
     print("There's a flat rock lying on the ground here.");
  }
}

if (said("look","sky")) {
  print("Oh look, another rock formation thingy.");
}

if (said("look","rock")) {
  v255=8;
  if(obj.in.room("Rock",v255)) {
     print("There's a flat rock lying on the ground here.");
  }
  else {
  reset(input_parsed);
  }
}

if (said("get","rock")) {
  v255=8;
  if(obj.in.room("Rock",v255)) {
      if(posn(ego,32,131,47,146)) {
       erase(ego);
       set.loop(o1,1);
       end.of.loop(o1,f16);
      }
      else {
       print("Come a little closer!");
      }
  }
  else {
  reset(input_parsed);
  }
}

if(isset(f16)) {
  reset(f16);
  erase(o1);
  draw(ego);
  get("Rock");
  print("Somehow you manage to stuff the rock into your jacket pocket. Probably some spell you cast over your clothes, you lost count of those long ago.");
}

if(isset(f3)) {
  erase(ego);
  death_type=2;
}

if(v2==2) {
 new.room(7);
}

if(v2==4) {
 new.room(9);
}

return();




